Automate ipart member drawings updates after member generation

[briant.markham]

I have lots of ipart factories with hundreds of ipart members, and it is really easy to make a change to the factory and re-generate the member files, but to get the drawings to update requires each drawing to be manually opened in inventor and manually saved. This seems like a ridiculus limitation, there has to be some way to automate the drawing updates either through a macro or ilogic, any help would be greatly appreciated. Thanks

[philip1009]

Is there a drawing for each member or is there a drawing with a table driven by the master part?  Are the drawings located in the same folder as the members?

[briant.markham]

There is a separate complete drawing for each member and the drawings are located in the same directory as the members. A drawing with a table wouldn't cover the range of parts that this covers.

[chandra.shekar.g]

@briant.markham,

Can you please provide sample iPart factory with 2 members along with drawings to test? Please make sure that files are non confidential.

Thanks and regards,

[briant.markham]

sure.

[chandra.shekar.g · Accepted solution]

@briant.markham,

Sorry for late reply,

Hoping that below VBA code may be helpful. To update drawings, run below VBA code at iPartFactory.

Sub Update_Drawings()

    Dim oDoc As PartDocument
    Set oDoc = ThisApplication.ActiveDocument

    Dim oDef As PartComponentDefinition
    Set oDef = oDoc.ComponentDefinition
    
    If oDef.IsiPartFactory = True Then
        Dim iPartCell As iPartTableCell
        Dim cnt As Integer
        cnt = oDef.iPartFactory.FileNameColumn.Count
        Dim i As Integer
        For i = 1 To cnt
            Set iPartCell = oDef.iPartFactory.FileNameColumn.Item(i)
            Call Update_Memeber_Drawing(oDef.iPartFactory.MemberCacheDir, iPartCell.Value)
        Next
        
    Else
        MsgBox ("Part document is not iPart Factory")
        Exit Sub
    End If
    
End Sub

Sub Update_Memeber_Drawing(dir_Name As String, memberName As String)
    
    Dim oMemeber_path As String
    oMemeber_path = dir_Name & "\" & memberName & ".dwg"
    
    ThisApplication.SilentOperation = True
    
    Dim oDrawdoc As DrawingDocument
    Set oDrawdoc = ThisApplication.Documents.Open(oMemeber_path, False)
    
    Call oDrawdoc.Update
    
    Call oDrawdoc.Save
    
    Call oDrawdoc.Close
    
    ThisApplication.SilentOperation = False
    
End Sub

Thanks and regards,

[briant.markham]

That worked great except I had to add some code between update and save that did a check and loop till the update had fully taken effect.

Thanks