Text Area calculation
Accepted solution
I guess this is what you asked for.
(defun c:repl (/ *error* adoc string_to_list ss e ent i nt)
(defun *error* ( msg )
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ)
)
(if (and adoc) (vla-endundomark adoc))
(princ)
)
(defun string_to_list ( str del / pos )
(if (setq pos (vl-string-search del str))
(cons (substr str 1 pos) (string_to_list (substr str (+ pos 1 (strlen del))) del))
(list str)
)
)
(princ "\nSelect text to change with area >")
(setq adoc (vla-get-activedocument (vlax-get-acad-object)))
(setq ss (ssget '((0 . "TEXT"))) i -1)
(vla-endundomark adoc)
(vla-startundomark adoc)
(while (< (setq i (1+ i)) (sslength ss))
(setq ent (entget(ssname ss i)))
(setq e (cdr (assoc 1 ent)))
(setq e (substr e (+(vl-string-position (ascii "(") e) 2)))
(setq e (substr e 1 (- (strlen e)1)))
(setq e (string_to_list e "/"))
(setq e (mapcar 'atof e))
(setq nt(strcat "("(rtos (/ (* (car e)(cadr e)) 10000.0) 2 3) " \U+33A1" ")"))
(setq ent (subst (cons 1 nt)(assoc 1 ent) ent))
(entmod ent)
)
(vla-endundomark adoc)
(princ "\nDone!")
(princ)
)It's time to switch to Euro 2020 Ukraine ws England.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
Accepted solution
@k005 wrote:we will just create new TEXT. the format is just this: 0.18 m²
Here you go
(Defun c:TrueSize ( / _WantedList)
(defun _WantedList (str / p )
(setq p (vl-string-position 40 str))
(strcat "(" (rtos (apply '*
(cons 0.0001
(read (Vl-string-subst " " "/" (substr str (1+ p)))) )
) 2 3 ) " m²)")
)
(if (setq ss (ssget "_:L" '((0 . "TEXT")(1 . "*(*#/#*)"))))
(repeat (setq i (sslength ss))
(setq str (getpropertyvalue (setq e (ssname ss (setq i (1- i)))) "TextString"))
(setq new_str (_WantedList str))
(setpropertyvalue e "TextString" new_str)
)
)(princ)
)
HTH
You can also try ALTEXT.
Use following codes in ALTEXT as a formula.
;;; This is an example formula for ALTEXT.vlx
;;; It convert text in a format of "(36/60)" to "0.18m2"
(defun ALTEXT_FORMULA (/ P1 P2 P3 T0 T1 T2)
(setq P1 (vl-string-search "(" ALTEXT_STR_ORG) ;(setq ALTEXT_STR_ORG "SZ01 (60/40)")
P2 (vl-string-search "/" ALTEXT_STR_ORG)
P3 (vl-string-search ")" ALTEXT_STR_ORG)
T0 (substr ALTEXT_STR_ORG 1 P1)
T1 (substr ALTEXT_STR_ORG (+ P1 2) (- P2 P1 1))
T2 (substr ALTEXT_STR_ORG (+ P2 2) (- P3 P2 1))
)
(if (and T0 T1 T2)
(strcat T0 "(" (vl-string-right-trim "0" (rtos (/ (* (atoi T1) (atoi T2)) 10000.0) 2)) "m\U+00B2)")
)
)
Result drawing as in the attachment.
@k005 wrote:Thank you so much . Exactly as I want. my friend.
Thank you for letting me know it works for you. There's one more thing we can do.
(Defun c:TrueSize ( / _WantedList)
(defun _WantedList (str / p )
(setq p (vl-string-position 40 str))
(setq n (apply '*
(read (Vl-string-subst " " "/" (substr str (1+ p))))
))
(strcat "(" (rtos (* n 0.0001) 2 (1+ (fix (/ (log n) (log 10)))) ) " m²)")
)
(if (setq ss (ssget "_:L" '((0 . "TEXT")(1 . "*(*#/#*)"))))
(repeat (setq i (sslength ss))
(setq str (getpropertyvalue (setq e (ssname ss (setq i (1- i)))) "TextString"))
(setq new_str (_WantedList str))
(setpropertyvalue e "TextString" new_str)
)
)(princ)
)
That should take care of the decimal precision.
HTH
@k005 wrote:
How should we change the code so that we can operate both with and without parentheses in this code?
We can cerainly make it work for both formats, but as always, i need a sample drawing of what is and what it will be
[ before / after ] for both conditions so there will be no confusion.
Accepted solution
(Defun c:TrueSize ( / _Clean _WantedList ss str new_str)
(Defun _Clean (Str)
(foreach itm '(("(" "") (")" "")(" " "")("/" " "))
(setq str (Vl-string-subst (cadr itm) (car itm)str))))
(defun _WantedList (str / val p )
(if
(and
(vl-some '(lambda (d)
(setq p (vl-string-position d str))) '(40 32)
)
(setq n (apply '*
(read (strcat "(" (_Clean (substr str (1+ p))) ")"))
))
)
(strcat (rtos (* n 0.0001) 2 (1+ (fix (/ (log n) (log 10)))) ) " m²")
)
)
(if (setq ss (ssget "_:L" '((0 . "TEXT")(1 . "*(*#/#*),* *#/#*"))))
(repeat (setq i (sslength ss))
(setq str (getpropertyvalue (setq e (ssname ss (setq i (1- i)))) "TextString"))
(setq new_str (_WantedList str))
(setpropertyvalue e "TextString" new_str)
)
)(princ)
)
HTH
I suggest for now please look for other conditions that you might have overlooked.
Reply back only if you are sure you got every format covered.
@k005 wrote:Now when I say every form... Actually, there is no other form for now. I have 3 formats in total...
A quick mod
(Defun c:TrueSize ( / _Clean _WantedList ss str new_str)
(Defun _Clean (Str)
(foreach itm '(("(" "") (")" "")(" " "")("/" " "))
(setq str (Vl-string-subst (cadr itm) (car itm)str))))
(defun _WantedList (str / val p )
(if
(and
(or
(vl-some '(lambda (d)
(if (setq p (vl-string-position d str))
(setq str (substr str (1+ p)))))
'(40 32))
(wcmatch str "#*/*#"))
(setq n (apply '*
(read (strcat "(" (_Clean str) ")"))
))
)
(strcat (rtos (* n 0.0001) 2 (1+ (fix (/ (log n) (log 10)))) ) " m²")
)
)
(if (setq ss (ssget "_:L" '((0 . "TEXT")(1 . "*(*#/#*),* *#/#*,#*/*#"))))
(repeat (setq i (sslength ss))
(setq str (getpropertyvalue (setq e (ssname ss (setq i (1- i)))) "TextString"))
(if
(setq new_str (_WantedList str))
(setpropertyvalue e "TextString" new_str)
)
)
)(princ)
)
HTH
