【iLogic関連】外観ライブラリのAsset.itemプロパティの引数について

[masaya.sekido]

iLogicなどを使った　外観の変更に関して

ヘルプや海外フォーラム、サンプルなどでも良く出てくる

"generic_reflectivity_at_0deg　

　　↑反射率　直接光

などは分かるのですが、実際の外観ライブラリには

他にも多彩な表現があると思います。

赤枠以外の内容のfloat値など引数が不明です

何処かまとまった情報掲載先ご存じないでしょうか。 

INVENTOR2022

[HideoYamada · Accepted solution]

こんにちわ。

無いのなら

  作ってしまえ

    VBA

ということで、一覧を表示するコードを書きました。パーツファイルを開いて実行してください。

Option Explicit

Sub DumpAssetValues()
    Dim oAsset As Asset: Set oAsset = ThisApplication.ActiveDocument.ActiveAppearance
    Dim oAssetValue As AssetValue
    For Each oAssetValue In oAsset
        Dim ValueTypeName As String
        Select Case oAssetValue.ValueType
            Case AssetValueTypeEnum.kAssetValueTextureType
                ValueTypeName = "Texture"
            Case AssetValueTypeEnum.kAssetValueTypeBoolean
                ValueTypeName = "Boolean"
            Case AssetValueTypeEnum.kAssetValueTypeChoice
                ValueTypeName = "Choice"
            Case AssetValueTypeEnum.kAssetValueTypeColor
                ValueTypeName = "Color"
            Case AssetValueTypeEnum.kAssetValueTypeFilename
                ValueTypeName = "Filename"
            Case AssetValueTypeEnum.kAssetValueTypeFloat
                ValueTypeName = "Float"
            Case AssetValueTypeEnum.kAssetValueTypeInteger
                ValueTypeName = "Integer"
            Case AssetValueTypeEnum.kAssetValueTypeReference
                ValueTypeName = "Reference"
            Case AssetValueTypeEnum.kAssetValueTypeString
                ValueTypeName = "String"
            Case AssetValueTypeEnum.kAssetValueUnknownType
                ValueTypeName = "Unknown"
            Case Else
                ValueTypeName = "(Unknown)"
        End Select
        Debug.Print oAssetValue.DisplayName, oAssetValue.Name, ValueTypeName
    Next oAssetValue
End Sub

結果の一例

AssetLibID    AssetLibID    String
ExchangeGUID  ExchangeGUID  String
オブジェクトによる色        color_by_object             Boolean
共有          common_Shared_Asset         Choice
ティント カラー             common_Tint_color           Color
色空間        common_Tint_color_colorspace              Choice
ティント      common_Tint_toggle          Boolean
他のマテリアルから色を使用する            generic_ao_details          Boolean
最大距離      generic_ao_distance         Float
アンビエント オクルージョン generic_ao_on Boolean
サンプル      generic_ao_samples          Integer
背面非表示    generic_backface_cull       Boolean
量            generic_bump_amount         Float
バンプ        generic_bump_map            Color
カットアウト  generic_cutout_opacity      Float
色            generic_diffuse             Color
色空間        generic_diffuse_colorspace  Choice
イメージのフェード          generic_diffuse_image_fade  Float
光沢          generic_glossiness          Float
ハイライト    generic_is_metal            Boolean
反射 最大トレース デプス    generic_refl_depth          Integer
反射 光沢のあるサンプル     generic_reflection_glossy_samples         Integer
反射率        generic_reflectivity_at_0deg              Float
反射率        generic_reflectivity_at_90deg             Float
屈折深度に優先              generic_refr_depth          Integer
反射 光沢のあるサンプル     generic_refraction_glossy_samples         Integer
屈折          generic_refraction_index    Float
半透明        generic_refraction_translucency_weight    Float
他のマテリアルとブレンド    generic_roundcorners_allow_different_materials          Boolean
ラウンド コーナー           generic_roundcorners_radius Float
色温度        generic_self_illum_color_temperature      Float
フィルタ色    generic_self_illum_filter_map             Color
色空間        generic_self_illum_filter_map_colorspace  Choice
自己照明      generic_self_illum_luminance              Float
透過          generic_transparency        Float
イメージのフェード          generic_transparency_image_fade           Float
モード        mode          Integer

[masaya.sekido]

あ、そうか・・・ 流石です。

プロパティと同じですね・・・^_^;。頭が回りませんでした。

ありがとうございました。

[masaya.sekido]

iLogicで表示（参考）

Imports System.Windows.Forms

Sub main

    Dim oAsset As Asset: oAsset = ThisApplication.ActiveDocument.ActiveAppearance

    Dim oAssetValue As AssetValue

Dim ApperList As New ArrayList

    For Each oAssetValue In oAsset

        Dim ValueTypeName As String

        Select Case oAssetValue.ValueType

            Case AssetValueTypeEnum.kAssetValueTextureType

                ValueTypeName = "Texture"

            Case AssetValueTypeEnum.kAssetValueTypeBoolean

                ValueTypeName = "Boolean"

            Case AssetValueTypeEnum.kAssetValueTypeChoice

                ValueTypeName = "Choice"

            Case AssetValueTypeEnum.kAssetValueTypeColor

                ValueTypeName = "Color"

            Case AssetValueTypeEnum.kAssetValueTypeFilename

                ValueTypeName = "Filename"

            Case AssetValueTypeEnum.kAssetValueTypeFloat

                ValueTypeName = "Float"

            Case AssetValueTypeEnum.kAssetValueTypeInteger

                ValueTypeName = "Integer"

            Case AssetValueTypeEnum.kAssetValueTypeReference

                ValueTypeName = "Reference"

            Case AssetValueTypeEnum.kAssetValueTypeString

                ValueTypeName = "String"

            Case AssetValueTypeEnum.kAssetValueUnknownType

                ValueTypeName = "Unknown"

            Case Else

                ValueTypeName = "(Unknown)"

        End Select

        ApperList.Add("表示名:" & oAssetValue.DisplayName & Space(5) & "名称:" & oAssetValue.Name & Space(5) & "データ型:" & ValueTypeName)

ApperList.Add(oAssetValue.Name.ToString )

ApperList.Add("")

    Next oAssetValue

  Ret = InputListBox("外観一覧",ApperList,"","外観", "外観")

    MsgBox(Ret)

Clipboard.SetDataObject(Ret)

End Sub