Retrieve Drawing Dimension from Derived Part in Assembly

johnster100 · ‎05-05-2020

Hi,

I'm trying to retrieve a dimension in a drawing view using API. The dimension is is within a derived part:

The code I am using successfully finds the sketch in 'Pt1.ipt' but crashes when I try to create a geometry proxy of the dimension.

I have attached the drawing (and models) and the code can be found in the 'retrieve dim from assy rule'. I've also posted it below.

	'get the view
	Dim oView As Inventor.DrawingView = ActiveSheet.View("VIEW1").View

	'get the assembly document
	Dim oAssy As Inventor.AssemblyDocument = oView.ReferencedDocumentDescriptor.ReferencedDocument

	'get the assembly component definition
	Dim oAssyCompDef As Inventor.AssemblyComponentDefinition = oAssy.ComponentDefinition

	'get the first occurrence in the assembly
	Dim oCC As Inventor.ComponentOccurrence = oAssyCompDef.Occurrences.Item(1)

	'get the part document from the occurrence
	Dim oPart As Inventor.PartDocument = oCC.ReferencedDocumentDescriptor.ReferencedDocument

	'get the part component definition
	Dim oPartCompDef As Inventor.PartComponentDefinition = oPart.ComponentDefinition

	'get the collection of derived comps
	Dim oRefComps As Inventor.ReferenceComponents = oPartCompDef.ReferenceComponents

	'get the first ref doc
	Dim oRefDoc As Inventor.PartDocument = oRefComps.DerivedPartComponents.Item(1).ReferencedDocumentDescriptor.ReferencedDocument

	Dim oDC As Inventor.DimensionConstraint = oRefDoc.AttributeManager.FindObjects(, , "TEST").Item(1)
	MsgBox(oDC.Parameter.Name) 'check we have the parameter
	 
	'create the object collection
	Dim oObjColl As Inventor.ObjectCollection = ThisApplication.TransientObjects.CreateObjectCollection
	
	Dim oDCProxy As Object
	oCC.CreateGeometryProxy(oDC, oDCProxy)

	'add the dim to the collection
	oObjColl.Add(oDCProxy)

	Dim oSheet As Inventor.Sheet = ActiveSheet.Sheet
	oSheet.DrawingDimensions.GeneralDimensions.Retrieve(oView, oObjColl)

Any help would be appreciated,

thanks,

John

yan.gauthier · ‎05-06-2020

What you are trying to do is to find a dimension from a part sketch, and then place it on a drawing view ?

If that is the case, what i would do is find the model geometry your dimension is attached to, and then loop through all drawing segment in the drawing view until the refered model geometry matches.

johnster100 · ‎05-11-2020

I am trying to retrieve a sketch dimension. The issue is that the part is made from a multi-body solid part (we use these a lot to create assemblies), so the sketch I want to retrieve from is in this part. In the example drawing provided I included code which can do this when the drawing view is the part, but it fails when the drawing view is of the assembly.

Any help is appreciated,

thanks,

John

JhoelForshav · ‎05-11-2020

Hi @johnster100

Try this iLogic rule as your "retrieve dim from assy"-rule.

It works for me 🙂

	'get the view
	Dim oView As Inventor.DrawingView = ActiveSheet.View("VIEW1").View

	'get the assembly document
	Dim oAssy As Inventor.AssemblyDocument = oView.ReferencedDocumentDescriptor.ReferencedDocument

	'get the assembly component definition
	Dim oAssyCompDef As Inventor.AssemblyComponentDefinition = oAssy.ComponentDefinition

	'get the first occurrence in the assembly
	Dim oCC As Inventor.ComponentOccurrence = oAssyCompDef.Occurrences.Item(1)

	'Get the part document From the occurrence
	Dim oPart As Inventor.PartDocument = oCC.ReferencedDocumentDescriptor.ReferencedDocument

	'get the part component definition
	Dim oPartCompDef As Inventor.PartComponentDefinition = oPart.ComponentDefinition

	'get the collection of derived comps
	Dim oRefComps As Inventor.ReferenceComponents = oPartCompDef.ReferenceComponents

	Dim oDercompProxy As Inventor.DerivedPartComponentProxy

	oCC.CreateGeometryProxy(oRefComps.DerivedPartComponents.Item(1), oDercompProxy)

	Dim oSheet As Inventor.Sheet = ActiveSheet.Sheet
	oSheet.DrawingDimensions.GeneralDimensions.Retrieve(oView, oDercompProxy.Sketches)

