numeric Increment along with multileader
@ishaq03 wrote:
Please Provide me lisp where I can control numeric Increment in Prefix Middle Suffix along with multi leader. For your reference I am attaching the Image file.
The image you posted doesnt tell us much @ishaq03
You mean user is prompt for all three?
Enter prefix:
Enter Middle:
Enter Suffix:
I assume those string values are separated by "-" and suffix is the only one that increments?
Will the user be selecting an existing Mleader and changing the value or create new Mleader for every increment?
Post a sample drawing please.
@ishaq03 wrote:
I assume those string values are separated by "-" and suffix is the only one that increments. Yes I need the Increment in suffix only. and i want to be create new multileader for increment.
We need to know if it works on an actual drawing @ishaq03 , the multileader style? the scale? etc..
Again, please post a sample drawing
@ishaq03 wrote:
I attached the sample dwg as you requested.
Thanks, that's good.
You have "TP-RD-Z2-004" as a value,
- Enter Prefix string value: TP
- Enter Middle string value: RD
- Enter Suffix string value: Z2
Enter Start number: 1 ( and always 3 digits? i.e. 00, 012, 102? )
Then user starts clicking away placing the Mleader
If "TP-RD-Z2" will be the same during increment, why not just
- Enter string: TP-RD-Z2
- Enter Start number: 1
Here's a simple code
(defun c:IncAt ( / _padzeros Prefix startNos p1 p2)
(defun _padzeros ( s l)
(if (< (strlen s) l) (_padzeros (strcat "0" s) l) s))
(if
(and
(setq Prefix (getstring "\nEnter Prefix string value: " ))
(setq startNos (getint "\nEnter Start number: "))
)
(while (and
(setq p1 (getpoint "\nPick target point"))
(setq p2 (getpoint p1 "\nText Location"))
)
(command "_Mleader" "_non" (trans p1 1 0) "_non" (trans p2 1 0) "")
(vla-put-textstring (vlax-ename->vla-object (entlast))
(strcat Prefix "-" (_padzeros (itoa startNos) 3)))
(setq startNos (1+ startNos)))
)
(princ)
)
Command: Incat
Let me know how it goes.
@Jafarali wrote:
how to use this lisp i need the same
I am new in lisp tools, can you help me
loded lisp tool and what is the commend for this list to active
- Copy the code at post # 15
- Save the file as INCAT.lsp
- Load the file using Appload.
Command: INCAT
Enter Prefix string value: BANANA
Enter Start number: 456
Pick target point
Text Location
Of course it depends on the current multileader style.
@k.rakha wrote:
@pbejse It worked perfectly, but can be edited to include the text inside a circle block?
(defun c:IncAt ( / _padzeros Prefix startNos p1 p2 ml attblock firstAtt BlockIDcoll)
(defun _padzeros ( s l)
(if (< (strlen s) l) (_padzeros (strcat "0" s) l) s))
(if
(and
(setq Prefix (getstring "\nEnter Prefix string value: " ))
(setq startNos (getint "\nEnter Start number: "))
)
(while (and
(setq p1 (getpoint "\nPick target point"))
(setq p2 (getpoint p1 "\nText Location"))
)
(command "_Mleader" "_non" (trans p1 1 0) "_non" (trans p2 1 0) "")
(setq ml (vlax-ename->vla-object (entlast)))
(setq nstr (strcat Prefix "-" (_padzeros (itoa startNos) 3)))
(cond
((snvalid (setq attblock (vla-get-ContentBlockName ml)))
(setq mblk (vla-item (vla-get-blocks (vla-get-ActiveDocument (vlax-get-acad-object))) attblock))
(or firstAtt
(progn
(vlax-for itm mblk (setq BlockIDcoll (cons itm BlockIDcoll)))
(vl-some '(lambda (o)(and (eq (vla-get-ObjectName o) "AcDbAttributeDefinition")
(setq firstAtt (vla-get-ObjectID o))))
BlockIDcoll )
)
)
(vla-SetBlockAttributeValue ml firstAtt nstr)
)
((vla-put-textstring ml nstr))
)
(setq startNos (1+ startNos)))
)
(princ)
)
