vla-GetExtensionDictionary
Hi,
Dictionaries are containers for xrecords, custom objects or other dictionaries. There're two types of dictionaries: the named dictionaries which typically are children of the named object dictionary (accessible through the namedobjdict LISP function ; and the extension dictionaries which can be attached to an AutoCAD object. See this topic for more information.
So any AutoCAD object (graphical entities as non-graphical objects) might have one (and only one) extension dictionary. These dictionaries are mainly use by AutoCAD or third applications to attach data to an object (a little like xdata).
The "ACAD_FIELD" dictionary you're refering to, only exists in the extension dictionary of TEXT and MTEXT entities which have some field code in their text string.
So, a MTEXT entity can have or not have an extension dictionary and this dictionary can have or not have the "ACAD_FIELD" entry., but as soon as a MTEXT entity contains a field code, AutoCAD attaches an extension dictionary to the MTEXT (is it has not have already one) and attach a "ACAD_FIELD" which contains the field data.
So, looking for the "ACAD_FIELD" entry in a MTEXT extension dictionary to know if a MTEXT contains some field is not applicable for anything.
When you're saying "What do I need to put in for ATTRIBS, TEXT, MTEXT, ETC ETC" what do you expect?
You still do not understand.
An entity (MTEXT, TEXT, ATTRIB, ATTDEF) may have an extension dictionary and this extension dictionary may have an "ACAD_FIELD" entry and, if so, that means the entity contains a field.
This little commented routine shows this:
;; Returns T if the entity (MTEXT, TEXT, ATTRIB, ATTDEF) has some field; otherwise, nil.
(defun HasField (ent / dxfLst xdict)
(and
;; get the DXF data list of the entity
(setq dxfLst (entget ent))
;; get the entity extension dictionary (may return nil if none)
(setq xdict (cdr (assoc 360 (member '(102 . "{ACAD_XDICTIONARY") dxfLst))))
;; check for the "ACAD_FIELD" entry in the extension dictionary (may return nil if none)
(dictsearch xdict "ACAD_FIELD")
)
)
Now talking about filtering entities, there mainly two ways:
- with a selection and a selection filter this only allow to filter on first level entities and some of their properties (block reference name, text contents, ...)
- iterating through a collection of entities (possibly a filtered selection set) and make your own tests, this allows all type of deep filtering.
1. You cand filter TEXT (ssget '((0 . "TEXT"))), MTEXT (ssget '((0 . "MTEXT"))) or both (ssget '((0 . "MTEXT,TEXT"))), but you cannot directly filter ATTRIBS or (M)TEXTs having fields (see this topic and the realted ones).
2. You can deeply inspect each entity, for example get (and inspect) the attribute references (ATTRIB) of a block reference, or check if a (M)TEXT contains a field.
@DGRL wrote:
Hi @_gile
You are correct
I do not understand this and the whole LISP
Autodesk should consider MAKING way better documentation about thisYou sent me http://help.autodesk.com/view/OARX/2018/ENU/
This should cover everything needed for a developer to get started
Yet it does not provide the info needed.
Where can I get extensive documentation about LISP used in and for Autodesk Products?
How in the world can I know stuff like this if CANT even find it anywhere?
Anyway Thanks for the explanation.
As for now I will just stop coding in lisp coz i am not good in it anyway.
Sad that I tried to become a good coder yet im failing
Do not be discouraged. Other have been able to learn LISP, so there's no reason you cannot.
The AutoLISP Developer's Guide is, as far as I know, the most extensive documentation about AutoLISP / Visual LISP existing today.
I'm pretty sure you did not read it all (I did not).
You can also find other resources on the internet, but the way most of us learned is by reading other ones codes and experimenting.
Anyway, you probaly won't find ready-made examples which exactly correspond to what you're looking for.
Perhaps you should begin with simpler tasks (it seems to me you're trying to build something too complex for a beginer).
And you should get help from other here and elsewhere...
@DGRL wrote:
I just want 1 answer
Where can i find that list or HOW CAN I KNOW WHAT to fill inIs there only 1 dictionary ? i.e
(dictsearch xdict "ACAD_FIELD")Because i do not believe that there is only 1 dict called ACAD_FIELD
There must be more
Please attentively read the topic about dictionaries I linked in a previous message.
By definition, a dictionary cannot contain duplicated entry names so there can be only one ACAD_FIELD dictionary per extension dictionary.
If your goal is to get all ACAD_FIELD dictionaries in a drawing, you have to iterate through all enetities wich can have one in their extension dictionary (ATTRIB, ATTDEF, MTEXT, TEXT).
I do not know how should I try to explain this in an other way, so I purpose you to make some test with the following routines and understand by yourself the "Dictionary stuff".
These routines use the gc:GetExtDict and gc:GetDictEntries functions from the gc-Dictionary.lsp library (available here).
;; gc:GetExtDict (gile)
;; Returns the extension dictionary of the object (or nil)
;;
;; Argument : obj (ENAME)
(defun gc:GetExtDict (obj)
(cdadr (member '(102 . "{ACAD_XDICTIONARY") (entget obj)))
)
;; gc:GetDictEntries
;; Return the list of all entries in the dictionary as dotted pairs (name . ENAME)
;;
;; Argument : dict the dictionary (ENAME or DXF list)
(defun gc:GetDictEntries (dict / result)
(and (= (type dict) 'ENAME) (setq dict (entget dict)))
(while
(setq dict (vl-member-if (function (lambda (x) (= (car x) 3))) (cdr dict)))
(setq result (cons (cons (cdar dict) (cdadr dict)) result))
)
(reverse result)
)
This one prints the name of all named dictionaries contained by the root dictionary (Named Object Dictionary)
;; List all dictionaries in the named object dictionary
(defun listNamedObjDict ()
(foreach entry (gc:GetDictEntries (namedobjdict))
(princ (strcat "\n" (car entry)))
)
(princ)
)
This one prints the name of all layouts in the drawing. This is the AutoCAD stores the Layout objects of a drawing.
You can try with other dictionaries repalcing "ACAD_LAYOUT" by some othe name returned by the previous function.
;; list all entries in the ACAD_LAYOUT dictionary
(defun listLayoutDict (/)
(setq dictionaries (gc:GetDictEntries (namedobjdict))
layoutDict (cdr (assoc "ACAD_LAYOUT" dicts))
)
(foreach entry (gc:GetDictEntries layoutDict)
(princ (strcat "\n" (car entry)))
)
(princ)
)
This one list the entries of the object extension dictionary (if any).
;; list all entries in the object extension dictionary
(defun listExtensionDict (obj)
(if (setq xdict (gc:GetExtDict obj))
(foreach entry (gc:GetDictEntries xdict)
(princ (strcat "\n" (car entry)))
)
(princ "\nThe object do not have an extension dictionary")
)
(princ)
)
You can try this last one with a selected drawing entity (try with a MTEXT with field and a MTEXT without field)
(listExtensionDict (car entsel)))
You can also try with non graphic objects as the layer "0"
(listExtensionDict (tblobjname "Layer" "0"))
or the Model space BLOCK_RECORD.
(listExtensionDict (cdr (assoc 330 (entget (tblobjname "block" "*Model_space")))))
Remember that not all objects have an extension dictionary.
The next step can be creation and adding dictionaries and xrecords to the root dictionary or to an extension dictionary (and create it if not already exists).
See the dictadd function in the AutoLISP Reference, it contains an example.
@john.uhden wrote:
Thank goodness you are not afraid of using...
(and
...
...
...
)
Sorry I don't understand what you mean.
Isn't this exactly the purpose of the and function?
Short circuit evaluation of multiple condition to return T or nil.
