Princ name of layer to command line

[Anonymous]

Please can someone help with an assoc & entget puzzle?

I'm having trouble making this lisp print the name of the layer selected printo to the command line.

It's supposed to display Layer 'mylayer' selected & at the end say x Items Deleted On Layer 'Mylayer'

This line is supposed to return the name of the layer:

(assoc 8 (entget ssl))

Code so far:

(defun c:dlayer ( / ssl ss2)
  (if (and (princ "\nSelect Layer to Delete ")
	   (setq ssl (ssget "_+.:E:S"))
	   (princ (strcat "\n Layer '" (assoc 8 (entget ssl)) "' Selected"))
	   (setq ss2 (ssget (list (assoc 8 (entget (ssname ssl 0)))))))
    (command "_.erase" ss2 "")
    )
  (if (= ss2 nil)
    (princ "\n No Items found")
    (princ (strcat "\n "(itoa (sslength ss2))" Items Deleted On Layer" (assoc 8 (entget ssl))))
    )
  (princ)
)

[ВeekeeCZ]

Maybe something like this....

(defun c:dlayer ( / ssl ss2 lay)
  (if (and (princ "\nSelect Object to define Layer to Delete, ")
	   (setq ssl (ssget "_+.:E:S"))
	   (= 1 (sslength ssl))
	   (princ (strcat "\n Layer '" (setq lay (cdr (assoc 8 (entget (ssname ssl 0))))) "' Selected"))
	   (setq ss2 (ssget (list (cons 8 lay))))
	   )
    (progn
      (command "_.erase" ss2 "")
      (princ (strcat "\n "(itoa (sslength ss2))" Items Deleted On Layer '" lay "'.")))
    (princ " Nothing erased."))
  (princ)
)

;if you have selection set, then layer
(cdr (assoc 8 (entget (ssname (ssget) i)))) ; where i=0 as the first item of selectin set

;if you have entity selected using (entsel)
(cdr (assoc 8 (entget (car (entsel)))))

[Anonymous]

Ahh I see now

I copied the code from a lisp that uses nentsel & I used a selection set.

It's clear now.

Thank you BeekeeCZ