AutoLISP to offset closed polyline, hatch, and delete the second polyline [C3D]
That should be possible, but which of my earlier Messages here has the code you are using? Also, in the context of this topic, would you be using only the inward-offsetting command from OffsetInOrOut, or is the idea just to steal its multiple-selection capability and work that part into something from here?
Kent Cooper, AIA 
@MauCabrera789 wrote:
....
In the context of this topic, the core idea was to incorporate multiple-selection capability into your offset-hatching program OI2H.lsp, because at the moment it only accepts a single input.
I brought up OffsetInOrOut.lsp because, from my understanding, you already took care of a lot of the heavy lifting with regards to defining a function that can offset a lot of polylines simultaneously. ....
Not so heavy lifting, really.... Just a matter of a selection set rather than a single object, and a (repeat) function to step through that set and do the same to each object in it. Minimally tested:
(defun C:OI2H ; = Offset Inward by 2 drawing units, and Hatch
(/ *error* doc ss n ent obj oarea pickpt pl2)
(defun *error* (errmsg)
(if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
(princ (strcat "\nError: " errmsg))
); if
(vla-endundomark doc)
(princ)
); defun - *error*
(vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
(prompt "\nBuilding outline to Offset Inward and Hatch: ")
(if (setq ss (ssget "_:L" '((0 . "LWPOLYLINE") (-4 . "&") (70 . 1)))); on unlocked Layers, closed
(repeat (setq n (sslength ss)); then
(setq
obj (vlax-ename->vla-object (setq ent (ssname ss (setq n (1- n)))))
oarea (vla-get-Area obj)
pickpt (vlax-curve-getClosestPointTo obj (last (last (last (ssnamex ss)))))
); setq
(vla-offset obj 2)
(if (> (vla-get-Area (vlax-ename->vla-object (entlast))) oarea)
(progn ; then -- went wrong way
(entdel (entlast))
(vla-offset obj -2)
); progn
); if [went wrong way -- no else; do nothing if it went right way]
(command
"_.hatch" "USER"
(cvunit
(+
(angle '(0 0 0) (vlax-curve-getFirstDeriv obj (vlax-curve-getParamAtPoint obj pickpt)))
(/ pi 4)
); +
"radian" "degree"
); cvunit
0.75 "_no" ent (setq pl2 (entlast)) "" "" ; <-- EDIT 0.75 as preferred
"_.chprop" "_last" "" "_layer" "YourLayerName" "" ; <-- EDIT Layer name
"_.erase" pl2 ""
)
); repeat -- then
); if
(vla-endundomark doc)
(princ)
); defun -- C:OI2H
(vl-load-com)
(prompt "\nType OI2H to Offset Inward by 2 drawing units and Hatch.")
Don't listen to curmudgeonly John about in/out vs. left/right. In the context of this topic [building footprints], the area comparison works fine, but do listen to other earlier caveats that apply whether comparing areas or determining drawn direction. The too-small-to-Offset-inward issue from the OffsetInOrOut topic is probably not a concern unless you have garden sheds or something tiny like that. But the possibility that something is of a convoluted-enough shape that more than one object results from Offsetting it is something to be aware of.
Kent Cooper, AIA
@kmohs wrote:
If I set the value of an offset distance based on "cannoscalevalue" for setq (vla-offset obj...), how would I go about setting the negative value?
A (-) function with only one argument gives you the negative of that argument:
(vla-offset obj (- YourValueOrVariable))
Kent Cooper, AIA
Ahah. I see what you would like, but copying does not offset the vertical sides inward.
In the image below, the white is the original, the red is the offset or copy, and the green is obviously the hatch.
I'm sure I could figure out a way to "offset" the sides inward, but there doesn't seem to be much visual difference between the horizontal points via copying vs. offsetting. I mean the red offset/copy won't be used for any data calculations, will it? In fact it will be deleted, right?
Yes, similar to this but there will be no vertical lines on both ends and these should be created by lisp automatically.
In the image you can see example.
Colors are for example only.
Thank you.
@saqib_tipa wrote:
.... there should be vertical sides (left and right) created by lisp, keep them and not join to original line and copied line so that we can apply same command again.
.... OR down by user click (like in offset command) where we want that polyline to copy and hatch.
Color and layer have no problem same color and layer is ok. ....
Try this, edited from Message 35 [very lightly tested}. You can Copy not only either up or down but in any direction, so you can use it on a generally vertical original and go sideways, etc. -- turn Ortho on if you want. Edit the Hatch spacing number [1] as instructed.
(defun C:CCH ; = Copy, Close, and Hatch
(/ *error* doc ss ent1 ent2)
(defun *error* (errmsg)
(if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
(princ (strcat "\nError: " errmsg))
); if
(vla-endundomark doc)
(princ)
); defun - *error*
(vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
(prompt "\nObject to Copy, Close and Hatch: ")
(if (setq ss (ssget "_:S+." '((0 . "LWPOLYLINE") (-4 . "<NOT") (-4 . "&") (70 . 1) (-4 . "NOT>")))); one, open only
(progn ; then
(setq
ent1 (ssname ss 0)
ss (ssadd ent1); re-use variable name
); setq
(command-s "_.copy" ent1 "")
(ssadd (setq ent2 (entlast)) ss)
(command "_.line" "_non" (vlax-curve-getStartPoint ent1) "_non" (vlax-curve-getStartPoint ent2) "")
(ssadd (entlast) ss)
(command "_.line" "_non" (vlax-curve-getEndPoint ent1) "_non" (vlax-curve-getEndPoint ent2) "")
(ssadd (entlast) ss)
(command "_.hatch" "USER" "45" 1 "_no" ss ""); <-- EDIT 1 as preferred
); progn -- then
); if
(vla-endundomark doc)
(princ)
); defun -- C:CCH
(vl-load-com)
(prompt "\nType CCH to Copy, Close and Hatch an open Polyline.")
It could easily be adjusted to:
1) allow selection of any open-ended object [Line, Arc, open Spline or Ellipse];
2) allow selection of multiple objects, to be Copied/Closed/Hatched by the same distance and direction;
3) ask for, rather than build in, things like Hatch angle or single/double, or pattern name, spacing/scale, rotation, etc.;
4) control for Layer(s) of the new pieces.
Kent Cooper, AIA