select textsize lisp

[nychoe1]

hello, 

I'm writing a Lisp, and going to ask for help.

I do not know which part is wrong

(defun c:tt (/ ss textsi1 textsi2)
  (prompt "\nselect textsize")
  (setq textsi1 (getreal "\ninput textsize"))
  (setq textsi2 (getreal "\ninput textsize"))
  (setq ss (ssget '((-4 . "<and")
  (0 "text,mtext")
  (-4 "<") (40 textsi1)
  (-4 ">") (40 textsi2)
  (-4 . "and>"))
  ))
(sssetfirst nil ss)
(princ)
) ;defun

[ВeekeeCZ · Accepted solution]

Guess you want to select texts outside specified range? Or if not, adjust conditions as required.

(defun c:SelectTextBySize (/ ss textsi1 textsi2)

  (if (and (setq textsi1 (getreal "\nMinimum textsize: "))
	   (setq textsi2 (getreal "\nMaximum textsize: "))
	   (setq ss (ssget (list '(0 . "text,mtext")
				 '(-4 . "<or")
				 '(-4 . "<") (cons 40 textsi1)
				 '(-4 . ">") (cons 40 textsi2)
				 '(-4 . "or>"))))
	   )
    (sssetfirst nil ss))
  (princ)
  )

The issue is the list building. Once you use a variable, you need to use (list) or (cons) to evaluate the variables. Constants as strings and integers could be just quoted (the black ones).

And be careful, there are many doted pairs needed.

[nychoe1]

thank you