Crear tabla de superficies

[jose_manuel_garcia_garcia]

Buenas a todos, 

Necesito crear tablas de superficies de forma automática. De tal forma que selecciones varias polilineas y automaticamente me produzca la tabla. Mi interés es que todas esas superficies sean campos, parra que cuando modifica alguna de esas polilineas, se me modifiquen todas las demás.

Gracias de antemano!

[Valentin-WSP]

@jose_manuel_garcia_garcia ,

Es posible que desee considerar el uso del comando DataExtraction:: 

• AutoCAD 2024 Ayuda | EXTRACDAT (comando) | Autodesk
•  AutoCAD 2024 Ayuda | Acerca de la extracción de datos | Autodesk

O quizás encuentre algo en la tienda de aplicaciones de Autodesk: 

• TAP_Polyline_Data | AutoCAD | Autodesk App Store

[jose_manuel_garcia_garcia]

Me temo que no me satisface... hay programas como Solicad que pueden hacerlo: generar una tabla de superficies seleccionando todas las polilineas de las que quieres sacar las superficies. 

De todos modos agradezco su interés por responderme.

[calderg1000 · Accepted solution]

Saludos @jose_manuel_garcia_garcia 

Aunque ya paso algún tiempo. No quiero dejar pasar la oportunidad de compartir esta rutina para obtener lo que requieres. Espero que te sea de Utilidad.

(Defun c:Area_tab_F
       (/ LData ss i e Item ccoord Desc Area eData Obj_Table Tname nrow)
  (vl-load-com)
  (princ "\nSelecciones Polilineas para calcular el Area...:")
  (if
    (setq LData nil
          ss    (ssget '((0 . "LWPOLYLINE")))
          Item  1
    )
     (progn
       (repeat (setq i (sslength ss))
         (setq e (vlax-ename->vla-object (ssname ss (setq i (1- i))))
               a (strcat
                   "%<\\AcObjProp Object(%<\\_ObjId "
                   (Get-ObjectIDx64 e)
                   ">%) .Area \\f \"%lu2%pr2>%"   ;m2
                 )
         )
         (setq Desc  (strcat "A-" (itoa Item))
               Area  a
               eData (list Item Desc Area)
               LData (cons eData LData)
         )
         (entmakex (list '(0 . "text")
                         (cons 1 Desc)
                         (cons 10 (osnap (vlax-curve-getStartPoint e) "gcen"))
                         (cons 40 1.5)
                   )
         )
         (setq Item (1+ Item))
       )                                          ;repeat
       (setq LData (vl-sort LData '(lambda (m n) (< (Car m) (car n)))))
       (setq Obj_Table
              (vlax-invoke
                (vlax-get (vla-get-ActiveLayout
                            (vla-get-activedocument (vlax-get-acad-object))
                          )
                          'Block
                )
                'Addtable
                (trans (getpoint "\nPick point for Table:") 1 0)
                2                                 ;Filas
                3                                 ;Columnas
                40                                ;
                40                                ;
              )
       )
       (setq Tname "TABLA DE AREAS")
;;;Titulo...
       (vla-settext Obj_Table 0 0 Tname)
       (vla-setcelltextheight Obj_Table 0 0 8.0)
;;;Encabezado...
       (mapcar '(lambda (y)
                  (vla-settext Obj_Table 1 (car y) (cadr y))
                  (vla-setcelltextheight Obj_Table 1 (car y) 8.0)
                )
               (list '(0 "ITEM") '(1 "DESCRIPCION") '(2 "AREA"))
       )
       (foreach j LData
         (vla-insertrows
           Obj_Table
           (1+ (setq nrow (vla-get-rows Obj_Table)))
           15
           1
         )
         (vla-setcelltextheight Obj_Table nrow 0 8.0)
         (vla-setCellAlignment Obj_Table nrow 0 5)
         (vla-setCellValue Obj_Table nrow 0 (car j))
         (vla-setCellValue Obj_Table nrow 1 (cadr j))
         (vla-settext Obj_Table nrow 2 (caddr j)) ;area
         (vla-setcelltextheight Obj_Table nrow 1 8.0)
         (vla-setcelltextheight Obj_Table nrow 2 8.0)
         (vla-setCellAlignment Obj_Table nrow 1 5)
         (vla-setCellAlignment Obj_Table nrow 2 5)
         (vla-setcellformat Obj_Table nrow 2 "%lu2%pr2%ps[, m2]")
       )
       (vla-setColumnWidth Obj_Table 1 100)
       (vla-setColumnWidth Obj_Table 2 120)
     )
  )
  (princ)
)

[joaquim.moral · Accepted solution]

Hola @calderg1000,

muchas gracias por compartir la información en el foro! De esta manera ayudas a usuarios con duda similares.

Si os ha sido útil, os animo a que nos dejéis un like en el post 🙂

Hasta pronto,