Sketchblockcolor

[Anonymous]

I am trying to set the sketchblock layer color to red  in a part. What am i doing wrong??

Here is the code:

oline=ThisApplication.CommandManager.Pick(SelectionFilterEnum.kSketchBlockFilter,"Select a SketchBlock")
oBlock01=oline.ContainingSketchBlock
Dim oColor As Color
oColor = ThisApplication.TransientObjects.CreateColor(255, 0, 0)
oBlock01.Color.Setcolor=oColor

change 

[bradeneuropeArthur]

 Think you should do that curve by curve!

[Anonymous]

Ok, so how do you change the color of a simple line in a sketch? Keep in mind i am not talking about drawing documents but sketches in parts.......

[frederic.vandenplas]

Hi @Anonymous 

Please try this code (assuming it's ilogic)

Select a sketchblock in an active sketch and run the code below

If ThisApplication.ActiveDocument.SelectSet.Count = 1 Then
If ThisApplication.ActiveDocument.SelectSet.Item(1).Type = kSketchBlockObject Then

Dim oSketchBlock As SketchBlock
oSketchBlock = ThisApplication.ActiveDocument.SelectSet.Item(1)

oSketchBlock.Color = ThisApplication.TransientObjects.CreateColor(255, 0, 0)

End If
Else

MessageBox.Show( "Please select a sketchblock")
End If

[Anonymous]

I tried the code  but i get this error

[frederic.vandenplas]

Here it works inventor 2019 make sure in the options that you don't use straight vb code.
In inventor 2015 this does not seems to work, so maybe api in your current version is not supported?

[Sergio.D.Suárez]

There is a problem with the selection, this code is working but you must select the block from the browser, in the model tab inside the blocks folder that appears on the left

Dim oBlock As Inventor.SketchBlockDefinition 
oBlock = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kSketchBlockDefinitionFilter, "Select a SketchBlock in Browser")

Dim oColor As Color
oColor = ThisApplication.TransientObjects.CreateColor(255, 0, 0) 'Red

oBlock.Color = oColor
InventorVb.DocumentUpdate()

[frederic.vandenplas]

Hi @Sergio.D.Suárez 

Now i see that you use the sketchblockdefinition instead of the blockdefinition

SelectionFilterEnum.kSketchBlockFilter

Try this but you still must select it in the treeview

Dim oBlock As Inventor.SketchBlock
oBlock = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kSketchBlockFilter, "Select a SketchBlock in Browser")

Dim oColor As Color
oColor = ThisApplication.TransientObjects.CreateColor(255, 0, 0) 'Red

oBlock.Color = oColor
InventorVb.DocumentUpdate()

[frederic.vandenplas]

@Sergio.D.Suárez 

With this code you can select in the sketch itself.

Dim oBlock As Inventor.SketchLine
oBlock = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kSketchBlockFilter, "Select a SketchBlock in Browser")

Dim oColor As Color
oColor = ThisApplication.TransientObjects.CreateColor(255, 0, 0) 'Red

oBlock.Parent.Color = oColor
InventorVb.DocumentUpdate()

[bradeneuropeArthur]

this will change the blockcolor in the definition:

Public Sub ChangeBlockColor()
Dim a As Application
Set a = ThisApplication

Dim prt As PartDocument
Set prt = a.ActiveDocument

Dim comps As SketchBlockDefinitions
Set comps = prt.ComponentDefinition.SketchBlockDefinitions

Dim skbd As SketchBlockDefinition
Set skbd = comps.Item(1)

Dim x As Byte
Dim y As Byte
Dim z As Byte

x = 100
y = 100
z = 100

Dim oColor As Color
Set oColor = ThisApplication.TransientObjects.CreateColor(x, y, z)

skbd.Color = oColor
prt.Update

End Sub

[Anonymous · Accepted solution]

Thank you all for the help. This is the final working version of the code i have decided on. This way I can select the block in the sketch and not in the browsernode to change the color

Dim oDoc As Document
oDoc = ThisApplication.ActiveDocument


Dim oBlocks As SketchBlockDefinitions
oBlocks  = oDoc.ComponentDefinition.SketchBlockDefinitions

oline = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kSketchBlockFilter, "Select a SketchBlock")
oBlock01=oline.ContainingSketchBlock

For i=1 To oBlocks.count
    If InStr(1,oBlock01.Name ,oBlocks.item(i).Name) > 0 Then
        Dim skbd As SketchBlockDefinition
        skbd = oBlocks.Item(i)
        Dim oColor As Color
        oColor = ThisApplication.TransientObjects.CreateColor(255, 0, 0) 'Red
        skbd.Color = oColor
        InventorVb.DocumentUpdate()
    End If
Next

[Sergio.D.Suárez]

Dim oDoc As Document
oDoc = ThisApplication.ActiveDocument
Dim oColor As Color
oColor = ThisApplication.TransientObjects.CreateColor(255, 0, 0) 'Red

oline = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kSketchBlockFilter, "Select a SketchBlock")
Dim oblockname As String
oblockname = Left(oline.ContainingSketchBlock.name, InStr(oline.ContainingSketchBlock.name, ":") - 1)

Dim oSketchBlock As Inventor.SketchBlockDefinition
For Each oSketchBlock In  oDoc.ComponentDefinition.SketchBlockDefinitions 
	If oSketchBlock.name = oblockname Then
	oSketchBlock.Color = oColor
	InventorVb.DocumentUpdate()
	End If
Next

 another form of code greetings