Community
Dynamic Blocks with fields that reference the block instance are a bit tricky. They will only update if you invoke a dynamic action for the specific block.
So just inserting and mirroring will not trigger any field in the block that uses the block properties to update, but you first need to switch i.e. a visibility parameter to activate them, even if the dynamic action itself doesn't change or do any thing at all.
Formulas in blocks will be even more difficult and I do not have any experience with them myself.
But....you are referring to a dynamic block. So instead of mirroring, you can use a flip parameter. With the Extract Data tool you can create a table and/or Excel to extract all blocks and the current state of the parameter.
And if you want to have an attribute, that is also possible. By default an empty value, but If the block gets flipped give it a value of -1.
See example block, it contains a visibility, flip & block properties parameter. After insertion you can select the block and switch from normal to mirrored state and vice versa.
Here's a way also working on AutoCAD MAC (requires AutoCAD 2012 or later).
EDIT: this one works whatever the block name
(defun c:test (/ ss i br)
(if (setq ss (ssget "_X" '((0 . "insert") (66 . 1))))
(repeat (setq i (sslength ss))
(setq br (ssname ss (setq i (1- i))))
(vl-catch-all-apply
'setpropertyvalue
(list br
"MIRROR"
(strcat
(if (minusp (car (getpropertyvalue br "ScaleFactors")))
"-"
" "
)
(getpropertyvalue br "MIRROR")
)
)
)
)
)
(princ)
)
Sorry, my mistake.
Here's new version which only add a suffix ("-" or " ") if it does not already exists (it also removes wrong suffixes).
(defun c:test (/ ss i br)
(if (setq ss (ssget "_X" '((0 . "insert") (66 . 1))))
(repeat (setq i (sslength ss))
(setq br (ssname ss (setq i (1- i))))
(vl-catch-all-apply
'(lambda (/ val)
(setq val (getpropertyvalue br "MIRROR")
suf (substr val (strlen val))
)
(if (minusp (car (getpropertyvalue br "ScaleFactors")))
(if (/= suf "-")
(setpropertyvalue br "MIRROR" (strcat (vl-string-right-trim " " val) "-"))
)
(if (/= suf " ")
(setpropertyvalue br "MIRROR" (strcat (vl-string-right-trim "-" val) " "))
)
)
)
)
)
)
(princ)
)
Now talking about optimization, here's a version which neither select all attributed blocks references nor iterate through all entities in model spaces.
It first iterate through the block table looking for block definitions with a MIRROR attribute (as @DannyNL's last routine) and then, for each found block definition, directly get all inserted references.
(defun c:test (/ massoc getAllReferences addSuffix hasMirrorAtt block)
(defun massoc (key alst)
(if (setq alst (member (assoc key alst) alst))
(cons (cdar alst) (massoc key (cdr alst)))
)
)
(defun getAllReferences (bname / blk)
(if (setq blk (tblobjname "BLOCK" bname))
(vl-remove-if
(function (lambda (x) (null (entget x))))
(massoc 331 (entget (cdr (assoc 330 (entget blk)))))
)
)
)
(defun addSuffix (br / val suf)
(setq val (getpropertyvalue br "MIRROR")
suf (substr val (strlen val))
)
(if (minusp (car (getpropertyvalue br "ScaleFactors")))
(if (/= suf "-")
(setpropertyvalue br "MIRROR" (strcat (vl-string-right-trim " " val) "-"))
)
(if (/= suf " ")
(setpropertyvalue br "MIRROR" (strcat (vl-string-right-trim "-" val) " "))
)
)
)
(defun hasMirrorAtt (blk / ent found elst)
(setq ent (cdr (assoc -2 blk)))
(while (and ent (not found))
(if (and (= (cdr (assoc 0 (setq elst (entget ent)))) "ATTDEF")
(= (cdr (assoc 2 elst)) "MIRROR")
)
(setq found T)
(setq ent (entnext ent))
)
)
found
)
(while (setq block (tblnext "BLOCK" (not block)))
(if (hasMirrorAtt block)
(foreach br (getAllReferences (cdr (assoc 2 block)))
(addSuffix br)
)
)
)
(princ)
)
@DannyNL, from the tests I did (mainly with .NET but it should be similar with LISP) a filtered select all (ssget "_X" ...) is not faster than iterating through all enities in the drawing and filter them. Internally a select all does through all enities in the drawing.
The getAllReferences function is faster because it directly access to the enames of the block references which are stored in the BLOCK_RECORD of the bloc definition.
@_gile Thanks for the info. Learned something new today 
In my mind it was assumed to be faster, also because it is space independent compared to iterating through modelspace. But I'm intrigued by your way of selecting and will dive into it in more detail and learn an alternative way of selecting the references myself as well.
You caught me just before heading home for dinner
But in that case I'm going to revert back to my old code that iterates through all objects in modelspace with the modification of adding/removing a suffix.
If needed I can look into it more tomorrow and spend some more time on it.
For now this should work
(defun c:Test (/ T_TagSearch T_TagValue T_ActiveDoc T_Blocks T_AttribFound T_BlockList )
(setq T_TagSearch "MIRROR")
(setq T_TagValue "-")
(setq T_Blocks (vla-get-Blocks (setq T_ActiveDoc (vla-get-ActiveDocument (vlax-get-acad-object)))))
(vlax-for T_BlockDef T_Blocks
(if
(and
(= (vla-get-IsLayout T_BlockDef) :vlax-false)
(= (vla-get-IsXref T_BlockDef) :vlax-false)
)
(progn
(setq T_AttribFound nil)
(vlax-for T_Object T_BlockDef
(if
(and
(not T_AttribFound)
(= (vla-get-ObjectName T_Object) "AcDbAttributeDefinition")
(= (vla-get-TagString T_Object) T_TagSearch)
)
(setq T_BlockList (cons (vla-get-Name T_BlockDef) T_BlockList))
)
)
)
)
)
(if
T_BlockList
(progn
(vla-StartUndoMark T_ActiveDoc)
(vlax-for T_Object (vla-get-ModelSpace T_ActiveDoc)
(if
(and
(= (vla-get-ObjectName T_Object) "AcDbBlockReference")
(= (vla-get-HasAttributes T_Object) :vlax-true)
(member (vla-get-EffectiveName T_Object) T_BlockList)
)
(foreach T_Attribute (vlax-safearray->list (vlax-variant-value (vla-GetAttributes T_Object)))
(if
(= (vla-get-TagString T_Attribute) T_TagSearch)
(cond
(
(and
(minusp (vla-get-XScaleFactor T_Object))
(not (wcmatch (setq T_TagString (vla-get-TextString T_Attribute)) (strcat "*" T_TagValue)))
)
(vla-put-TextString T_Attribute (strcat T_TagString T_TagValue))
)
(
(and
(not (minusp (vla-get-XScaleFactor T_Object)))
(wcmatch (setq T_TagString (vla-get-TextString T_Attribute)) (strcat "*" T_TagValue))
)
(vla-put-TextString T_Attribute (substr T_TagString 1 (- (strlen T_TagString) (strlen T_TagValue))))
)
)
)
)
)
)
(vla-EndUndoMark T_ActiveDoc)
)
)
(mapcar 'vlax-release-object (list T_Blocks T_ActiveDoc))
(princ)
)
Forums Links
Can't find what you're looking for? Ask the community or share your knowledge.
Post to forums
