CommandManager.Pick (KDrawingWeldSymbol) Inventor 2024

[bradeneuropeArthur]

How can I use the the commandmanager to select/pick a DrawingWeldingSymbol in Inventor 2024. The API now is available for DrawingWeldSymbols, but not for selection?

Any Ideas how to select these?

[Michael.Navara]

It looks like a bug. You can process only pre-selected symbols. Selection doesn't work in SelectEvents too.

According to this StackOverflow post I try to implement custom functionality similar to Pick method. But it doesn't work with drawing weld symbols. 😞

imports system.Threading.Tasks
Sub Main()
MainAsync()
End Sub

Private pickTcs As TaskCompletionSource(Of Boolean) = New TaskCompletionSource(Of Boolean)()
Private interactionEvts As InteractionEvents
Private selectEvts As SelectEvents

Async Sub MainAsync()
	interactionEvts = ThisApplication.CommandManager.CreateInteractionEvents()
	selectEvts = interactionEvts.SelectEvents

	AddHandler interactionEvts.OnTerminate, AddressOf interactionEvts_OnTerminate
	AddHandler selectEvts.OnSelect, AddressOf selectEvts_OnSelect

	interactionEvts.Start()

	Dim selectedSomething = Await pickTcs.Task
	Logger.Debug("Something selected: {0}", selectedSomething)
End Sub

Private Sub selectEvts_OnSelect(justSelectedEntities As ObjectsEnumerator, selectionDevice As SelectionDeviceEnum, modelPosition As Point, viewPosition As Point2d, view As Inventor.View)

	pickTcs.SetResult(True)
	StopInteraction()
End Sub

Private Sub interactionEvts_OnTerminate()
	pickTcs.SetResult(False)
	StopInteraction()
End Sub

Private Sub StopInteraction()
	interactionEvts.Stop()
	interactionEvts = Nothing
	selectEvts = Nothing
End Sub

[bradeneuropeArthur]

Hi Michael,

I was trying exact the same but no result. Seems as a bug indeed.

@johnsonshiue could you and your team have a look at it?

[Michael.Navara · Accepted solution]

I found a solution! 😀

Imports System.Threading.Tasks

Sub Main()
MainAsync()
End Sub

Private pickTcs As TaskCompletionSource(Of Boolean) = New TaskCompletionSource(Of Boolean)()
Private userInputEvts As UserInputEvents
Private pickedObject As Object

Async Sub MainAsync()

	userInputEvts = ThisApplication.CommandManager.UserInputEvents
	AddHandler userInputEvts.OnSelect, AddressOf userInputEvts_OnSelect
	Dim selectedSomething = Await pickTcs.Task

	If (selectedSomething) Then
		Logger.Debug("Something selected: {0}", selectedSomething)
	End If

	Dim drwWeldSymbol As DrawingWeldingSymbol = TryCast(pickedObject, DrawingWeldingSymbol)
	If (Not drwWeldSymbol Is Nothing) Then
		Logger.Debug("DrawingWeldingSymbol picked")
	End If
End Sub

Private Sub userInputEvts_OnSelect(justSelectedEntities As ObjectsEnumerator, ByRef moreSelectedEntities As ObjectCollection, selectionDevice As SelectionDeviceEnum, modelPosition As Point, viewPosition As Point2d, view As Inventor.View)
	If (justSelectedEntities.Count > 0) Then
		pickedObject = justSelectedEntities(1)
		RemoveHandler userInputEvts.OnSelect, AddressOf userInputEvts_OnSelect
		pickTcs.SetResult(True)
	End If
End Sub
		

[bradeneuropeArthur]

@Michael.Navara ,

Good job thanks.

I have learned something new also.

Where did you find this, or how did you come to this idea?

[Michael.Navara]

I know there are two events for selection UserInputEvents.OnSelect and SelectEvents.OnSelect both of them I used before. The first one is useful when you need to process any (relevant) entity selected by user, the second one is useful when you need to control what can be selected. 

The rest is an implementation of  StackOverflow post mentioned above.

And also I like this challenges.

I hope it helps.