How to add loads to a robot group selection (API)

[rbaXBU6W]

Hi All

I would like to add a simple uniform load to a group of elements (Bars) that i have in my model through API. 

I cannot seem to find any code that works... Can anyone help?

[Stephane.kapetanovic · Accepted solution]

hi @rbaXBU6W 

Sub Apply_UniformLoad_To_Bars_List()
  Dim RobApp As IRobotApplication
  Set RobApp = New RobotApplication
  
  Dim Cases As RobotCaseServer
  Dim Cas As IRobotSimpleCase
  Set Cases = RobApp.Project.Structure.Cases
  Set Cas = Cases.CreateSimple(1, "UNIFORM_LOAD", I_CN_EXPLOATATION, I_CAT_STATIC_LINEAR)
  
  Dim Rec As IRobotLoadRecord
  Set Rec = Cas.Records.Create(I_LRT_BAR_UNIFORM)
  Rec.SetValue IRobotBarUniformRecordValues.I_BURV_PZ, -1000
  Rec.Objects.FromText "1 2 3 4"
  
  RobApp.Project.ViewMngr.Refresh
  Set RobApp = Nothing
End Sub

Best regards

[rbaXBU6W]

Hi @Anonymous
Thanks for the help, but i need to assign the load to a group of bar members not choose the bars manually like your code

[Stephane.kapetanovic · Accepted solution]

hi @rbaXBU6W 

Add this function to search the group list of bars by its name : 

Function GetListByGroup(RobApp As IRobotApplication, GroupName As String) As String
  Dim GroupBars As RobotGroup
  Dim RGroups As RobotGroupServer: Set RGroups = RobApp.Project.Structure.Groups
  Dim BarType As IRobotObjectType:  BarType = IRobotObjectType.I_OT_BAR
  Dim GroupBarsCnt As Integer: GroupBarsCnt = RGroups.GetCount(BarType)
  For i = 1 To GroupBarsCnt
    Set GroupBars = RGroups.Get(BarType, i)
    If GroupBars.name = GroupName Then
      GetListByGroup = GroupBars.SelList: Exit Function
    End If
  Next i
  GetListByGroup = ""
End Function

Modify previous code as follow:

Sub Apply_UniformLoad_To_Bars_List()
(...)

' Rec.Objects.FromText "1 2 3 4" < Previous Line
  Dim GroupName As String
  GroupName = "Rafter" 
  Rec.Objects.FromText GetListByGroup(RobApp, GroupName)
 
(...)
End Sub

Result:

Best regards

See also https://forums.autodesk.com/t5/robot-structural-analysis-forum/robot-api-apply-load-to-a-chain-of-ba...