If work features/sketches are visible, then prompt to turn off?
Hi @steveh3. Since you used to have this launch on save, do you plan on making a rule like this launch on save again, or on some other event? When using save event, then I recommend on before save (instead of after save), then do not include saving within the code, because it will be saved afterwards, and you do not wand to cause endless loop. I see lots of potential to greatly condense your code, too. You could potentially ignore document type, to use the same sub routine for both document types, especially if running on all referenced documents. But if looping through components, which have their own DVR (DesignViewRepresentation) settings, you could simply make the one routine recursive (calls itself again, if sub components are present, to go the next step deeper each time), instead of repeating code.
Wesley Crihfield
(Not an Autodesk Employee)
Hi @steveh3. I have something here for you to check out. It does not contain much error handling yet, and I have not test ran this yet, but I think it should be a fairly good step in the right direction. Messing around with the visibility of stuff throughout the structure of an assembly can be complex & messy business, because all of the component objects themselves can be set to different DesignViewRepresentations (and they may be set to 'Associative'). And we haven't even touched on the whole ModelStates thing yet, which complicates your document references. I put a line in the Function to avoid attempting to make changes to documents if they are not 'modifiable', such as Content Center stuff, iPart/iAssembly, Library files, etc). But since it just deals with referenced documents, it does not do anything with component DVR settings at this time. It could be changed to loop components recursively, or expanded/improved in other ways too, if needed.
Sub Main
Dim oDoc As Document = ThisDoc.Document
If oDoc.DocumentType = DocumentTypeEnum.kDrawingDocumentObject Then Exit Sub
Dim oAllRefDocs As DocumentsEnumerator = oDoc.AllReferencedDocuments
Dim MainDocHasVisibleStuff, RefDocsHaveVisibleStuff As Boolean 'False by default
MainDocHasVisibleStuff = CheckVisibility(oDoc)
If oAllRefDocs.Count > 0 Then
For Each oRefDoc As Document In oAllRefDocs
If CheckVisibility(oRefDoc) Then RefDocsHaveVisibleStuff = True
Next
End If
If MainDocHasVisibleStuff Or RefDocsHaveVisibleStuff Then
Dim oAns As MsgBoxResult = MsgBox("Some Sketches or Work Features are visible." & vbCrLf & _
"Do you want to turn them all off?", vbYesNo + vbQuestion, "Visibility Check")
If oAns = MsgBoxResult.No Then Exit Sub
If MainDocHasVisibleStuff Then CheckVisibility(oDoc, True) 'True will turn off visibility
If RefDocsHaveVisibleStuff Then
For Each oRefDoc As Document In oAllRefDocs
CheckVisibility(oRefDoc, True) 'True will turn off visibility
Next
End If
If oDoc.RequiresUpdate Then oDoc.Update2(True)
End If
End Sub
'can be used to just 'check' if any are visible, or to turn visibility off, if second input is True
Function CheckVisibility(oDoc As Document, Optional TurnAllOff As Boolean = False) As Boolean
'should return True to calling routine, if any of these was found to be Visible
If TurnAllOff And (oDoc.IsModifiable = False) Then Return False 'can't make changes to this oDoc
'you may need to deal with DesignViewRepresentations, to save any changes
Dim oWPlanes As WorkPlanes = oDoc.ComponentDefinition.WorkPlanes
Dim oWAs As WorkAxes = oDoc.ComponentDefinition.WorkAxes
Dim oWPts As WorkPoints = oDoc.ComponentDefinition.WorkPoints
Dim oPSketches As PlanarSketches = oDoc.ComponentDefinition.Sketches
Dim oSketches3D As Sketches3D = Nothing 'only in parts, not in assemblies
If oDoc.DocumentType = DocumentTypeEnum.kPartDocumentObject Then
oSketches3D = oDoc.ComponentDefinition.Sketches3D
For Each oSketch3D As Sketch3D In oSketches3D
If oSketch3D.Visible Then If TurnAllOff Then oSketch3D.Visible = False Else Return True
Next
End If
For Each oWPlane As WorkPlane In oWPlanes
If oWPlane.Visible Then If TurnAllOff Then oWPlane.Visible = False Else Return True
Next
For Each oWA As WorkAxis In oWAs
If oWA.Visible Then If TurnAllOff Then oWA.Visible = False Else Return True
Next
For Each oWPt As WorkPoint In oWPts
If oWPt.Visible Then If TurnAllOff Then oWPt.Visible = False Else Return True
Next
For Each oPSketch As PlanarSketch In oPSketches
If oPSketch.Visible Then If TurnAllOff Then oPSketch.Visible = False Else Return True
Next
Return False
End Function
If this solved your problem, or answered your question, please click ACCEPT SOLUTION .
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
