[BUG] Revision Table Active Row

[MechMachineMan]

There is some issue with the functionality of the active row and the only workaround I am aware of isn't ideal.

In a revision table, if you use "insert row", it does not make it the active row. The only current way I am aware of to change the active row is to use the "add row" feature, copy the data into that row, and the old row.

In order to prevent this workaround of copy/pasting I tried writing a simple iLogic rule to allow the user to switch it via API.

Although the API says ".IsActiveRow" is a read-write property, the below code errors out when I try to set it. Thinking it may be because it cannot have 2 active rows, I tried disabling it first, but even that did not work.

Sub Main()

    'kDrawingRevisionTableFilter    16904    Drawing revision table filter.
    oRevTable = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingRevisionTableFilter, "Select Rev Table")
    
    Dim oRow As RevisionTableRow
    
    For Each oRow In oRevTable.RevisionTableRows
        If oRow.IsActiveRow = True Then
            oActiveRow = oRow(1).Text
        End If
    Next
    
    Dim oNewActiveRow As String
    oNewActiveRow = InputBox("Select New Active Row", "MacroMagic", oActiveRow)
    
    For Each oRow In oRevTable.RevisionTableRows
        If oRow(1).Text = oActiveRow Then
            oRow.IsActiveRow = False
        End If
    Next    
    
    MsgBox("Active row removed!")
    
    For Each oRow In oRevTable.RevisionTableRows
        MsgBox(oRow(1).Text & vbLf & oNewActiveRow)
        If oRow(1).Text = oNewActiveRow Then
            oRow.IsActiveRow = True  
        End If
    Next

    MsgBox("Active row set!" & vblf & vblf & "Please open rev table dialog and double check")    

End Sub
 

[Ruffy85]

@MechMachineMan

i tried to reproduce trough the normal way, manually in the drawing. i noticed that there is a Button with insertrow and Insertrevisionrow.

If you use insertrow, i can follow you, but with insertrevisionrow. the new row is the active one and the revision bumped up.

Maybe this helps?

[chandra.shekar.g]

Hi @MechMachineMan,

iLogic code works fine with little changes. This code is tested for following revision table.

Sub Main()

    'kDrawingRevisionTableFilter    16904    Drawing revision table filter.
    oRevTable = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingRevisionTableFilter, "Select Rev Table")
    
    Dim oRow As RevisionTableRow
    
    For Each oRow In oRevTable.RevisionTableRows
        If oRow.IsActiveRow = True Then
            oActiveRow = oRow(2).Text
        End If
    Next
    
    Dim oNewActiveRow As String
    oNewActiveRow = InputBox("Select New Active Row", "MacroMagic", oActiveRow)
   

    For Each oRow In oRevTable.RevisionTableRows
        If oRow(1).Text = oActiveRow Then
            oRow.IsActiveRow = False
        End If
    Next    
    
    MsgBox("Active row removed!")
    
    For Each oRow In oRevTable.RevisionTableRows
        MsgBox(oRow(1).Text & vbLf & oNewActiveRow)
        If oRow(1).Text = oNewActiveRow Then
            oRow.IsActiveRow = True  
        End If
    Next

    MsgBox("Active row set!" & vbLf & vbLf & "Please open rev table dialog and double check")    

End Sub

Can you please sample revision table to test iLogic code?

Thanks and regards,

[MechMachineMan]

Hmm. Interesting.

I have it consistently working for the default revision block now.

Whenever I set oRevNumberColumn to 2 ( for my table) and try running it on my custom style table, it fails.

Sub Main()
	
	Dim oRevNumberColumn As Integer
	oRevNumberColumn = 2

	Dim oRevTable As RevisionTable
        oRevTable = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingRevisionTableFilter, "Select Rev Table")
	
	Dim oRow As RevisionTableRow
	Dim oActiveRow As String
	
	For Each oRow In oRevTable.RevisionTableRows
		If oRow.IsActiveRow = True Then
			oActiveRow = oRow(oRevNumberColumn).Text
		End If
	Next
	
	Dim oNewActiveRow As String
	oNewActiveRow = InputBox("Select New Active Row", "MacroMagic", oActiveRow)
	If oNewActiveRow = "" Then: Exit Sub: End If

	For Each oRow In oRevTable.RevisionTableRows
		If oRow(oRevNumberColumn).Text = oNewActiveRow Then
			oRow.IsActiveRow = True
		End If
	Next

End Sub

Error Trace:

System.Runtime.InteropServices.COMException (0x80004005): Unspecified error (Exception from HRESULT: 0x80004005 (E_FAIL))
   at System.RuntimeType.ForwardCallToInvokeMember(String memberName, BindingFlags flags, Object target, Int32[] aWrapperTypes, MessageData& msgData)
   at Inventor.RevisionTableRow.set_IsActiveRow(Boolean )
   at LmiRuleScript.Main()
   at Autodesk.iLogic.Exec.AppDomExec.ExecRuleInAssembly(Assembly assem)
   at iLogic.RuleEvalContainer.ExecRuleEval(String execRule)

