Using ProgressBar.OnCancel Event

[MechMachineMan]

Application.CreateProgressBar( DisplayInStatusBar As Boolean, NumberOfSteps As Long, Title As String, [AllowCancel] As Boolean, [HWND] As Long ) As ProgressBar

Given the progress bar has the option to allow cancel, I was wondering how it is to be used within a Rule if it can even be used in that environment.

I have looked into the whole Handles and WithEvents thing, but have gotten lost. I don't have much background with programming aside from iLogic so I'm kind of stuck here.

ie; making the cancel button work for this snippet, directly in a rule:

Dim oProgressBar As Inventor.ProgressBar
oProgressBar = ThisApplication.CreateProgressBar(False, 10, "Test ProgressBar", True)

For j = 0 To 10
	oProgressBar.Message = ("Current Index: " & j & "/" & 10)
	Threading.Thread.Sleep(300)
	oProgressBar.UpdateProgress
Next

oProgressBar.Close

Any help would be appreciated.

Thanks! 

[MechMachineMan]

Any developments on this?

[MechMachineMan]

Hmmm....?

[ekinsb · Accepted solution]

I don't think iLogic is the best choice for something like this.  Writing code like this is quite painful just using the iLogic editor.  However, I was able to get it to work.  Here's the entire code of the rule.

Public Sub Main
    progBar = New TestProgressBar(ThisApplication)
    progBar.Start()
End Sub

Public Class TestProgressBar
    Private WithEvents progBar As Inventor.ProgressBar
    Private invApp As Inventor.Application

    Public Sub New(InventorApp As Inventor.Application)
        invApp = InventorApp
    End Sub

    Public Sub Start()
        progBar = invApp.CreateProgressBar(False, 10, "Test of Progress Bar", True)

        Dim j As Integer
        For j = 0 To 10
            progBar.Message = ("Current Index: " & j & "/" & 10)
            Threading.Thread.Sleep(1000)
            progBar.UpdateProgress()
        Next

        progBar.Close()
    End Sub

    Private Sub progBar_OnCancel() Handles progBar.OnCancel
        progBar.Close()
        MsgBox("Cancelled")
    End Sub
End Class

[MechMachineMan]

Thank-you for your troubles! That should work for what I need it to!

[Anonymous]

 @MechMachineMan

Do you know how to get the progBar_OnCancel() sub to exit the rule after closing the progress bar?

[Maxim-CADman77]

Judging by this cancelling iLogic rule is impossible.