object selected by lisp in all drawings ..
plz find the attached drawing.
lisp working exacted in this but in other drawings not getting accurate results.
for select object select 3 pair of text.
@jaggisingh003 wrote:
plz find the attached drawing.
lisp working exacted in this but in other drawings not getting accurate results.
for select object select 3 pair of text.
Hi @jaggisingh003 , what is considered as the "accurate" results? and what is not ? is it shown on the drawinng you posted?
Can you somehow show us please the desired result.
This is the format for the correct results as per the codes I want in drawing 4 results is ok but in next drawing values not getting the exact places.
From selection to right to left or left to right.
I dont get this:
...
(setq s (entsel "\nSelect exiting ACC1 block"))
...
Which block is this one?
Is that the one with 738.50 --- 702.00 ?
Does the block or a block always exists for selection?
Is there a reason why your using vanilla lisp and not ActiveX [ Vlax... ]?
Is this the correct result?
Please confirm if this is right
@pbejse wrote:
Is there a reason why your using vanilla lisp and not ActiveX [ Vlax... ]?
.....
Please confirm if this is right
Reason I asked that is because you might be using Autocad Mac Version.
Based on your reaction of clicking "like" I will assume that it is correct. and you are using windows version of Autocad.
[ code removed: delayed response ]
AND please let me kow if you do need a non ActiveX version of the rouinte.
HTH
@pbejse Sorry for the late reply
Some issues in internet connections.
I m not using the mac.
see attached images for final results.
I am new to AutoLISP and try to learn and don't have much knowledge of active -x(visual lisp).
I see, have a look at the picture below:
See how you had it on your posted code p6 as tag "loc-1", p2 as tag "ch-1" and so on. Your code is the only reference I have, so it ended up like that.
Anyhoo, I corrected the order now on this code, please tell me how it goes
(defun C:ACC ( / _insertAtt data pt1 s2 ss s1 s pt i ent data)
(defun _insertAtt (pt bn)
(vlax-invoke (vlax-get (vla-get-ActiveLayout
(vla-get-activedocument
(vlax-get-acad-object)))'Block)
'InsertBlock pt bn 1 1 1 0)
)
(if
(and
(tblsearch "BLOCK" "CO-ACC")
(tblsearch "BLOCK" "SC-ACC")
(setq data nil
pt1 (getpoint "\nSelected point for CONDUCTOR DETAILS CO-ACC"))
(tblsearch "BLOCK" "CO-ACC")
(setq s2 (vlax-vla-object->ename (_insertAtt pt1 "CO-ACC" )))
(setq ss (ssget '((0 . "text")(1 . "*#/#*"))))
( = (setq i (sslength ss)) 6)
(setq pt (getpoint "\nSelected point for SCHEMATIC DIAGRAM SC-ACC"))
(setq s1 (vlax-vla-object->ename (_insertAtt pt "SC-ACC")))
(setq s (entsel "\nSelect exiting ACC1 block"))
(eq "Acc1" (Cdr (Assoc 2 (entget (setq s (Car s))))))
)
(progn
(repeat i
(setq ent (entget (ssname ss (setq i (1- i)))))
(setq data (cons
(list (cdr (Assoc 10 ent))
(cdr (Assoc 1 ent))) data))
)
(mapcar '(lambda (c d)
(setpropertyvalue
(if (member c '("LOC-2" "CH-2"))
s1 s2) c d) d )
'("ch-1" "loc-1" "CH-2" "LOC-2" "ch-3" "loc-3" )
(mapcar 'cadr
(vl-sort data '(lambda (a b)
(< (caar a)(caar b)))))
)
(Foreach itm '("TENSION_LENGTH1" "TENSION_LENGTH2"
"MAST_COUNT1" "MAST_COUNT2"
)
(setpropertyvalue s1 itm (getpropertyvalue s itm))
)
)
)
(princ)
)
HTH
P.S. You can select the TEXT ivia window selection, does not need to be in any order as long as it lined up the way you had on your sample [ three sets ]
@jaggisingh003 wrote:
@pbejse thanks for your help.
Sry for that there was some mistake in that picture.
...
how to write this without Active-X. Can you show that?
You are welcome @jaggisingh003 , no worries but check the information you provide to avoid confusion next time.
Its not a big deal, we will just replace the inserting the blocks and the sorting bit. setup a couple settings to ensure the code will not break , i.e attdia, attreq, the block scale [ uniformyl scaled ], etc... but no need to do that now. 🙂
Lets start with the easy one
(Foreach itm '("TENSION_LENGTH1"
"TENSION_LENGTH2"
"MAST_COUNT1"
"MAST_COUNT2"
)
(setpropertyvalue s1 itm (getpropertyvalue s itm))
)
The reason we did that so you dont have to make 8 separate statement.
(setQ TL1 (getpropertyvalue (car s) "TENSION_LENGTH1"))
(setQ TL2 (getpropertyvalue (car s) "TENSION_LENGTH2"))
(setQ MC1 (getpropertyvalue (car s) "MAST_COUNT1"))
(setQ MC2 (getpropertyvalue (car s) "MAST_COUNT2"))
(setpropertyvalue s1 "TENSION_LENGTH1" TL1)
(setpropertyvalue s1 "TENSION_LENGTH2" TL2)
(setpropertyvalue s1 "MAST_COUNT1" MC1)
(setpropertyvalue s1 "MAST_COUNT2" MC2)
You also dont need to assign the value to a variable from getpropertyvalue function. and afterwards passing the value to the setpropertyvalue as argument
(setpropertyvalue s1 itm (getpropertyvalue s itm))
But what about the tag names?
By using foreach function, you will be using a temporary variable we named as itm for every actual name on the given list.
("TENSION_LENGTH1" "TENSION_LENGTH2" "MAST_COUNT1" "MAST_COUNT2" )
on the first run itm = "TENSION_LENGTH1"
What is the common thing between this two?
(setQ TL1 (getpropertyvalue (car s) "TENSION_LENGTH1"))
(setpropertyvalue s1 "TENSION_LENGTH1" TL1)
Yes. "TENSION_LENGTH1", so translating that two statement above into
(setpropertyvalue s1 itm (getpropertyvalue s itm))
since itm = "TENSION_LENGTH1"
(setpropertyvalue s1 "TENSION_LENGTH1" (getpropertyvalue s "TENSION_LENGTH1"))
the next run will do the same but with the next item on the list --> "TENSION_LENGTH2" and so on...
thus eliminating the need to a fixed named variable for every TAG name.
HTH
