Converse string to list

[Browning_Zed]

Dear forum members, help.
How can a string be converted to a list?
"100,250,50"    >>>    '(100 250 50)

This is as an example. That is, when converting, the "x, x, x" pattern must be parsed into '(x x x).

[Kent1Cooper]

Will they always be whole numbers?  It makes a difference to which AutoLisp function is most appropriate to convert the pieces of text string to the numbers in the final list.

[Kent1Cooper · Accepted solution]

---

@Kent1Cooper wrote:

Will they always be whole numbers?  ....

---

If they are, this seems to do it:

(defun TCD2LN ; = Text Comma-Delimited {to} List of Numbers
  (txt / LN)
  (while (wcmatch txt "*`,*"); still any comma(s)?
    (setq
      LN (cons (atoi (substr txt 1 (vl-string-position 44 txt))) LN)
      txt (substr txt (+ (vl-string-position 44 txt) 2))
    ); setq
  ); while
  (reverse (cons (atoi txt) LN)); add last number
); defun

Command: (TCD2LN "123,456,789")
(123 456 789)

Command: (TCD2LN "1,12,123,1234")
(1 12 123 1234)

It does not check whether the supplied text string is appropriate, but could be made to.

[Browning_Zed]

Yes, it will always be whole numbers. Thank you for your help.

[pbejse · Accepted solution]

---

@Browning_Zed wrote:

Yes, it will always be whole numbers. Thank you for your help.

---

Another

(Defun _SNL (str);<-- String Numbers to List
(read (strcat "(" 
	(vl-string-translate  "," " " str) ")" 	))
  )

_SNL
_$ (_SNL "100,250,50")
(100 250 50)
_$ (_SNL "1,12,123,1234")
(1 12 123 1234)

HTH

[pbejse]

Re: Converse string to list 

A literal solution  😊

[Sea-Haven]

May be known as laces only $10 add to shopping LIST.