AutoLISP to offset closed polyline, hatch, and delete the second polyline [C3D]
@saqib_tipa wrote:
.... after selecting object it automatically selects displacement point anywhere ... so that we just need to enter value. ....
... [and aim for the direction]. This should do that:
(command-s "_.copy" ent1 "" (getvar 'viewctr))
Kent Cooper, AIA 
@john.uhden wrote:
.... You have provided only one point to the copy command. .....
You must not have noticed that the COPY command is in a (command-s) function. It will wait for the second point. Alternatively, in a regular (command) function, the pause for the second point would be supplied [see my next Message].
Kent Cooper, AIA
@saqib_tipa wrote:
.... How to make selection of multiple objects. as you said ....
Try this [lightly tested]. It also allows selection of open-ended objects other than Polylines.
(defun C:CCH ; = Copy, Close, and Hatch
(/ *error* doc ss p1 p2 n ent1 ss2 ent2)
(defun *error* (errmsg)
(if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
(princ (strcat "\nError: " errmsg))
); if
(vla-endundomark doc)
(princ)
); defun - *error*
(vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
(prompt "\nTo Copy, Close and Hatch open-ended object(s),")
(if
(setq ss
(ssget "_:L"
(list
'(-4 . "<OR")
'(0 . "LINE,ARC"); any [always open]
'(-4 . "<AND")
'(0 . "*POLYLINE,SPLINE") '(-4 . "<NOT") '(-4 . "&") '(70 . 1) '(-4 . "NOT>"); open only
'(-4 . "AND>")
'(-4 . "<AND")
'(0 . "ELLIPSE")
'(-4 . "<NOT") '(-4 . "<AND") '(41 . 0.0) (cons 42 (* pi 2)) '(-4 . "AND>") '(-4 . "NOT>"); open only
'(-4 . "AND>")
'(-4 . "OR>")
); filter list
); ssget & ss
); setq
(progn ; then
(setq
p1 (getvar 'viewctr)
p2 (getpoint p1 "\nDirection and distance to Copy: ")
); setq
(repeat (setq n (sslength ss))
(setq
ent1 (ssname ss (setq n (1- n)))
ss2 (ssadd ent1)
); setq
(command "_.copy" ent1 "" "_non" p1 "_non" p2)
(ssadd (setq ent2 (entlast)) ss2)
(command "_.line" "_non" (vlax-curve-getStartPoint ent1) "_non" (vlax-curve-getStartPoint ent2) "")
(ssadd (entlast) ss2)
(command "_.line" "_non" (vlax-curve-getEndPoint ent1) "_non" (vlax-curve-getEndPoint ent2) "")
(ssadd (entlast) ss2)
(command "_.hatch" "USER" "45" 1 "_no" ss2 ""); <-- EDIT 1 as preferred
); repeat
); progn -- then
(prompt "\nNo open-ended unlocked object(s) selected."); else
); if
(vla-endundomark doc)
(princ)
); defun -- C:CCH
(vl-load-com)
(prompt "\nType CCH to Copy, Close and Hatch open-ended objects.")Of course, as with the earlier one, it is up to you to use it appropriately for the configuration of the object(s) involved. It will do this kind of thing [here with an Arc, but potentially with several other kinds of objects]:
Kent Cooper, AIA
@saqib_tipa wrote:
... it is not a good way to select auto point on the mid screen, can you plz tell me how to make it to select manual on the screen ....
Try changing this:
p1 (getvar 'viewctr)to this:
p1 (getpoint "\nBase point for defining displacement: ")Though I don't understand what's not good about letting it use the middle of the current view, to spare you the need to specify a start point [i.e. to save you a step]. If the displacement is going to be applied to multiple objects, having you pick a start, maybe with a particular relationship to any of the objects, will be irrelevant for the others, so it seems to me a "generic" displacement is appropriate.
Kent Cooper, AIA
@saqib_tipa wrote:.... modified in the way that it may work only in one direction up or down ....
If you really want only up, or only down, built into the command definition, that can be done. If you want the choice within one command of either up or down, but only those two directions, simply having Ortho mode turned on helps a lot, but will not prevent the orthogonal sideways directions. Or would you want an option for Up or Down, which you would need to specify [e.g. with a U/D choice] each time separately from the distance part?
When drawing manually, while drawing something like a Line, or for the second point of displacement in a Move or Copy command, you can type in <90 and have your next point restricted in direction from the previous point to only 90° [and the opposite direction 270°], which is like Ortho but prevents the sideways directions. However, I have not found a way to get that to work within an AutoLisp routine -- the language can be included, but it seems to ignore it. [I'll keep trying to find a way.]
Kent Cooper, AIA
@john.uhden wrote:
.... I was under the impression that he wanted to 'CCH' a selection set of polylines all in the same direction and distance. ... supply the distance just once and the direction ... just once....
[Not necessarily a "he,", but anyway....]
The code in Message 85, with or without the adjustment at Message 90, does that much. It's not limited to just Up or Down, but that's a separate question, about which I await a response.
Kent Cooper, AIA
@saqib_tipa wrote:
.... If possible, only up or down then it will be great. .... two codes for up (CCHU) and down (CCHD) ....
Try the attached CopyCloseHatchUpDown.lsp, which defines a CCHU command and a CCHD command, using a shared sub-routine that does all the work, with a couple of arguments appropriate to each direction. After the first use, it remembers your specified distance [which can be typed in or by on-screen picks], and offers it as default on subsequent use.
Kent Cooper, AIA
Since the structure of that makes it so easy to do, attached is a version for all four orthogonal directions, with CCHL [Left] and CCHR [Right] commands added,
Kent Cooper, AIA