Trying to get block insert lisp to separate insertion point and rotate.
@Anonymous wrote:
....
- make the lisp rotate the block
- then select its insertion point
The reason being i want to use a line to make the angle but i don't want the block to be on top of the line. ....
Also I have about 30 of these small lisps repeated all the same except for the block name and the defun, is there any way to simplify that?
....
A Line entity specifically? Or possibly a Polyline line segment, or an Mline, or an edge of something else?
Let's say it could be a straight piece or segment or edge of any entity type. If you can manage to pick on it not at an end, so that Object Snap between NEArest and ENDpoint modes can determine an angle, you can do something like this, using a shared routine that will take a Block name as an argument:
(defun BlockOnEdge (blkname / pt ang)
(setq
pt (getpoint "\nPick on line/edge to define Block rotation: ")
ang (angle (osnap pt "_nea") (osnap pt "_end"))
); setq
(command
"_.insert" blkname "_scale" 1 "_rotate" (angtos ang) pause
; sets scale/rotation as options before pause at end for insertion point
"_.copy" "_last" "" "_multiple" "@"
); command
); defun
That lets you get the angle with one pick, instead of by way of a temporary-because-that-'s-not-where-you-really-want-it insertion point on the Line [or whatever] and another pick for the rotation.
That assumes a Block without Attributes, and doesn't yet account for possible running Osnap modes, etc. It could be made to adjust the angle to the more-upright direction, if that's appropriate to your Blocks, and/or to check that you picked on something straight rather than curved, and some other things. [It could even be made to let you pick on a curve, and use its direction at the pick point for the rotation, though that doesn't seem likely to be what you want.]
Then for all your different Blocks, make little command names using that shared routine:
(defun C:EE5 ()
(BlockOnEdge "EES")
)
(defun C:ABC ()
(BlockOnEdge "ABC")
)
(defun C:XYZ ()
(BlockOnEdge "XYZ")
)
@Anonymous wrote:
... I am getting blocks that are upside down. Any way to fix that? the blocks ... need to be upright. ...
Certainly! [Second sentence, longer paragraph in Post 4.] No need to require two picks from the User to set the rotation. One way is to add this line before the Insert command starts:
....
); setq
(if (and (> ang (/ pi 2)) (<= ang (* pi 1.5))) (setq ang (+ ang pi)))
(command
....
@Anonymous wrote:
.... I'm still a bit fuzzy on what (blkname / pt ang) in the lisp dose ....
To expand on what stevor said about blkname:
Anything before the slash [/] in the parentheses following a function name is an argument, as distinguished from the things that come after the /, which are variables. Think of it as a kind of variant on a variable, a 'placeholder' for a value that is going to be fed in when the function is used.
When you do:
(BlockOnEdge "EES")
the "EES" is the argument, and wherever the blkname placeholder occurs in the function definition, that argument will be fed in. So when it gets to:
(command
"_.insert" blkname "_scale" 1 ....
it will be supplied with the "EES" [or another Block name in the other command definitions] in place of the blkname argument/placeholder. That's how one function definition can be used in any number of different command definitions -- each command calls that same function but supplies its own argument value.
Note the difference between:
(defun BlockOnEdge
without the C: before its function name, and:
(defun C:EE5
with the C: before its command name. Command definitions with the C: can't have arguments before the slash; function definitions without it can, though they don't always need to. In either type, if there are no arguments or localized variables, they still need their name to be followed by either [as I usually do it] empty parentheses or [as you will sometimes see it done] nil in their place.
When you use a function with one or more arguments in its definition, you must supply a value for each argument, within the parentheses calling the function, and if there's more than one, in the order in which their placeholders are listed in the function definition. If you were to try:
(BlockOnEdge)
without supplying a value for the blkname argument, it would complain to you that you didn't supply enough information:
; error: too few arguments
Also, you type in a command name "plain" to use it, e.g. EES, but a function must be called inside parentheses, just like the difference between using an AutoCAD command and an AutoLisp function at the Command: prompt.
To use a custom-defined command name within another AutoLisp routine, you likewise call it in parentheses and with the C: prefix, e.g. (C:EES). You can't use it in a (command) function, which only recognized AutoCAD's own command names.
@Anonymous wrote:
....
.... "_.copy" "_last" "" "_multiple" "@" )(setvar 'osmode (osm)) )I am trying to make it so the snaps turn off while I am placing in the blocks but turns back on at the end of the lisp. ....
This is the classic case of a command that can have an indeterminate number of User inputs before it's completed, and you don't want it to continue on to something such as resetting that System Variable until after the command is done.
You can have it wait for further input as long as the User wants to keep going, and continue only when they're finished, by monitorng the CMDACTIVE System Variable:
....
"_.copy" "_last" "" "_multiple" "@"
); command
(while (> (getvar 'cmdactive) 0) (command pause))
; CMDACTIVE returns to 0 when done with command, so (>) returns nil,
; stopping (while) loop, and only then:
(setvar 'osmode (osm))
)
@Anonymous wrote:
hmmm, when i enter out of the command it gives me error: bad function. when i escape out of the command (as i usually do) it gives me ; error: function cancelled. Also I put the osm into the local function, that correct?
.... (setvar 'osmode (osm)) )....
Yes, listing osm as a localized variable is correct. Sorry, I should have noticed this before:
(setvar 'osmode osm)
[no parentheses around variable names -- that's what made it think (osm) was supposed to be a function, but of course it isn't, hence the bad-function error message]
If you ESCape to end it, it won't reset that, because it cancels the whole routine, rather than simply ending the Copy command. So an *error* handler would be needed to ensure it does, unless you can always remember to use Enter/space to end it. It can be handled like a localized variable, so that AutoCAD's standard one will go back into effect after the routine is done, and it can also suppress the function-cancelled message. Here's a typical way of doing it:
(defun BlockOnEdge (blkname / *error* pt ang osm) (defun *error* (errmsg)
(if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
(princ (strcat "\nError: " errmsg))
); if
(setvar 'osmode osm); reset
(princ)
); defun - *error*
(setq osm (getvar "osmode")
pt (getpoint "\nPick on line/edge to define Block rotation: ") ang (angle (osnap pt "_nea") (osnap pt "_end")) ); setq (if (and (> ang (/ pi 2)) (<= ang (* pi 1.5))) (setq ang (+ ang pi))) (setvar 'osmode 0) (command "_.insert" blkname "_scale" 1 "_rotate" (angtos ang) pause "_.copy" "_last" "" "_multiple" "@" ); command (while (> (getvar 'cmdactive) 0) (command pause)) (setvar 'osmode osm); reset
(princ) ); defun
[I put the 'osm' variable first in the setting of localized variables, so that even if the User cancels when it's asking to pick on a line/edge [the first time the User has a chance to kill it], the *error* handler won't itself trigger an error, for trying to reset OSMODE to a variable that doesn't exist, because it will already be there.]
EDIT: Come to think of it [without trying it out], that osm variable may not be set if they cancel at that point, since the (setq) function hasn't closed. It may be necessary to separate it from the others to ensure that it's set, no matter what the User does:
(setq osm (getvar "osmode"))
(setq
pt (getpoint "\nPick on line/edge to define Block rotation: ") ang (angle (osnap pt "_nea") (osnap pt "_end")) ); setq
@Anonymous wrote:
I am trying a similar routine however ... error ....
Post the code.