How to add areas of multiple hatches

[Anonymous]

I have a drawing with many hatches. I need the area of each hatch in the drawing. I used FIELD command, it works but is slow with many hatches. Does AutoCAD have a feature to label more objects with one command?

[Patchy]

Use Properties Pallette

[john.vellek]

Hi cserszomorce0,

As @Patchy indicates, the properties palette is a great way to see this kind of information. Check out the Qselect command to select all the areas at once!

The fields can be a useful tool if you need to reuse the information or schedule it in a table but can be tedious for a onetime process.

[Anonymous]

I use Properties if I need the areas only once but sometimes I need the information many times or permanently. It would be good on the drawing or in a list if I can identify which number goes tohether which hatch.
I attached a picture about it, it is made with Field command but I have sometimes much more hatches than in this drawing.

[Patchy · Accepted solution]

You can try this from Lee-Mac.com

http://www.lee-mac.com/areastofield.html

[wispoxy]

Hello @Anonymous, you should be able to select objects non stop and it will just keep filling. Or you can box in everything too. Easy process even if you have to fill in one hundred spots in one drawing.

[Anonymous]

---

@Anonymous wrote:

Hello @Anonymous, you should be able to select objects non stop and it will just keep filling. Or you can box in everything too. Easy process even if you have to fill in one hundred spots in one drawing.

---

Can you please demonstrate how your solution provides what the OP wants to do?  He provided an image in post #4.  

[john.vellek · Accepted solution]

Hi @Anonymous,

This is always a challenge. @Patchy's link provides a slick LISP routine to do some of this.

In the past I have used a combination of techniques to create a schedule. 

One way is to make a table and insert a field linked to the object's area. This works well but makes it difficult to know which area is which.

So the other way I have done this is to create a block with two attributes: one for the area name and a second to capture the area size

I can then create a table to capture both pieces of information. Once in a table you can even export it to Excel to perform calculations. The only draw back is that you have to manually enter the area into the attribute value.

Perhaps this will get you started on a solution that best fits your needs.

Please hit the Accept as Solution button if my post fully solves your issue or answers your question.

[wispoxy]

@Anonymous Thanks for pointing that out. I was only missing out on 90%  

An attribute definition with multiple fields and blocked to be associated with a hatch pattern. Then selecting multiple objects to be filled with the attribute definition shown in the center with a hatch around it within all the objects selected.

I understand @john.vellek's method but requires too much time without the MULTIPLE command.

It's a bit complicated (just a too much to share) for someone that's not familiar with attribute definition connections and field connections. I'm trying to find an add-on instead.

[ВeekeeCZ · Accepted solution]

---

@Anonymous wrote:

I have a drawing with many hatches. I need the area of each hatch in the drawing. I used FIELD command, it works but is slow with many hatches. Does AutoCAD have a feature to label more objects with one command?

---

You can try these routines. The first makes area as a field, the second as a text. 

Text is placed in the middle of shape, but be careful about specific shapes such as "U" shape, where the middle point is NOT laying inside of shape.

Spoiler

(vl-load-com)

(defun c:HatchArea2Field  (/ asp adoc ss en ptsum ptlst ID field obj pt)
  
  (setq  asp (vla-get-modelspace (setq adoc (vla-get-activedocument (vlax-get-acad-object)))))
  (vla-startundomark adoc)
  
  (if (setq ss (ssget ":L" '((0 . "HATCH") (410 . "Model"))))
    (repeat (sslength ss)
      (setq en     (ssname ss 0)
	    ptsum   '(0 0)
	    ptlst (cdr (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) (entget en))))
	    novrt  (length ptlst)
	    ID     (itoa (vla-get-objectid (vlax-ename->vla-object en)))
	    field (strcat "%<\\AcObjProp Object(%<\\_ObjId " ID ">%).Area \\f \"%lu2\">%"))
      (foreach x ptlst (setq ptsum (mapcar '+ x ptsum)))
      (vla-put-AttachmentPoint
	(setq obj (vla-addMText asp (setq pt (vlax-3d-point (mapcar '/ ptsum (list novrt novrt)))) 0 field))
	acAttachmentPointMiddleCenter)
      (vla-put-InsertionPoint obj pt)
      (ssdel en ss)
      )
    (princ "\nNo object found."))
  (vla-endundomark adoc)
  (princ)
)


(defun c:HatchArea2Text  (/ asp adoc ss en ptsum ptlst ID area obj pt)
  
  (setq  asp (vla-get-modelspace (setq adoc (vla-get-activedocument (vlax-get-acad-object)))))
  (vla-startundomark adoc)
  
  (if (setq ss (ssget ":L" '((0 . "HATCH") (410 . "Model"))))
    (repeat (sslength ss)
      (setq en     (ssname ss 0)
	    area  (rtos (vla-get-area (vlax-ename->vla-object en)) 2)
	    ptsum   '(0 0)
	    ptlst (cdr (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) (entget en))))
	    novrt (length ptlst))
      (foreach x ptlst (setq ptsum (mapcar '+ x ptsum)))
      (vla-put-AttachmentPoint
	(setq obj (vla-addMText asp (setq pt (vlax-3d-point (mapcar '/ ptsum (list novrt novrt)))) 0 area))
	acAttachmentPointMiddleCenter)
      (vla-put-InsertionPoint obj pt)
      (ssdel en ss)
      )
    (princ "\nNo object found."))
  (vla-endundomark adoc)
  (princ)
)

[Anonymous]

Thank you for all your solutions!

I've never used lisp, I think it's time to learn it 🙂