Mutileader block attribute
@H_franco wrote:
I have the following lisp routine that edit attribute values inside a multileader, however when I attached a block with more than one attribute the values is the same for all attribute definitions. I truly want just to change the value of ONE attribute definition and not the rest. Can anyone help me?
In cases like that, what you need is routine that targets a specfic TAG name or otherwise use the first attribute definition, but in your block, the target is not even the first one, which means you need to specify the TAG name. Also there are issues not using a standard naming with a blocks and etc.
To make a routine truly universal, you have to take into account every possble scenario.
3 ways you can do this.
1 Hard code the TAG name in the code
2. Prompt for a tag name to find. <---- that is if user happen to know the tag name.
3. Select the target attribute as reference before selecting the blocks to be processed. but then again there are blocks using same TAG names in a single block (crazy isnt it? ) [ and also too much work ]
We will stick Option 1 for now
(defun c:Demo (/ _MLAttValue BlockColl ss i e f)
(vl-load-com)
;;; pBe 22May2013 ;;;
;; Demo for Mtext Block Attribute ;;;
(defun _MLAttValue (en et tag coll m / n i attag)
(setq n -1
i (1- (vla-get-count et))
)
(while (and (null attag) (< n i))
(if
(And
(eq "AcDbAttributeDefinition"
(vla-get-ObjectName (setq x (vla-item et (setq n (1+ n)))))
)
(eq tag (vla-get-TagString x))
(setq attag (vla-getBlockAttributeValue en (setq ID (vla-get-ObjectID x))))
)
(if m (vla-SetBlockAttributeValue en ID m) attag)
)
)
)
(setq BlockColl
(vla-get-blocks
(vla-get-ActiveDocument (vlax-get-acad-object)))
blocklist '("TAG-HEX-TXT3" "_TagBox");< Add as may block names
TAG "XX" ;<-- hard coded tag name
)
(if (and (setq str (getstring t "\nSpecify new attribute value: "))
(setq ss (ssget "_:L" '((0 . "MULTILEADER"))))
)
(repeat (setq i (sslength ss))
(setq e (vlax-ename->vla-object (ssname ss (setq i (1- i)))))
(if (setq matrb (member (vla-get-ContentBlockName e) blocklist))
(_mlattvalue
e
(vla-item BlockColl (car matrb))
TAG
BlockColl str
)
)
)
)
(princ)
)
@Sea-Haven wrote:
You forgot 4
You can change an attribute knowing the order of the attributes when looping through attributes if = x y then update attribute. All att tags can be same.
Like you said though re-order the block and version 4 does not work now.
True, that is another option, need to get back on that, I almost had it. its a mix between lisp and .NET. I got the order and dynamic property figured out, but when i inserted the block, the default values are swapped, minor thing ( i think )
I'll keep you posted.
@H_franco wrote:
I updated the lisp based on the comments. If i stay with option 3 i will have to keep my tags names short hahahaha. but I have modified this lisp multiple times already and i remember having an small dialog to identified which tag i want to update but i dont remember save it that version, I know that included tag names for sure.
If you want option 3 we can do that.BUT i will not edit "LM:setmleaderblockattributevalues" routine.
We will need one from LeeMac's collection LM:List Box
(defun c:pbedml (/ _MLAttValue _HowMayTagsBuddy BlockColl str tag ss i e nm f blocklist)
(vl-load-com)
;;; pBe 22May2019 | Demo for Mtext Block Attribute ;;;
(defun _HowMayTagsBuddy (nm / tags sel)
(Vlax-for itm (Vla-item BlockColl nm)
(if (eq (vla-get-ObjectName itm) "AcDbAttributeDefinition")
(setq tags (cons (vla-get-TagString itm) tags))
)
)
(if (and tags
(or (and (= (length tags) 1) (setq sel tags))
(setq sel (LM:listbox "Select TAG to modfiy" tags 0)))
)
(list nm (car sel)))
)
(defun _MLAttValue (en et tag coll m / n i attag)
(setq n -1 i (1- (vla-get-count et)))
(while (and (null attag) (< n i))
(if
(And
(eq "AcDbAttributeDefinition"
(vla-get-ObjectName (setq x (vla-item et (setq n (1+ n)))))
)
(eq tag (vla-get-TagString x))
(setq attag (vla-getBlockAttributeValue en (setq ID (vla-get-ObjectID x))))
)
(if m (vla-SetBlockAttributeValue en ID m) attag)
)
)
)
(setq BlockColl (vla-get-blocks
(vla-get-ActiveDocument (vlax-get-acad-object)))
)
(if (and (setq str (getstring t "\nSpecify new attribute value: "))
(setq ss (ssget "_:L" '((0 . "MULTILEADER"))))
)
(repeat (setq i (sslength ss))
(setq e (vlax-ename->vla-object (ssname ss (setq i (1- i))))
nm (vla-get-ContentBlockName e))
(if (setq TAG
(if (setq f (assoc nm blocklist))
(cadr f)
(cadar (setq blocklist (cons
(_HowMayTagsBuddy nm) blocklist)))
)
)
(_mlattvalue e (vla-item BlockColl nm)
TAG BlockColl str
)
)
)
)
(princ)
)
The way it works is:
- It would ask the user to select the target tag name only there are more than one attribute on the contentBlockname. otherwise it will modify the single attribute.
- IT will only ask the user once per block name while processing the selected MleaderStyle
- Deposit the payment to 112 66 101 58 85 83 36 32 79 78 76 89 32 80 76 69 65 83 69 for stagerring amount of
HTH
