There's no need for opening a file (and leaving it cluttering up the
disk) in plain AutoLISP:
;;; Convert a symbol to its name as a string.
;;; Jon Fleming April 25, 1998 - based on code attributed
;;; to Bill O'Neal
;;; WARNING: DO NOT "compile" this function, in Visual
;;; LISP or Vital LISP, with "link" or "drop" options on!
(defun SymToStr (SymbolName)
;; If the argument is a symbol ...
(if (= (type SymbolName) 'SYM)
(progn
;; Execute the function we are going to create ...
(
;; Create a function on the fly
(list
;; The argument and local variable list. Note
;; that SymbolName will be evaluated, so the
;; symbol name that we're trying to convert
;; will be a local variable.
(list '/ SymbolName)
;; Set the local variable to 0 to make sure it
;; appears in the atoms-family (variables that
;; are "bound to NIL", explicitly or implicitly,
;; do not appear in the atoms-family)
(list set (quote SymbolName) 0)
;; In "native "AutoLISP", the symbol would
;; now be the first one in the atoms-family
;; list. Not so in Visual LISP. So we have
;; to look up the symbol [as a symbol] using
;; (member ...), compute its position in the
;; list, and then extract it from the string
;; version of the atoms-family list. This
;; also sets up the return value.
(list nth
(list -
(list length (list atoms-family 0))
(list length
(list member
(list (quote quote) SymbolName)
(list atoms-family 0)
) ;_ end list
) ;_ end list
) ;_ end list
(list atoms-family 1)
) ;_ end list
;; End of the dynamic function
) ;_ end list
)
) ;_ end progn
;; If the argument is not a symbol, return NIL
nil
) ;_ end if
) ;_ end defun
jrf
Member of the Autodesk Discussion Forum Moderator Program
In article <38D2D6BA.1CA7E8D1@mindspring.com>, Andrew Wilford wrote:
> Although I am familiar with VL it is for a client who only has plain
> lisp. I didn't think there was an easy way.
