BOM EXPORT | EACH ASSEMBLY IN A CSV

[tpascual]

Hi Sirs,

Any idea about how to export BOM, but create a new csv for each assembly in the structure?

Of course via API.

Thanks,

[chandra.shekar.g]

Hi tomas,

Please find the following code to export BOM in csv

    Dim oDoc As AssemblyDocument
    Set oDoc = ThisApplication.ActiveDocument

    ' Set a reference to the BOM
    Dim oBOM As BOM
    Set oBOM = oDoc.ComponentDefinition.BOM
    
    ' Set the structured view to 'all levels'
    oBOM.StructuredViewFirstLevelOnly = False

    ' Make sure that the structured view is enabled.
    oBOM.StructuredViewEnabled = True

    ' Set a reference to the "Structured" BOMView
    Dim oStructuredBOMView As BOMView
    Set oStructuredBOMView = oBOM.BOMViews.Item("Structured")
    
    ' Export the BOM view to an Excel file
    oStructuredBOMView.Export "C:\Temp\StructuredBOM.csv", kTextFileCommaDelimitedFormat

Please free to contact if there is any doubt.

[MechMachineMan]

vb.net (to use as a rule):

Sub Main()
    Dim oDoc As Document
    oDoc = ThisApplication.ActiveDocument

    For Each oSubDoc in oDoc.AllReferencedDocuments
        If oSubDoc.DocumentType = kAssemblyDocumentObject Then
            Call ExportDocStructBOM(oSubDoc)
        End if
    Next

    MsgBox("Rule Complete!")
End Sub

Sub ExportDocStructBOM(oDoc As Document) 

    Dim oBOM As BOM
    oBOM = oDoc.ComponentDefinition.BOM
    
    oBOM.StructuredViewFirstLevelOnly = False
    oBOM.StructuredViewEnabled = True

    Dim oStructuredBOMView As BOMView
    oStructuredBOMView = oBOM.BOMViews.Item("Structured")
    
    oStructuredBOMView.Export("C:\Temp\StructuredBOM.csv", kTextFileCommaDelimitedFormat)
End Sub

vba:

Sub Main()
    Dim oDoc As Document
    Set oDoc = ThisApplication.ActiveDocument

    For Each oSubDoc in oDoc.AllReferencedDocuments
        If oSubDoc.DocumentType = kAssemblyDocumentObject Then
            Call ExportDocStructBOM(oSubDoc)
        End if
    Next

    Call MsgBox("Rule Complete!")
End Sub

Sub ExportDocStructBOM(oDoc As Document) 

    Dim oBOM As BOM
    Set oBOM = oDoc.ComponentDefinition.BOM
    
    oBOM.StructuredViewFirstLevelOnly = False
    oBOM.StructuredViewEnabled = True

    Dim oStructuredBOMView As BOMView
    Set oStructuredBOMView = oBOM.BOMViews.Item("Structured")
    
    Call oStructuredBOMView.Export("C:\Temp\StructuredBOM.csv", kTextFileCommaDelimitedFormat)
End Sub 

[tpascual]

Hi Chandra,
Thanks for your response, I have tried yet this code, but what I mean is to export each assembly in the structure to one csv.
Export first level, and if exist some assembly export too but in a different csv.
I'm now exporting first level into a csv.
Thanks,

[chandra.shekar.g]

Hi Tomas,

Please find the updated code to export BOM in different csv file for each assembly.

Sub Main()
    Dim oDoc As Document
    Set oDoc = ThisApplication.ActiveDocument
    
    Call ExportDocStructBOM(oDoc)
    
    Dim oSubDoc As Document

    For Each oSubDoc In oDoc.AllReferencedDocuments
        If oSubDoc.DocumentType = kAssemblyDocumentObject Then
            Call ExportDocStructBOM(oSubDoc)
        End If
    Next

End Sub

Sub ExportDocStructBOM(oDoc As AssemblyDocument)

    Dim oBOM As BOM
    Set oBOM = oDoc.ComponentDefinition.BOM
    
    oBOM.StructuredViewFirstLevelOnly = False
    oBOM.StructuredViewEnabled = True

    Dim oStructuredBOMView As BOMView
    Set oStructuredBOMView = oBOM.BOMViews.Item("Structured")
    
    oStructuredBOMView.Export "C:\Temp\" & oDoc.DisplayName & "_StructuredBOM.csv", kTextFileCommaDelimitedFormat
End Sub

Please feel free to contact if there is any doubt.

[tpascual]

Hi Sirs,

I'm not yet tested, but it seems to work.

Thanks,

[tpascual]

Great ¡¡¡

Now I'm trying to process only assemblies in Estructured BOM not in all document.

I have phantom ass.

Any idea wellcome.

Thanks,