Selection Lisp counting objects selected

[Anonymous]

I have a simple lisp that selects (and holds using sssetfirst) Mtest & Text.

I would like it to display on the command line how many objects are selected, I cannot get it to do this.

My code has the offending line blanked off using ;;

It works fine with the line not used & no variables declared

(defun C:SELECT_TEXT ( /sset)
(sssetfirst nil (ssget '((0 . "TEXT,MTEXT"))))
;;(princ (strcat "\n "(itoa (sslength sset)) items selected"))
(princ)
)

[Anonymous]

Hi sbanister,

His lack of space beetwen / and variable and your variblable is not used (no setq in your programme).

Try this code :

(defun C:SELECT_TEXT (/ sset)
(setq sset (ssget '((0 . "TEXT,MTEXT"))))
(princ (strcat "\n" (itoa (sslength sset)) " items selected"))
(princ)
)

The same shortly without variable.

(defun C:SELECT_TEXT ()
(princ (strcat "\n" (itoa (sslength (ssget '((0 . "TEXT,MTEXT"))))) " items selected"))
(princ)
)

Sorry for my english I'm french.

Olivier

[Anonymous]

Hi sbanister,Oliver

Oliver's code is forcing user to select text, it is not going to count how many objects are already selected, because he removed sssetfirst.

If I understand well sbanister want to count how many text objects are selected.

This is the version with sssetfirst:

(defun C:SELECT_TEXT ( / sset)
(sssetfirst nil (setq sset (ssget '((0 . "TEXT,MTEXT")))))
(princ (strcat "\n" (itoa (sslength sset)) " items selected"))
(princ)
)

Sbanister, problem with your code was, beside missing space while localizing sset variable, there was no definition of the same.

You need to use setq sset , to define this variable and store selection set in it so, that you could later use sslength to see the number of objects in selection set. Second problem was in strcat function, which is connecting strings in one. You need to put " after itoa function.

 Hope this help,

dicra

[Anonymous · Accepted solution]

---

@Anonymous wrote:

Hi sbanister,Oliver

Oliver's code is forcing user to select text, it is not going to count how many objects are already selected, because he removed sssetfirst.

---

Oliver, 

Sorry my mistake, I just made few tests, looks like there is no need for sssetfirst in this code.

Hope you don't mind.

dicra

[hmsilva]

Hi sbanister,

in addition to what Olivier have pointed out, 'the lack of space beetwen / and variable', when we code, is essential to check/validate, the return from a function, before providing that return to to another function as argument.
In your code, if the user press enter before select any object, the code will throw an error as '; error: bad argument type: lselsetp nil'...

I would suggest something like this:

(defun C:SELECT_TEXT (/ len sset)
  (if (setq sset (ssget '((0 . "TEXT,MTEXT"))))
    (princ (strcat "\n" (itoa (setq len (sslength sset))) (if (> len 1) " items" " item") " selected"))
    (princ "\n 0 items selected")
  )
(princ)
)

Hope that helps
Henrique

[Anonymous]

Thanks both of you, Dicra's code sorted it though as I wanted the selection to remain selected. Hence I used sssetfirst.

Very useful if I need to quickly delete or copy text from a congested area of a drawing

[Anonymous]

sbanister, Your welcome,

I would suggest you, to use Henrique's code, because of , what he is saying for the errors which are possible, when there are no text objects in selection set.

dicra

[Anonymous]

I take your point, but it doesn't retain selection (sssetfirst)

[Anonymous]

If you insist for sssetfirs, whit Henrique's remarks for error, maybe something like this:

(defun C:SELECT_TEXT ( / sset)
(sssetfirst nil (setq sset (ssget '((0 . "TEXT,MTEXT")))))

  (if sset
    (princ (strcat "\n "(itoa (sslength sset))" items selected"))
    (princ "\n 0 items selected")
    )
  (princ)
)

dicra

[Anonymous · Accepted solution]

Spot on, thanks Dicra.