Get Item Weight From Partslist

[Anonymous]

Hi , I'm new with ilogic code. I'm recently working on a code to automatic sort the Partslist inside a IDW.

The Partslist doesn't have a mass column. but in order to sort it i need the weight for each row. so i write following code.

SyntaxEditor Code Snippet

On Error Resume Next 

Dim oDrawDoc As DrawingDocument
oDrawDoc = ThisApplication.ActiveDocument

Dim oPartsList1 As PartsList
oPartsList1 = oDrawDoc.ActiveSheet.PartsLists.Item(1)

Dim oRow As PartsListRow

Dim oAssyDoc As AssemblyDocument 

Dim Mass As Double

For Each oRow In oPartsList1.PartsListRows

    MessageBox.Show(oRow.ReferencedFiles.Item(1).DocumentType)

    oAssyDoc = oRow.ReferencedFiles.Item(1)
    oAssyDoc.ComponentDefinition.MassProperties.Accuracy = k_Medium
    Mass = oAssyDoc.ComponentDefinition.MassProperties.Mass
    
    MessageBox.Show(Mass)

Next

I can see the referenced file type 12290 (ipt) and 12291 (iam). but the weight is always 0.

can anyone help me with that ?

Thanks

[bradeneuropeArthur]

Declare this
Dim Mass As inventor.massproperties

[Anonymous]

@bradeneuropeArthur, thanks for your reply. 

I have tried to declare the mass, but it still not working.

I solved the problem by adding an column of Mass in the Partslist and deleted it afterwards.  

I checked the ReferencedFiles Property (it is a hidden one) under the PartsListRow using the Object Browser in VBA environment. 

and it is ReferencedFileDescriptors Type and only contain Application , Count, Item, ItemByName, Type. So there isn't Mass Property or anything else like the Normal Document file. 

Probably that's why my code doesn't work.

 

[dgreatice · Accepted solution]

Hi,

try this:

Public Sub GetMassFromPartList()
    Dim oApp As Application
    Dim oDD As DrawingDocument
    Dim oSht As Sheet
    Dim oPL As PartsList
    Dim oRow As PartsListRow
    Dim oDoc As Document
    Dim oPD As PartDocument
    Dim oAD As AssemblyDocument
    Dim oPCD As PartComponentDefinition
    Dim oACD As AssemblyComponentDefinition
   
    Set oApp = ThisApplication
    Set oDD = oApp.ActiveDocument
    Set oSht = oDD.ActiveSheet
    Set oPL = oSht.PartsLists.Item(1)
   
    For Each oRow In oPL.PartsListRows
        Set oReffDoc = oRow.ReferencedFiles.Item(1)
        Set oDoc = oReffDoc.ReferencedDocument
        If oDoc.DocumentType = kAssemblyDocumentObject Then
            Set oAD = oDoc
            Set oACD = oAD.ComponentDefinition
            MsgBox (Round(oACD.MassProperties.Mass, 2) & " Kg")
        ElseIf oDoc.DocumentType = kPartDocumentObject Then
            Set oPD = oDoc
            Set oPCD = oPD.ComponentDefinition
            MsgBox (Round(oPCD.MassProperties.Mass, 2) & " Kg")
        End If
    Next
   
   
End Sub

[Anonymous]

Thanks @dgreatice, you are the best.

I was trying to do the same thing, but wasn't success. i thought it just stop at ReferencedFiles

Now i understand that the property chains are 

PartsListRows.Partslists.ReferencedFiles.Item.ReferencedDocument.ComponentDeinition.MassProperty.Mass

Thanks