Is it possible to insert a newly created part (without save) into an assembly?

[liminma8458]

Hi, everyone,

I am creating a part document from a custom part template using such as:

Dim oPartDoc As PartDocument
oPartDoc = ThisApplication.Documents.Add(DocumentTypeEnum.kPartDocumentObject, "C:\3D\......\my_std_part.ipt", False)

Before saving it, I want to assemble it into an assembly using (the purpose of this is to preview how this new part fit in the assembly first, then decide keep it or not):

oOcc = ThisApplication.ActiveDocument.ComponentDefinition.Occurrences.Add(full_path_file_name, oPositionMatrix)

Because I do not save it yet, this oPartDoc only has a name such as Part1, Part2 and so on assigned by system, but without a full path name. So is it possible adding this oPartDoc into an assmebly, and save it later?

Thank you very much in advance.

[bradeneuropeArthur]

Hi,

First create the part separately.

then add it to your assembly.

[liminma8458]

I mean how to use API to do it. Even you do it manually, looks like you need to save the part file first then assemble it.

[bradeneuropeArthur]

Public Sub d()
Dim a As Application
Set a = ThisApplication

Dim ba As AssemblyDocument
Set ba = a.ActiveDocument

'Set b = a.ActiveDocument
Dim oAsmCompDef As AssemblyComponentDefinition
Set oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition

Dim bp As PartDocument
Set bp = a.Documents.Add(kPartDocumentObject, , True)

Call bp.SaveAs("D:\Test.ipt", False)

Dim oTG As TransientGeometry
Set oTG = ThisApplication.TransientGeometry

Dim oMatrix As Matrix
Set oMatrix = oTG.CreateMatrix

Call oMatrix.SetTranslation(oTG.CreateVector(3, 2, 1))
' Add the occurrence.
Dim oOcc As ComponentOccurrence
Set oOcc = oAsmCompDef.Occurrences.Add("D:\Test.ipt", oMatrix)

End Sub

[liminma8458]

bradeneurope,

Thank you very much for your code. As in your code, we have to "Call bp.SaveAs("D:\Test.ipt", False)" to save bp (PartDocument) to a specific name ("D:\Test.ipt") in disc first, then we can use this name as a handle to assemble it (Set oOcc = oAsmCompDef.Occurrences.Add("D:\Test.ipt", oMatrix)).

But my problem is that I don't know whether this bp (PartDocument) is what I want. I just want to see it in the assembly first, then I can decide to save it later or just skip it

My challenge is whether we can do something to add bp (PartDocument) directly  like:

Set oOcc = oAsmCompDef.Occurrences.Add(bp, oMatrix)

Any way to do it?

Thanks again

[bradeneuropeArthur]

Hi,

Simply delete the file from disc if you do not want to keep it!!!

[liminma8458 · Accepted solution]

Bradeneurope:

Thank you for giving me the hint. I got it work the way I want by modifying your code as:

Public Sub d()
Dim a As Application
Set a = ThisApplication

Dim ba As AssemblyDocument
Set ba = a.ActiveDocument

'Set b = a.ActiveDocument
Dim oAsmCompDef As AssemblyComponentDefinition
Set oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition

Dim bp As PartDocument
Set bp = a.Documents.Add(kPartDocumentObject, , True)

'Call bp.SaveAs("D:\Test.ipt", False)

Dim oTG As TransientGeometry
Set oTG = ThisApplication.TransientGeometry

Dim oMatrix As Matrix
Set oMatrix = oTG.CreateMatrix

Call oMatrix.SetTranslation(oTG.CreateVector(3, 2, 1))
' Add the occurrence.
Dim oOcc As ComponentOccurrence
'Set oOcc = oAsmCompDef.Occurrences.Add("D:\Test.ipt", oMatrix)
Set oOcc = oAsmCompDef.Occurrences.AddByComponentDefinition(bp.ComponentDefinition, oMatrix)

ba.Activate
End Sub

Thanks again

[bradeneuropeArthur]

Hi,

Thank you for the Hint!

Dim a As Application
Set a = ThisApplication
Dim ba As AssemblyDocument
Set ba = a.ActiveDocument
'Set b = a.ActiveDocument
Dim oAsmCompDef As AssemblyComponentDefinition
Set oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition
Dim bp As PartDocument
Set bp = a.Documents.Add(kPartDocumentObject, , True)
'Call bp.SaveAs("D:\Test.ipt", False)
Dim oTG As TransientGeometry
Set oTG = ThisApplication.TransientGeometry
Dim oMatrix As Matrix
Set oMatrix = oTG.CreateMatrix
Call oMatrix.SetTranslation(oTG.CreateVector(3, 2, 1))
' Add the occurrence.
Dim oOcc As ComponentOccurrence
'Set oOcc = oAsmCompDef.Occurrences.Add("D:\Test.ipt", oMatrix)
Set oOcc = oAsmCompDef.Occurrences.AddByComponentDefinition(bp.ComponentDefinition, oMatrix)

Added this line of code?
ba.Activate

I need to be more careful before I release my ideas and solution.

Good job.