Join multiple Dtext contents
Hi dlanorh
Thank you. I have a solution like that, but I need something to join all the text in a dwg file. See image attached.
In this example I need to join 2P6Ø6.3 with C=3.3. All of them.
@Anonymous wrote:
.... I need to join all the texts with only one selection. I need to put the texts together, but I have a file with lots of texts to put together. I needed to do this with a single selection. ... AutoCAD has TXT2MTXT ... , but I have to do one by one.
TXT2MTXT doesn't require you to select them one by one, if that's what you're saying. What should be the effect of the drawing order of the selected Text objects, if you select them all at once? Does the result need to be in positional order as TXT2MTXT does it, whether or not that's the same as the drawing order? It wouldn't be hard to make a routine if it can use drawing order, but that won't do if it's not going to give you the desired result.
I have a routine that requires you to select them one by one, because it uses the selection order for combining the contents, but you can pick as many as you want all in one command. It's OneMtext.lsp, available >here<. You would use the 1MT0 command in it, which puts a space [i.e. zero Enters] between the contents of each selected Text object in the overall combined result. [The other commands in it put 1 or 2 Enters to start a new line, without or with a blank line between, for each one's contents.] Unlike TXT2MTXT, it accepts selection of both plain-Text and Mtext objects. After using it, if you want it all strung out as one Text object as your description implies [I'm not sure that's what you meant], you could pick the result and in the Properties Palette, set its Defined width to zero and then Explode it.
EDIT: Your image came in while I was writing the above. That's a little different than what I understood from your initial description, though I now see I mis-read part of it. You just want to combine pairs of Text objects, separately from other pairs [i.e. not all together into one overall combined one], but with mass selection? The difficulty would seem to be in getting a routine to decide which pairs go together, but if the paired ones are always adjacent in drawing order, or if their Y coordinates always match and never match those of any other pair, it could probably be done.
Kent Cooper, AIA 
Accepted solution
Paulo,
Check this one called TxtConcat (it's simple and works 
)
concatenatination (join) texts is base on alignment [(start,align, center,middle, fit, end) they must share the same aligment] and of cours same Y Coords. the join will be from left to right.
the text value is not restricted (e.g they must not have P or C inside) in could be anything.
enjoy
Moshe
(defun C:TxtConcat (/ isAlreadyExist formatX formatY Y&Align X&Object ; local functions
ss i data^ ename0 elist0 elist1 c72 item0 item1 text1 lst0 lst1)
(defun isAlreadyExist (item1)
(vl-some
'(lambda (item0)
(if (and
(equal (car item0) (car item1) 0.01)
(= (cadr item0) (cadr item1))
)
item0
)
)
data^
)
); isAlreadyExist
; return formated X coords
(defun formatX ()
(atof (rtos (car p0) 2 2))
)
; return formated Y coords
(defun formatY ()
(atof (rtos (cadr p0) 2 2))
)
; return formated X coords + text entity name
(defun X&Object ()
(list (formatX) ename)
)
; return formated Y coords + text alignment
(defun Y&Align ()
(list (formatY) c72)
)
; here starts C:TxtConcat
(setvar "cmdecho" 0)
(command "._undo" "_begin")
(if (setq ss (ssget ":L" '((0 . "text"))))
(progn
(setq i -1 data^ '())
(repeat (sslength ss)
(setq i (1+ i) elist0 (entget (setq ename (ssname ss i))))
(setq c72 (cdr (assoc '72 elist0)))
(if (or (= c72 0) (= c72 3))
(setq p0 (cdr (assoc '10 elist0)))
(setq p0 (cdr (assoc '11 elist0)))
)
; Build database
(if (setq item0 (isAlreadyExist (Y&Align)))
(setq data^ (cons (append item0 (list (X&Object))) (vl-remove item0 data^)))
(setq data^ (cons (list (formatY) c72 (X&Object)) data^))
)
); repeat
; Concatenate texts from left to right
; base on text Alignment and Y coords
(foreach item0 data^
(if (> (vl-list-length (setq lst0 (cddr item0))) 1)
(progn
; sort list base on X coords, from left to right
(setq lst1 (vl-sort lst0 (function (lambda (x0 x1) (< (car x0) (car x1))))))
(setq elist1 (entget (cadr (car lst1)))); get first text
(setq text1 (cdr (assoc '1 elist1)))
(foreach item1 (cdr lst1)
(setq text1 (strcat text1 " " (cdr (assoc '1 (entget (cadr item1)))))) ; concatenate texts
(entdel (cadr item1))
)
(entmod (subst (cons '1 text1) (assoc '1 elist1) elist1)); update database
); progn
); if
); foreach
); progn
); if
(command "._undo" "_end")
(setvar "cmdecho" 1)
(princ)
)
Accepted solution
find this line in the code and remove " " that's it !
save the file and you officialy declared as co-shared coder
(setq text1 (strcat text1 " " (cdr (assoc '1 (entget (cadr item1))))))