Mirror and Copy

[jorgearone_inssitu]

hello everyone
I wanted to know if this type of work is possible using dynamic blocks or some lisp
I have some blocks aligned in a line (a-b)

and what I would like is for it to be reflected in the line (c-d)

selecting the straight line as axis (c-d)

What I commonly do is make a mirror, but I have to first select the midpoint between those two lines, then draw my axis so that it comes out aligned, another thing is that the text comes out backwards.

[Kent1Cooper]

---

@jorgearone_inssitu wrote:

.... the text comes out backwards.

---

For that, read about the MIRRTEXT System Variable, but even that won't do it if they're plain Text in ordinary Blocks.

[jorgearone_inssitu]

I know about MIRRTEXT, 

I would like is for it to be reflected 

selecting the straight line as axis (c-d)

[komondormrex · Accepted solution]

hey there,

you can force the text to mirror regardless of mirrtext variable if you fix it inside the block with fix geometric constraint.

[dbroad]

;;;marko_ribar
(DEFUN average	(lst)
  (MAPCAR '(LAMBDA (x) (/ x (LENGTH lst)))
	  (APPLY 'MAPCAR (CONS '+ lst)))
  )

(DEFUN cdrs  (key lst / pr)
  (IF
    (SETQ pr (ASSOC key lst))
     (CONS (CDR pr)
	   (cdrs key (CDR (MEMBER pr lst))))))


(DEFUN c:mirrormid  (/ bl nl p1 p2 ss ss2)

  (IF
    (AND
      (PRINC "\nSelect object to mirror.")
      (SETQ ss (SSGET))
      (PRINC "\nSelect both baselines.")
      (SETQ ss2 (SSGET '((0 . "line"))))
      (>= (SSLENGTH ss2) 2)
      (SETQ bl (ENTGET (SSNAME ss2 0));baseline
	    nl (ENTGET (SSNAME ss2 1));new line
	    p1 (average (cdrs 10 (APPEND bl nl)));mid p1
	    p2 (average (cdrs 11 (APPEND bl nl)));mid p2

	    ))
            (COMMAND "_.mirror" ss "" p1 p2 "_n"));mirror without delete
            )
  (PRINC)
  )

[Kent1Cooper · Accepted solution]

---

@jorgearone_inssitu wrote:

....

What I commonly do is make a mirror, but I have to first select the midpoint between those two lines, then draw my axis ....

---

Since c-d is not the axis you want to mirror across, yes, you need an axis halfway between the two Lines.  But there's certainly no need to draw the axis!  And no routine is needed.  In MIRROR, select the stuff, then for the ends of the mirror line, use middle-of-two-points Object Snap [M2P or MTP typed abbreviation, or the "Mid Between 2 Points" item in the shift+right-click list] to get the halfway points between a & c and between b & d.  Either that, or something like @dbroad 's routine, which requires you to select both Lines anyway, because c-d alone isn't enough to tell the story.

[Kent1Cooper]

---

@dbroad wrote:

....
            (COMMAND "_.mirror" ss "" p1 p2 "_n"));mirror without delete
....

---

[That has an extra right parenthesis at the end.]

I would also point out that if a-b and c-d are nicely lined up and parallel as appears in the images, but happen to have been drawn in opposite directions, then p1 and p2 will be the same, causing an error.

[dbroad · Accepted solution]

Good points.  Try this out. Might be a simpler way

;;;marko_ribar
(DEFUN average	(lst)
  (MAPCAR '(LAMBDA (x) (/ x (LENGTH lst)))
	  (APPLY 'MAPCAR (CONS '+ lst)))
  )

(DEFUN c:mirrormid  (/ bl bp1 bp2 ip nl np1 np2 p1 p2 ss ss2)
  (IF
    (AND
      (PRINC "\nSelect object to mirror.")
      (SETQ ss (SSGET))
      (PRINC "\nSelect both baselines.")
      (SETQ ss2 (SSGET '((0 . "line"))))
      (>= (SSLENGTH ss2) 2)
      (SETQ bl	(ENTGET (SSNAME ss2 0))			    ;baseline
	    bp1	(CDR (ASSOC 10 bl))
	    bp2	(CDR (ASSOC 11 bl))
	    nl	(ENTGET (SSNAME ss2 1))			    ;new line
	    np1	(CDR (ASSOC 10 nl))
	    np2	(CDR (ASSOC 11 nl)))
      (IF (SETQ ip (INTERS bp1 bp2 np1 np2 nil))
	(PROGN
	  (SETQ	p1 (IF (< (DISTANCE ip bp1) (DISTANCE ip bp2))
		     bp2
		     bp1))
	  (SETQ	p2 (IF (< (DISTANCE ip np1) (DISTANCE ip np2))
		     np2
		     np1))
	  (SETQ p2 (average (LIST p1 p2)))
	  (SETQ p1 ip)
	  )
	(IF (< (DISTANCE bp1 np1) (DISTANCE bp1 np2))
	  (SETQ
	    p1 (average (LIST bp1 np1))			    ;mid p1
	    p2 (average (LIST bp2 np2))			    ;mid p2
	    )
	  (SETQ
	    p1 (average (LIST bp1 np2))
	    p2 (average (LIST bp2 np1))
	    ))
	))

     (COMMAND "_.mirror" ss "" "_non" p1 "_non" p2 "_n")    ;mirror without delete

     )
  (PRINC)
  )

 M 

[jorgearone_inssitu]

Thank you very much for the lisp, one last question, what if it were a polyline? It only works with lines.

[komondormrex · Accepted solution]

hey there,

check the code below. given the lines a-b and c-d are parallel, select source blocks, source mirror axis, target mirror axis...

(defun c:mirror_copy (/ source_list source_mirr_data source_point source_mirr_point target_mirr_ename target_point source_mirror)
	(setq source_list (mapcar 'vlax-ename->vla-object (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget '((0 . "insert")))))))
		  source_mirr_data (entsel "\nPick source mirror axis: ")
		  source_point (vlax-curve-getclosestpointto (setq source_mirr_ename (car source_mirr_data)) (cadr source_mirr_data))
		  source_mirr_point (polar source_point (angle '(0 0) (vlax-curve-getfirstderiv source_mirr_ename (vlax-curve-getparamatpoint source_mirr_ename source_point))) 1)  
		  target_mirr_ename (car (entsel "\nPick target mirror axis: "))
		  target_point (vlax-curve-getclosestpointto target_mirr_ename source_point) 
	)
	(foreach source source_list 
		(setq source_mirror (vla-mirror source (vlax-3d-point source_point) (vlax-3d-point source_mirr_point)))
		(vla-move source_mirror (vlax-3d-point source_point) (vlax-3d-point target_point))
	)
	(princ)
)

[jorgearone_inssitu]

Thank you very much, it works perfectly.

[jorgearone_inssitu]

Thank you very much, it works perfectly.