Get the current numeric PERCENT value from a "path constraint float script

[truckexpert]

How do I get the current numeric PERCENT value from a "path constraint float script?

Thanks.

Dave

SYSINFO

Dell Precision 7920 Tower
BaseBoard 060K5C
Intel Xeon Silver 4110 CPU @ 2.10GHz, 2095 Mhz, 8 Core(s), 16 Logical Processor(s)
NVIDIA Quadro P1000 - Adapter RAM (1,048,576) bytes
Physical Memory (RAM) 32.0 GB
Windows 10 Pro

3DS Max 2021

[denisT.MaxDoctor]

---

@truckexpert wrote:

How do I get the current numeric PERCENT value from a "path constraint float script?

---

what is "path constraint float script"?

I know "path constraint" and "float script" ... what are they together?  

[truckexpert]

Thank you for your reply.

Assume a dummy named "Dummy1" is moving along a spline path named "Path1". 

      I am controlling the percent progress of Dummy1 along the spline (length L) using a "float script" controller, so as to allow the user to specify the speed, so that %Dist = speed*time/L.   I simply want the script to print the current value of the percent progress (along with time and distance) to create a table in the listener window as the script runs, but I don't know it's name (it isn't %Dist) or how to refer to it. 

[denisT.MaxDoctor · Accepted solution]

delete objects
p = circle name:#path radius:30 wirecolor:green
t = teapot name:#source radius:5 wirecolor:orange
c = t.pos.controller = path_constraint path:p follow:on
s = c.percent.controller = float_script()
s.addconstant #velocity 0.5
s.addconstant #period 4.0
s.addconstant #debug false

ss  = ""
ss += "local value = sin (period * F) * velocity\n"
ss += "if debug do format \"frame:% secs:% period:% velocity:% == value:%\\n\" F S period velocity value\n"
ss += "value\n"

s.setexpression ss


(
	s.setconstant #debug on
	for t = 0 to 100f by 10 do at time t 
	(
		format "\t% >> percent:%\n" t c.percent
	)  
	s.setconstant #debug off
)

Use this as an example. Of course, the #debug option should be disabled in real time and should be used with data output (check, debug).

[truckexpert]

Thank you again!! I have learned a lot from the above script. You obviously have finessed the art of Maxscript programming!