Strange SelectionSets behaviuor
I cleaned up your code. Here are a few suggestions. Always post your code in a code window (use the </> button in the post menu). Always use Option Explicit at the top of your module, it reminds you to dimension your variables. In the lwp case, never dim a var with spelling the same as a class. My naming convention for variable names representing objects is to precede it with "o" for "object" and then a shortcut name for the class, i.e. "PL". Another method I use for more complex functions is a prefix for the type and a name representing it's use, i.e. "plWindowBoundary". Don't manually add a selection set. Use a function to trap for errors. I added mine for you. In your last MsgBox function, I reused the variable rather than going to the selectionsets collection.
There are two possible reasons why Count was zero. First, the sub adds the poly to ModleSpace. If you run the sub from PaperSpace, it won't find the pl. Second, it depends on how you selected the points for the window/pl. The Select method specifically calls point1 and then point 2. Then it creates a crossing window by reordering the points. So if you created your pl by picking upper right first and then lower left as if you were creating a crossing window, it would not work. To be more robust and allow the user, you would need to test the picked points to figure out which one was upper right and then supply the points to the Select function in the proper order.
Option Explicit
Sub test1()
Dim point1 As Variant
Dim point2 As Variant
point1 = ThisDrawing.Utility.GetPoint(, vbCr & "Specify first corner:")
point2 = ThisDrawing.Utility.GetCorner(point1, "Enter Other corner: ")
MsgBox "The point picked is" & point1(0) & ", " & point1(1) & "-" & point1(2) & "-----" & point2(0) & ", " & point2(1) & "-" & point2(2)
' the displayed cords are correct!
Dim dblPoints(0 To 3) As Double
dblPoints(0) = point1(0)
dblPoints(1) = point1(1)
dblPoints(2) = point2(0)
dblPoints(3) = point2(1)
Dim oPL As AcadLWPolyline
Set oPL = ThisDrawing.ModelSpace.AddLightWeightPolyline(dblPoints)
oPL.Layer = "0"
oPL.Update
' the line is correct on layout, it connects the two selected point!
Dim objSSet As AcadSelectionSet
Set objSSet = AddSelectionSet("mysel")
objSSet.Select acSelectionSetCrossing, point1, point2
objSSet.Highlight True
MsgBox ("SELECTION COUNT: " & objSSet.Count)
End Sub
Public Function AddSelectionSet(SetName As String) As AcadSelectionSet
' This routine does the error trapping neccessary for when you want to create a
' selectin set. It takes the proposed name and either adds it to the selectionsets
' collection or sets it.
On Error Resume Next
Set AddSelectionSet = ThisDrawing.SelectionSets.Add(SetName)
If Err.Number <> 0 Then
Set AddSelectionSet = ThisDrawing.SelectionSets.Item(SetName)
AddSelectionSet.Clear
End If
End Function
Ed
Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
How to post your code.
The code I posted works fine for me. If it doesn't work for you there may be something weird with your file. Please post a sample dwg that has the problem.
Ed
Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
How to post your code.
Accepted solution