TabName as Filename

[SAFizzy]

Hello to all

i have small lisp to change tabname as file name, but i want this to be used as batch/Multiple files name. can some one help into modify this lisp.

(DEFUN C:RRT ()
(command "-layout" "rename" "" (vl-filename-base (getvar "dwgname")))
(princ)
)

Regards

[dbhunia · Accepted solution]

---

@SAFizzy wrote:

Hello to all

i have small lisp to change tabname as file name, but i want this to be used as batch/Multiple files name. can some one help into modify this lisp.

...........

---

you can try the approach of This post

(defun c:BatchJob (/ dwgs file dwgName scrFile folderName)
  (setq folderName
  (browsefolder "Select folder to perform batch job: ")
  )
  (setq dwgs (vl-directory-files folderName "*.dwg"))
  (setq scrFile (open (strcat folderName "\\batchJob.scr") "w"))
  (foreach file dwgs
	(setq dwgName (strcat "\"" folderName "\\" file "\""))
	(write-line ".Open" scrFile) 
	(write-line dwgName scrFile)
	(write-line "-layout rename  (vl-filename-base (vla-get-Name (vla-get-ActiveDocument (vlax-get-acad-object))))" scrFile)
	(write-line ".Qsave" scrFile)
	(write-line ".close" scrFile)

  )	 
  (close scrFile)  
  (command ".script" (strcat folderName "\\batchJob.scr"))
  (princ)
)	
;;; Function to browse folder
;;; This code was originally posted by kpblc2000 in AUGI AutoLisp Forum
;;;
(defun browsefolder (title / shlobj folder fldobj)
  (vl-load-com)
  (setq shlobj (vla-getinterfaceobject (vlax-get-acad-object) "Shell.Application")
		folder (vlax-invoke-method shlobj 'browseforfolder 0 title 0)
  )
  (vlax-release-object shlobj)
  (if folder
	(progn
	  (setq fldobj(vlax-get-property folder 'self)
			folderName (vlax-get-property fldobj 'path)
	  )
	  (vlax-release-object folder)
	  (vlax-release-object fldobj)
	  folderName
	)
  )
)
(princ)

[SAFizzy]

@dbhunia 

Thanks for help

exactly what i needed