Jhoel Forshav

Download my free Inventor Addin - Hole Projector

LinkedIn | Ideas | Contributions | Blog posts | Website

johnster100 · ‎05-11-2020

Hi,

that's very close to what I want, the only issue is it brings through all the model dimensions, not just the specific one I'm after (the models I will be using this on have lots of dimensions so I don't want to bring them all through).

Any other suggestions would be greatly appreciated,

thanks,

John

JhoelForshav · ‎05-11-2020

@johnster100

Turns out that the proxy I created in my previous reply is absolutely useless.

oDercompProxy.Sketches is actually nothing, so I didn't really pass any optional argument at all to the Retrieve function 🙂

With that said. It seems the only way to create this particular proxy is to run the Retrieve function on the entire view.

This creates our proxy and dimension, but also all the dimensions we don't want.

What we'll have to do is simply delete all the dimensions we dont want after Retrieve.

See code below:

'get the view
Dim oView As Inventor.DrawingView = ActiveSheet.View("VIEW1").View

'get the assembly document
Dim oAssy As Inventor.AssemblyDocument = oView.ReferencedDocumentDescriptor.ReferencedDocument

'get the assembly component definition
Dim oAssyCompDef As Inventor.AssemblyComponentDefinition = oAssy.ComponentDefinition

'get the first occurrence in the assembly
Dim oCC As Inventor.ComponentOccurrence = oAssyCompDef.Occurrences.Item(1)

'Get the part document From the occurrence
Dim oPart As Inventor.PartDocument = oCC.ReferencedDocumentDescriptor.ReferencedDocument

'get the part component definition
Dim oPartCompDef As Inventor.PartComponentDefinition = oPart.ComponentDefinition

'get the collection of derived comps
Dim oRefComps As Inventor.ReferenceComponents = oPartCompDef.ReferenceComponents
Dim oRefDoc As Inventor.PartDocument = oRefComps.DerivedPartComponents.Item(1).ReferencedDocumentDescriptor.ReferencedDocument

Dim oDC As Inventor.DimensionConstraint = oRefDoc.AttributeManager.FindObjects(, , "TEST").Item(1)

Dim oSheet As Inventor.Sheet = ActiveSheet.Sheet
ThisApplication.ScreenUpdating = False 'Turn off screen updating if you dont want to see unwanted dimensions for a millisecond or so...
'get them all
Dim generalDims As GeneralDimensionsEnumerator = oSheet.DrawingDimensions.GeneralDimensions.Retrieve(oView)
'delete the ones that isn't retrieved from a proxy with native object oDC
For Each generalDim As GeneralDimension In generalDims
	On Error Resume Next 'Just in case some dimensions aren't retrieved from proxies (no native object)
	If generalDim.RetrievedFrom.NativeObject IsNot oDC Then generalDim.Delete
Next
ThisApplication.ScreenUpdating = True 'Dont forget to turn screen updating back on

I believe this is the only solution to the problem...

Turning off and on the screen updating while retrieving all the dimensions hides the "ugliness" of the solution 😉

Hope it works for you!

Jhoel Forshav

Download my free Inventor Addin - Hole Projector

LinkedIn | Ideas | Contributions | Blog posts | Website

johnster100 · ‎05-11-2020

Hi,

thanks again, that works.

what I've ended up doing is using:

Dim oRetrievedDims As Inventor.ObjectCollection = ThisApplication.TransientObjects.CreateObjectCollection

oRetrievedDims = GeneralDimensions.GetRetrievableDimensions(oView, occ)

and getting the collection for all retrievable dimensions for my occurrence in a collection.

I then loop through checking the proxies like in your code and add the one I want. I found this slightly faster (when running on a complex model) and it prevents any dimension which were already added from being deleted.

thanks again,

John