Help. How can I disable information about snapping coordinates in the bottom line of the UI?

[MaxBlum]

Hi.

I use 3DS MAX for many years. I'm architect and working with architectural objects use snaps in my workflow almost all the time. There is one thing in Max 2021.3 UI which bothers me every day. I'm talking about small window in the bottom part of the Max window where you can find some tips what to do, something like the one you can see on attached screenshot. It's ok when snaps are OFF, but if they switched ON information about current point of snapping (type of snap and coordinates of the snapping point) appears in the same line replacing the tip for a 0.1 sec, after that tips appears again and they replace each other each 0.1 sec. On screen it looks just like blinking of that line even if I stop the mouse and some snap preview is shown on screen. This blinking actually does nothing, it's just annoying element which doesn't have any use for me.

Is it possible to disable this information about snapping coordinates at all still having snaps active?

[Serejah · Accepted solution]

You can disable/enable control redraw manually with a macro.

macroScript StatusPanelPromptToggle
category:"Snaps"
tooltip:"Status Panel Prompt Toggle"
icon:#("Maxscript",4)
(
	local hwnd  = undefined
	local checked = false
	
	fn FindStatusPanelPrompt = 
	(
		for w in windows.getChildrenHWND (dotNetClass "Autodesk.Max.GlobalInterface").Instance.CoreInterface14.StatusPanelHWnd where w[4] == "CustStatus" and (UIAccessor.GetWindowResourceID w[1]) == 7 do
		(
			exit with w[1]
		)
	)

	on isChecked do checked

	on execute do
	(
		if hwnd == undefined do hwnd = FindStatusPanelPrompt()
		
		checked = not checked
		
		PushPrompt (if checked then "Status panel redraw disabled" else "") 
		windows.sendMessage hwnd 0xB (if checked then 0 else 1) 0		
		
		if not checked do
		(
			popPrompt()
			PushPrompt ""
		)			
	)	
)

[MaxBlum]

Thank you so much! This is exactly what I need.

Do you mind if I share your script with my colleagues who would like to have this option too?

[Serejah]

Sure you can share it.

It would be nice to have a script that do this kind of thing automatically when user activates any type of snap, but I don't know how to do it easiest way yet.

[MaxBlum]

Thank you very much for your help!

[denisT.MaxDoctor]

---

@Serejah wrote:

Sure you can share it.

It would be nice to have a script that do this kind of thing automatically when user activates any type of snap, but I don't know how to do it easiest way yet.

---

if your macro added to toolbar you can check the state of Snap using any handle - ischecked or isenabled for example

[MaxBlum]

With this script I've created the button and it works well.