Retrieving elements from a "list of lists"
The 'itemlist' should not have commas between entries. They are not part of the standard way of building a list, and they "count" as items in the list, and make things more complicated than they need to be. Try it without them:
(setq itemlist '(("DWG_01" "DESC_01" "PART_01") ("DWG_02" "DESC_02" "PART_02") ("DWG_03" "DESC_03" "PART_03")))
That is an association list [actually, with or without the commas], and you can get the parts related to the first entry easily. Presumably you put that value you've determined into a variable:
(setq attval "DWG_01")
Then there's no need to step through the list of lists, checking whether the first item in each matches that value, but you can go straight to the one you want:
Command: (assoc attval itemlist)
returns
("DWG_01" "DESC_01" "PART_01")
You can get the second and third ones in one list, if that's of any use to you, just as entity data is often extracted:
(setq 2nd3rd (cdr (assoc attval itemlist)))
returns
("DESC_01" "PART_01")
from which you can pull out the pieces separately, either to put into variables or just to use without variables.
Or, you can set them into their own separate variables directly, without the middle-man:
(setq
2nd (cadr (assoc attval itemlist))
3rd (caddr (assoc attval itemlist))
)
This could all be done with the commas in there, using different (ca....) functions, or (nth), but I don't see any reason for doing so.
@dmfrazier wrote:
...
Now this has uncovered another issue: I'm modifying (replacing) the values of two attributes in the selected block insert. One of the attributes changes correctly, but the other doesn't change at all, and there's no error message. I suspect that it is due to the fact that this particular attribute is multi-line.
To change the attributes I'm using the following (sub)function:
...
Hi dmfrazier,
MText in ATTRIBs have two 'assoc 1', the first, the default value "" and the second, after (101 . "Embedded Object")' is the string.
Try to change (untested)
(setq E (subst (cons 1 VAL) (assoc 1 E) E)
FndLst (append FndLst (list TAG))
)
to
(if (setq memb (member '(101 . "Embedded Object") E))
(setq E (subst (cons 1 VAL) (assoc 1 memb) E)
FndLst (append FndLst (list TAG))
)
(setq E (subst (cons 1 VAL) (assoc 1 E) E)
FndLst (append FndLst (list TAG))
)
)
But I would suggest to use ActveX method because if the MText string is too long, It will be divided by multiple 'assoc 3' 250-character long...
Hope this helps,
Henrique
@dmfrazier wrote:
Thanks, Henrique.
No, that doesn't work - now it doesn't change either type of attribute.
I did some research and had learned what you have said about the second "assoc 1". I think I might need to produce a second version of the function specifically for multi-line attributes. I will work on that tomorrow.
Oh, P.S., the longer-than-250-character issue will not apply in my case.
Did you test the mod with the edited code?
I had a typo in my original post...
;;; Function to update one or more block attribute value(s) in a block insert.
;;; Insert can be identified by it's Entity ID or name.
;;; Passed: <Block Ename or Block name> <List of the type: ((Attribute Name . New Value)(... ))>
(defun UpdBlk (BlkEN AttLst / OrgEN SS E ITM TagIdx AttNam AttVal TAG FndLst memb)
(setq TagIdx nil)
(setq OrgEN BlkEN)
(setq FndLst '("FN" "BOM_CCN" "BOM_STRID" "BOM_STRREV"))
(if (= (type BlkEN) 'STR)
(if (setq SS (ssget "X" (list (cons 0 "INSERT") (cons 2 BlkEN))))
(setq BlkEN (ssname SS 0))
(setq BlkEN nil)
)
)
(foreach ITM AttLst
(setq TagIdx (append TagIdx (list (car ITM))))
)
(if BlkEN
(progn
(setq E (entget (entnext BlkEN)))
(while (= (cdr (assoc 0 E)) "ATTRIB")
(setq TAG (cdr (assoc 2 E)))
(if (member TAG TagIdx)
(progn
(setq VAL (cdr (assoc TAG AttLst)))
(if (not VAL)
(setq VAL "??")
)
(if (= (strcase VAL) "**ERROR**")
(setq VAL "")
)
(if (setq memb (member '(101 . "Embedded Object") E))
(setq E (subst (cons 1 VAL) (assoc 1 memb) E)
FndLst (append FndLst (list TAG))
)
(setq E (subst (cons 1 VAL) (assoc 1 E) E)
FndLst (append FndLst (list TAG))
)
)
(entmod E)
)
)
(setq E (entget (entnext (cdr (assoc -1 E)))))
)
(entupd BlkEN)
(foreach ITM AttLst
(setq ITM (car ITM))
(if (not (member ITM FndLst))
(if ITM
(princ (strcat "\nError, No attribute named '"
ITM
"' exists in block "
(cdr (assoc 2 (entget BlkEN)))
" !"
)
)
(princ
"\nError, Invalid Attribute 'TAG' name passed to Block Attribute update function!"
)
)
)
)
) ;progn
(if (= (type OrgEN) 'STR)
(alert (strcat "Error! Invalid Block Name ["
OrgEN
"] passed to block update!"
)
)
(progn
(princ "\nPassed entity name was [")
(princ OrgEN)
(princ "] ")
(alert
"Error! Invalid Block Entity Name was passed to block update!
\nInvalid entry's name is on command printed below."
)
) ;progn
) ;if
) ;if
) ;defun
Henrique
@dmfrazier wrote:
I didn't realize you had edited your post, so, no, I had not tried the latest code.
I just used it and it works! Fantastic!
Thank you so much, Henrique!
You're welcome, dmfrazier
Glad I could help!
Henrique
