Push PageSetup changes to Layout with LISP

[Anonymous]

Hi all,

What I need is kind of hard for me to explain. Instead I recorded a short video showing what I mean. Basically I was wondering if there is chance that I could avoid Running PageSetup window everytime, press Modify button and then OK it to update my background to fit the viewport. (Am I write on terminologies here ?!)

Regards

[hencoop]

I have a lisp routine I use to set page setups.

setstdpage.lsp which requires several subroutines:

Doslib (free from Robert McNeeal & Associates

check_for_doslib (to load the correct version)

ukword (our initget - getkword handler)

ustr (our initget - getstring handler)

It hard codes the path to our template files that contain the pagesetups we use.

The template files are swapped out depending upon the user because AutoCAD 2013 page setups used by one user are incompatible with other versions of AutoCAD we use (at least as currently installed here).

If you replace our template section of the code setting your template path it should work for you.  Removing our template code may eliminate the need for DOSLIB and thus CHECK_FOR_DOSLIB.

[joselggalan]

Try one of these two functions.
Ideally, it should work with the first one (RefreshAllLayout_1)

 (defun C:RefreshAllLayout_1 ( / oLayout AcDoc)
  (setq AcDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
  (vlax-for oLayout (vla-get-layouts AcDoc)
    (cond
     ((= (vla-get-ModelType oLayout) :vlax-true))
     (T
      (vla-RefreshPlotDeviceInfo oLayout)
     )
    );c.cond 
   )
  (princ)
 )

(defun C:RefreshAllLayout_2 ( / oLayout NameLayout AcDoc oActLayout)
  (setq AcDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
   (setq oActLayout  (vla-get-ActiveLayout AcDoc))
   (vlax-for oLayout (vla-get-layouts AcDoc)
    (cond
     ((= (vla-get-ModelType oLayout) :vlax-true))
     (T
      (vla-put-ActiveLayout AcDoc oLayout)
      (vla-ZoomExtents (vlax-get-acad-object))
      (vla-RefreshPlotDeviceInfo oLayout)
      (vla-Regen AcDoc acActiveViewport)
     )
    );c.cond 
   )
   (vla-put-ActiveLayout AcDoc oActLayout)
  (princ)
 )

[Anonymous]

Dude, I am using your first code. Although it does the job but I noticed some weird behaviour. 

Here is how my layout looks like before running your code:

Immediately after running your code, here is what I get:

Any idea why the plot unit is changed to "INCH"?

[hencoop]

The Page Setup should have a name.  The program sets the page setup by name.  If after it has been set the name is <None> then there is a problem with the source of the page setup being used or it is coming from a template file that was last saved from a different version of AutoCAD.  

The change of units is part of this problem.

In our office one user is on Civil 3D 2013. Its page setups will produce similar results in my Civil 3D 2014.  Use a template file that you have created or revised.  Set your desired page setup settings and then use the Add... button to update the definitions to make them work in your sessions.

Also, if you are plotting a layout the plot area is best if set to "Layout" which will always correspond to the paper size of your page setup.  Plotting Layout is highly recommended for its easy association with a Sheet Set to access its great plotting and publishing abilities.

[joselggalan]

try this

(defun C:RefreshAllLayout_1 (/ oLayout AcDoc)
 (setq AcDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (vlax-for oLayout (vla-get-layouts AcDoc)
  (cond
   ((= (vla-get-ModelType oLayout) :vlax-true))
   (T
    (vla-RefreshPlotDeviceInfo oLayout)
    (vla-put-PaperUnits oLayout acMillimeters)
    )
   );c.cond 
  );c.vlax-for
 (princ)
);c.defun

[Anonymous]

That's more or less what I am trying to achieve in 1000+ drawings I have in front of me for a brown field job. I need LISP routines for this mean. But thanks for the reply.

[Anonymous]

Nothing happens i.e. no refreshing whatsoever. 

[joselggalan]

You can put a sample dwg file, to try .. thanks

[Anonymous]

Sample file attached. Tnx for your help.

EDIT:

-----------------

I think I found out what was wrong. The line (command "regenall") was missing. 

[joselggalan]

Anyway, try this...

(defun C:RefreshAllLayout_3 (/ acApp AcDoc oActLayout oLayout
			       PlotOrigin PaperUnits PlotType CenterPlot
			    )	  
 (setq acApp (vlax-get-acad-object))
 (setq AcDoc (vla-get-ActiveDocument acApp))
 (setq oActLayout  (vla-get-ActiveLayout AcDoc))
 (vlax-for oLayout (vla-get-layouts AcDoc)
  (cond
   ((= (vla-get-ModelType oLayout) :vlax-true))
   (T
    (vla-put-ActiveLayout AcDoc oLayout)
    (setq PaperUnits (vla-get-PaperUnits oLayout))
    (setq PlotOrigin (vla-get-PlotOrigin oLayout))
    (setq PlotType   (vla-get-PlotType oLayout))
    (setq CenterPlot (vla-get-CenterPlot oLayout))
    
    (vla-RefreshPlotDeviceInfo oLayout)
    (vla-put-PaperUnits oLayout PaperUnits)
    (vla-put-PlotOrigin oLayout PlotOrigin)
    (vla-put-PlotType oLayout acExtents)
    (vla-Regen AcDoc acActiveViewport)
    (vla-ZoomExtents acApp)
    (vla-put-CenterPlot oLayout CenterPlot)
    (vla-put-PlotType oLayout PlotType)
   )
  );c.cond 
 );c.vlax-for
 (vla-put-ActiveLayout AcDoc oActLayout)
 (princ)
);c.defun

[joselggalan · Accepted solution]

Apologies, some code was missing so that everything went well.

(defun C:RefreshAllLayout_3 (/ acApp AcDoc oActLayout oLayout
			       PlotOrigin PaperUnits PlotType CenterPlot
			    )	  
 (setq acApp (vlax-get-acad-object))
 (setq AcDoc (vla-get-ActiveDocument acApp))
 (setq oActLayout  (vla-get-ActiveLayout AcDoc))
 (vlax-for oLayout (vla-get-layouts AcDoc)
  (cond
   ((= (vla-get-ModelType oLayout) :vlax-true))
   (T
    (vla-put-ActiveLayout AcDoc oLayout)
    (if (= (vla-get-MSpace AcDoc) :vlax-true)
     (vla-put-MSpace AcDoc :vlax-false)
    )
    (setq PaperUnits (vla-get-PaperUnits oLayout))
    (setq PlotOrigin (vla-get-PlotOrigin oLayout))
    (setq PlotType   (vla-get-PlotType oLayout))
    (setq CenterPlot (vla-get-CenterPlot oLayout))
    
    (vla-RefreshPlotDeviceInfo oLayout)
    (vla-put-PaperUnits oLayout PaperUnits)
    (vla-put-PlotOrigin oLayout PlotOrigin)
    (vla-put-PlotType oLayout acExtents)
    (vla-Regen AcDoc acActiveViewport)
    (vla-ZoomExtents acApp)
    (vla-put-CenterPlot oLayout CenterPlot)
    (vla-put-PlotType oLayout PlotType)
   )
  );c.cond 
 );c.vlax-for
 (vla-put-ActiveLayout AcDoc oActLayout)
 (princ)
);c.defun

[Anonymous]

This one works exactly as I wanted to.

Thank you so much for your time.