Join multiple Dtext contents

[Anonymous]

Hi all.

Is there a lisp to join two "dtext" text contents in one single text line? Maybe all the text on the same Text Alignment Y value?

[ronjonp · Accepted solution]

Another one for fun 🙂

(defun c:foo (/ a i s)
  (cond	((setq s (ssget ":L" '((0 . "text"))))
	 (setq s (vl-remove-if 'listp (mapcar 'cadr (ssnamex s))))
	 (setq
	   s (mapcar '(lambda (x) (list x (cdr (assoc 1 (entget x))) (cdr (assoc 10 (entget x))))) s)
	 )
	 (setq s (vl-sort s '(lambda (r j) (< (caaddr r) (caaddr j)))))
	 (while	(setq i (car s))
	   (setq a (vl-remove-if-not '(lambda (x) (equal (cadr (last x)) (cadr (last i)) 1e-2)) s))
	   (entmod (append (entget (car i)) (list (cons 1 (apply 'strcat (mapcar 'cadr a))))))
	   (and (> (length a) 1) (mapcar 'entdel (cdr (mapcar 'car a))))
	   (mapcar '(lambda (x) (setq s (vl-remove x s))) a)
	 )
	)
  )
  (princ)
)(vl-load-com)

[Anonymous]

Thank you.

[ronjonp]

You're welcome 🙂

[duynhat151092]

Hello
Can you help me with this lisp vertically.

Thank.

[duynhat151092]

Hello
Can you help me with this lisp vertically.

Thank.

[patrickBG24Z]

Just what I was looking for! Thanks