Programming Challenge 6/22
@john.uhden wrote:
....
Where do "virtual" lines come into this?
....
I meant that in the sense that you were not looking for a Line [or Polyline or Ray or Xline] to be drawn, but only wanted the location on the Ellipse at which such an object, running in the designated direction, would be tangent to the Ellipse. A place to put such an object, of whatever type you want, but not an actual drawn object.
The word "tangent" means "touching." It has come to mean, in mathematical terms, touching in a particular way, but in my opinion, doing so in either direction still qualifies. Nevertheless, my routine above satisfies your limitation on the meaning of it.
EDIT: Further consideration: By your definition, not one of these Circles, which were drawn with the Circle command's Tangent-Tangent-Radius option, is tangent to any other:
a notion which I find downright ludicrous.
@dbroad wrote:
I think John is looking for a vector, a ray tangent to the ellipse, not an xline.
[No, he's looking for a location on the Ellipse at which such a vector or ray would be tangent to it.]
Hi Dbroad I think your right go back to 1st principles for a ellipse found another image.
Taking this theory its easy to draw a tangent at a ellipse point, using normal Acad, line circle etc.
Ok for the tricky bit given Johns task
The ellipse above is 200x 100 lower left 0,0 for simplicity.
Dumpit reveals a lot more useful stuff than entget as 1st step.
; Center = (100.0 50.0 0.0)
; EndAngle = 6.28318530717959
; EndParameter = 6.28318530717959
; EndPoint (RO) = (0.0 50.0 0.0)
; EntityName (RO) = "AcDbEllipse"
; MajorAxis = (-100.0 0.0 0.0)
; MajorRadius = 100.0
; MinorAxis (RO) = (0.0 -50.0 0.0)
; MinorRadius = 50.0
; Normal = (0.0 0.0 1.0)
; RadiusRatio = 0.5
; StartAngle = 0.0
The rotated ellipse and a chunk missing rotated around 100,50 like Johns.
Center = (100.0 50.0 0.0)
; EndAngle = 5.41444906889887
; EndParameter = 5.11248640424141
; EndPoint (RO) = (89.2931875880689 109.356871670377 0.0)
; EntityName (RO) = "AcDbEllipse"
; HasExtensionDictionary (RO) = 0
; MajorAxis = (-86.6025403784439 50.0 0.0)
; MajorRadius = 100.0
; MinorAxis (RO) = (-25.0 -43.3012701892219 0.0)
; MinorRadius = 50.0
; Normal = (0.0 0.0 1.0)
; RadiusRatio = 0.5
; StartAngle = 0.0866080357023967
; StartParameter = 0.171935938283013
; StartPoint (RO) = (10.3971284385284 91.8543526740536 0.0)
Given major radius , minor radius, should be able to work out the focus pts, using intersectwith can get ang1 = pt-> focus1, ang2 = pt -> focus2 so 90 angle is (ang1 ang2) / 2 add 90 is it tangent angle, if yes solved for John. Just need to work out from info center and angle of major axis.
All this geometry has given me a thirst so will think some more whilst having a quite beer.
Hi,
This is certainly not the most efficient way, but it seems to work as expected.
The code uses a dichotomic search of the point according to the angle accuracy (hard coded).
(defun getPointAtTangent (ellipse tanAngle / wrapTo2Pi angbase param delta ang)
(defun wrapTo2Pi (a)
(cond
((< a 0) (wrapTo2Pi (+ a (* PI 2))))
((< (* PI 2) a) (rem a (* PI 2)))
(T a)
)
)
(setq angbase (angle '(0. 0. 0.) (vlax-curve-getFirstDeriv ellipse 0.))
tanAngle (wrapTo2Pi (- tanAngle angbase))
param 0.
delta (* 2. PI)
)
(while
(not
(equal (setq ang
(wrapTo2Pi
(- (angle '(0. 0. 0.) (vlax-curve-getFirstDeriv ellipse param)) angbase)
)
)
tanAngle
1e-12 ; <- angle accuracy
)
)
(setq param (if (< (- tanAngle ang) 0.)
(- param (setq delta (* delta 0.5)))
(+ param (setq delta (* delta 0.5)))
)
)
(if (< param 0.)
(setq param (+ param (* 2. PI)))
)
)
(vlax-curve-getPointAtParam ellipse param)
)A testing command:
(defun c:test (/ e a p)
(if (and (setq e (car (entsel)))
(= (cdr (assoc 0 (entget e))) "ELLIPSE")
)
(while (setq a (getangle "\nTangent direction: "))
(setq p (getPointAtTangent e a))
(entmake (list (cons 0 "RAY")
(cons 100 "AcDbEntity")
(cons 100 "AcDbRay")
(cons 10 p)
(list 11 (cos a) (sin a) 0.0)
)
)
)
)
(princ)
)
This was really fun! I think I have a useable solution. My little brother (Drue) helped me with the hard math parts. He's a genius.
The main function (to pass ellipse and angle) are toward the bottom. The last function is a TEST command.
Given your original ellipse, my TEST command creates a Circle of one acceptable tangent point on the ellipse...
The general workflow is as follows:
- Ellipse and Angle passed to main function
- Pretend center of ellipse is at origin, and rotation is 0
--- Also, adjust slope angle since we may have imaginarily rotated ellipse
- do important math stuff to determine 2 points where tangent line intersects
- translate those intersection points back to original ellipse placement
- finally, test if they're actually on the ellipse (ellipse could be open)
- throw a circle on the tangential points for user to see
;; Returns list of 4 ellipse details...
;; (centerPt majorRadis minorRadius rotationAngleToMajorRadius)
(defun EllipseInfo (e / eg)
(setq eg (entget e))
(list
(cdr (assoc 10 eg))
(getpropertyvalue e "MajorRadius")
(getpropertyvalue e "MinorRadius")
(angle '(0. 0. 0.) (cdr (assoc 11 eg)))
)
)
;; Converts 2 tangential points at origin ellipse to corrected 'rotated' points around origin
;; pts - list, of 2 points as returned by 'TangentPointsAtOrigin'
;; eInfo - list, of 4 ellipse info items
(defun RotateOriginPoints (pts eInfo / ptZero r a)
(setq ptZero '(0. 0. 0.))
(setq r (distance ptZero (car pts)))
(setq a (last eInfo))
(mapcar
'(lambda (p)
(mapcar
'(lambda (n f) (* r (f (+ a (angle ptZero p)))))
p
(list cos sin)
)
)
pts
)
);defun
;; Translates 2 ellipse tangent points (at origin) to current ellipse location
;; pts - list, of 2 tangent points near origin
;; eInfo - list, of 4 ellipse info items
;; returns - list, of 2 tangent points on ellipse
(defun TranslateOriginPoints (pts eInfo / )
(mapcar
'(lambda (p) (mapcar '+ (car eInfo) p))
(RotateOriginPoints pts eInfo)
)
);defun
;; Determines X coord val (in positive Y area) for ellipse w/ zero rotation at origin
;; ALWAYS assumes Major radius is in X-direction, minor in Y-direction
;; slope - real, slope of Tangent line we are trying to find coordinate of
;; xR - real, the MAJOR radius of the ellipse
;; yR - real, the MINOR radius of the ellipse
(defun SolveForXAtOrigin (slope xR yR / )
(setq *x*
(sqrt
(/
(* (expt slope 2) (expt xR 4))
(+ (* (expt slope 2) (expt xR 2))
(expt yR 2)
)
)
)
)
(cond
((minusp slope) *x*)
(t (- *x*))
)
)
;; Determines positive Y coord val given corresponding X coord from 'SolveForXAtOrigin'
;; x - real, X coord value from 'SolveForXAtOrigin'
;; xR - real, the MAJOR radius of the ellipse
;; yR - real, the MINOR radius of the ellipse
(defun SolveForYAfterX (x xR yR / )
(setq *y*
(sqrt
(- (expt yR 2)
(* (/ (expt yR 2) (expt xR 2))
(expt x 2)
)
)
)
)
)
;; Returns 2 points where tangent line intersects ellipse at origin
;; slope - real, slope of tangent line to be checked
;; eInfo - list, of 4 ellipse info items
;; returns - list, of 2 tangent points near origin
(defun TangentPointsAtOrigin (slope eInfo / p1 x)
(list
(setq p1
(list
(setq x (SolveForXAtOrigin slope (cadr eInfo) (caddr eInfo)))
(SolveForYAfterX x (cadr eInfo) (caddr eInfo))
)
)
(mapcar '- p1)
)
);defun
;; Tangent - Lee Mac
;; Args: x - real
(defun tan ( x )
(if (not (equal 0.0 (cos x) 1e-10))
(/ (sin x) (cos x))
)
)
;; Radians to Slope
;; r - real, radian value
;; returns - real, slope of radian value
(defun Rad2Slope (r / )
(tan r)
)
;; Calculates Points where Tangent line intersects Ellipse (2 or fewer points)
;; e - ename, of ellipse
;; a - real, angle in radians of line tangent to ellipse
;; returns - list, of points where tangent slope intersects ellipse, or nil if none
(defun EllipseTangentPoints (e a / ev eInfo)
(setq ev (vlax-ename->vla-object e))
(setq eInfo (EllipseInfo e))
(setq a (- a (last eInfo)))
(vl-remove-if-not
'(lambda (p) (vlax-curve-getParamAtPoint ev p))
(TranslateOriginPoints
(TangentPointsAtOrigin (Rad2Slope a) eInfo)
eInfo
)
)
)
;; Creates circles (w/ 1 unit radius) at tangent points on selected ellipse
(defun c:TEST ( / ellipse a etp)
(if (and (setq ellipse (car (entsel "\nSelect Ellipse: ")))
(eq "ELLIPSE" (cdr (assoc 0 (entget ellipse))))
(setq a 5.8)) ;<<--- DEFAULT TANGENT ANGLE PROVIDED BY JOHN !!! -----
(progn
(setq etp (EllipseTangentPoints ellipse a))
(if etp
(progn
(prompt "\nEllipse tangent points are: ") (print etp)
(foreach p etp
(command "_.CIRCLE" "_non" p 1)
)
)
;else
(prompt "\n...No ellipse tangent points were found!")
)
)
;else
(prompt "\nMust select an ELLIPSE.")
)
(princ)
)
Best,
~DD
