Polyline lisp
I just ran FOO.lsp (left) & my PlnLenAng.lsp (right) and Distance/Length matches as well as Angle in Radians.
Accepted solution
I again modified PlnLenAng.lsp code to meet your dwg angle requirements...give this a try:
; PlnLenAng places distance of segment length & angle at pline's vertex
; Response to OP:
; https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/polyline-lisp/m-p/11777166#M444164
(defun c:PlnLenAng
(/
*error* adoc ang ang_lst del dst DtR corect_ang csv csvfil eo
i lst lst2 luprec p0 p1 pick_poly_chk rad RtD text_height txtstr w_ang?
)
(if(not(car (atoms-family 1 '("vl-load-com"))))(vl-load-com))
; error function
(defun *error* (msg)
(and
msg
(not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*,*EXIT*"))
(princ (strcat "\nError: " msg))
)
(if
(= 8 (logand (getvar 'undoctl) 8))
(vla-endundomark acdoc)
)
(princ)
) ; defun *error*
; w_ang? function by CADaSchtroumpf modified to return angle in degrees using lunit prec
; https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/list-polyline-angles/m-p/3019110#M296526
(defun w_ang? ( p1 px p2 / l_pt l_d p ang)
(setq
l_pt (mapcar '(lambda (x) (list (car x) (cadr x))) (list px p1 p2))
l_d (mapcar 'distance l_pt (append (cdr l_pt) (list (car l_pt))))
p (/ (apply '+ l_d) 2.0)
)
(if (zerop (* p (- p (cadr l_d))))
(setq ang pi)
(setq ang (* (atan (sqrt (/ (* (- p (car l_d)) (- p (caddr l_d))) (* p (- p (cadr l_d)))))) 2.0))
)
; (angtos (- pi ang) (getvar "AUNITS") (getvar "AUPREC"))
(angtos (- pi ang) 0 (getvar "LUPREC")) ; return angle in degrees as string
) ; defun w_ang?
; converts radians to degrees
(defun RtD (r) (* 180.0 (/ r pi)))
; converts degrees to radians
(defun DtR (d) (* pi (/ d 180.0)))
; select pline validation
(defun pick_poly_chk (/ e)
(setq e (car(entsel "\nSelect Open Polyline: ")))
(if
(or
(not e)
(= (getvar 'Errno) 7)
(not (eq "LWPOLYLINE"(cdr(assoc 0 (entget e)))))
(not (zerop (cdr(assoc 70 (entget e))))) ; not closed
)
(pick_poly_chk)
e
)
) ; defun pick_poly_chk
; angle adjustment
(defun corect_ang (ang)(if (and (>= ang (* 0.5 pi))(< ang (* 1.5 pi))) (setq ang (+ ang pi))) ang)
; main function
(setq adoc (vla-get-activedocument (vlax-get-acad-object)))
(vla-endundomark adoc)
(vla-startundomark adoc)
(if(not *csv*)(setq *csv* (strcat(getvar"dwgprefix")(vl-filename-base (getvar"dwgname")))))
(setq csv(getfiled "Enter Name of CSV File To Save Segment Distances & Angles" *csv* "csv" 1))
(if csv
(progn
(setq *csv* csv)
(setq csvfil (open *csv* "w")) ; open csv to write info
(write-line (strcat"Length, Angle <Radians>, Angle <Degrees>") csvfil) ; segment length & angle Column Title
(if(not *text_height*)(setq *text_height* (getvar"textsize")))
(setq text_height (getreal (strcat"\nText height <" (rtos *text_height* 2 (getvar"luprec"))">: ")))
(if(not text_height)(setq text_height *text_height*)(setq *text_height* text_height))
(if(setq eo (pick_poly_chk)) ; pick pline
(progn
(foreach x (entget eo) ; get pline entity's data
(if (= (car x) 10)
(setq lst (append lst (list (cdr x)))) ; get pline vertices
)
)
; for angle calc
; code by CADaSchtroumpf
; https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/list-polyline-angles/m-p/3019110#M296526
(setq lst2 lst)
(while (and (car lst2) (cadr lst2) (caddr lst2))
(setq
ang_lst (cons (w_ang? (car lst2) (cadr lst2) (caddr lst2)) ang_lst)
lst2 (cdr lst2)
)
) ; while
(setq ang_lst (append (list"0") (reverse ang_lst))) ; set first angle = 0
(setq luprec (getvar"luprec")) ; get current unit decimal precision
(setq dst(mapcar 'distance lst (cdr lst))) ; get distance between vertices
(setq p0 (nth 0 lst)) ; get 1st point
(setq p1 (nth 1 lst)) ; get 2nd point
(setq i 0 del 0)
(repeat (length dst)
(setq p0 (nth i lst)) ; get point
(setq p1 (nth (1+ i) lst)) ; get next point
(setq del (nth i dst)) ; get distance value item from list
(setq ang (distof (nth i ang_lst)))
(setq rad (DtR ang))
(setq txtstr (strcat (rtos del 2 luprec)","(rtos rad 2 luprec)","(rtos ang 2 luprec))) ; segment length & angle in radians & degrees
; create text
(entmakex
(list
(cons 0 "TEXT")
(cons 100 "AcDbEntity")
(cons 100 "AcDbText")
(cons 1 txtstr)
(cons 10 p1)
(cons 40 *text_height*)
(cons 7 "STANDARD")
(cons 8 "PlnLenAng")
(cons 50 (corect_ang(+ (angle p0 p1) (* 0.5 pi))))
)
) ; entmake
(write-line txtstr csvfil) ; write info to csv
(setq i (1+ i)) ; next list item
) ; repeat cycle through list of distances
(close csvfil) ; close csv
(startapp "Notepad" *csv*)
) ; progn
(progn
(princ"\nNo Open Pline Selected.")(princ)
)
) ; if
) ; progn
(progn
(princ"\nNo CSV File Entered.")(princ)
)
) ; if
(vla-endundomark adoc)
(princ)
) ; defun