[dgreatice]

Hi.

I think class "IsActiveRow" just for Revision Row. Not For Custom Row.

I check this with.

Sub Main()

Dim oRevNumberColumn As Integer
oRevNumberColumn = 2

Dim oRevTable As RevisionTable
        oRevTable = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingRevisionTableFilter, "Select Rev Table")

Dim oRow As RevisionTableRow
Dim oActiveRow As String

For Each oRow In oRevTable.RevisionTableRows
If oRow.IsActiveRow = True Then
oActiveRow = oRow(oRevNumberColumn).Text
End If
Next

Dim oNewActiveRow As String
oNewActiveRow = InputBox("Select New Active Row", "MacroMagic", oActiveRow)
If oNewActiveRow = "" Then: Exit Sub: End If

For Each oRow In oRevTable.RevisionTableRows
If oRow(oRevNumberColumn).Text = oNewActiveRow Then

If oRow.Custom = True then

oRow.IsActiveRow = True

else

msgbox "This Row are Custom Row"

end if
End If
Next

End Sub

[chandra.shekar.g]

Hi @MechMachineMan,

Can you please provide Revision table details?

Screenshot also fine.

Thanks and regards,

[MechMachineMan]

It's just a custom rev table style that is organized:

Rev     |        Date     |      By      |    Description

Thanks,

[chandra.shekar.g]

Hi @MechMachineMan,

You are right!!!

Unable to set the value for RevisionTableRow.IsActiveRow property. I am checking the same with Engineering team. After hearing from team, I will get back to you.

Thanks and regards,

[chandra.shekar.g · Accepted solution]

Hi @MechMachineMan,

I heard back from Engineering team, Setting RevisionTableRow.IsActiveRow property from False to True is possible which makes Inactive to Active row. But, setting RevisionTableRow.IsActiveRow property from True to False will raise error. Because one of the row must be active.

So, the following iLogic code throws error message if that row is active.

For Each oRow In oRevTable.RevisionTableRows
        If oRow(1).Text = oActiveRow Then
            oRow.IsActiveRow = False
        End If
Next 

Please feel free to contact if there is any queries.

If solves problem, click on "Accept as solution" / give a "Kudo".

Thanks and regards,

[dgreatice · Accepted solution]

Hi @chandra.shekar.g

I think you miss understood. @MechMachineMan want try to activated Custom Row (Create from Insert Row at Revision Table)

To Activate Revision Row (Created From "Add Revision Row") is no problem.

like I said "I think class "IsActiveRow" just for Revision Row. Not For Custom Row".

Why must use Custom Row that created with "Insert Row" at Revision Table?

For most people, they use "Add Revision Row" because automatically will update Revision Number at Properties.

[MechMachineMan]

Thanks @dgreatice & @chandra.shekar.g.

That makes sense about the custom row. I think it's what I was missing before as it would work in some cases, but not others. Seems interesting how it makes there is the custom row set up there that is so easily confused with the "Add Row" of the UI. It seems like most users would think 'What's the difference?' or click the first button they see.

Anyhow, the code below works for all intents and purposes, within this limitation.

Sub Main()
	
	Dim oRevNumberColumn As Integer
	oRevNumberColumn = 1

	Dim oRevTable As RevisionTable
        oRevTable = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingRevisionTableFilter, "Select Rev Table")
	
	Dim oRow As RevisionTableRow
	Dim oActiveRow As String

	'Custom Row Check
	For m = 1 To oRevTable.RevisionTableRows.Count
		If oRevTable.RevisionTableRows.Item(m).Custom = True Then
			oCustomString = oCustomString & vbLf & m
		End If
	Next
	
	If Not oCustomString Is Nothing
		MsgBox("Custom Rows (cannot be activated): " & vbLf & oCustomString)
		Exit Sub
	End If
	
	'Find Active Row
	For Each oRow In oRevTable.RevisionTableRows
		If oRow.IsActiveRow = True Then
			oActiveRow = oRow(oRevNumberColumn).Text
		End If
	Next
	
	'Set New ActiveRow
	Dim oNewActiveRow As String
	oNewActiveRow = InputBox("Select New Active Row", "MacroMagic", oActiveRow)
	If oNewActiveRow = "" Then: Exit Sub: End If

	For Each oRow In oRevTable.RevisionTableRows
		If oRow(oRevNumberColumn).Text = oNewActiveRow Then
			oRow.IsActiveRow = True
		End If
	Next

End Sub