LISP to quickly number multiple polylines
@ramirez.m.1989 wrote:
I need to quickly number polylines....
As a starting point
(defun c:LMB ( / sel e sum verts ptList p_)
;; Label Me Buddy ;;
;; pBe Feb 2018 ;;
;;--------------------------------------;;
;; Kent Cooper sum|verts ;;
;;--------------------------------------;;
(setq inc (cond
((getint (strcat "\nEnter number"
(if inc
(strcat " <" (itoa inc) ">: ")
": ")
)))
(inc))
)
(while (and (princ (strcat "\nLabel Number " (itoa inc)))
(setq sel (ssget "_+.:S:E" '((0 . "LWPOLYLINE"))))
)
(setq e (ssname sel 0)
sum '(0 0)
verts (cdr (assoc 90 (setq ent (entget e)))))
(setq ptList
(mapcar 'cdr
(vl-remove-if-not
'(lambda (x) (= (car x) 10)) ent)))
(foreach x ptList (setq sum (mapcar '+ x sum)))
(setq p_ (mapcar '/ sum (list verts verts)))
(entmakex
(list
(cons 0 "TEXT")
(cons 10 p_)
(cons 11 p_)
(cons 8 (cdr (assoc 8 ent)))
'(40 . 0.18)
'(72 . 4)
'(73 . 3)
(cons 1 (itoa inc))
)
)
(entmakex
(list (cons 0 "CIRCLE")
(cons 10 p_)
(assoc 8 ent)
(cons 40 0.28)
)
)
(setq inc (1+ inc)))
(princ)
)
@ramirez.m.1989 wrote:
...would only be necessary to include the multiple selection and it would be perfect.
Sure...
(defun c:LMBS(/ sel e sum verts ptList p_)
;; Label Me Buddy ;;
;; pBe Feb 2018 ;;
;;--------------------------------------;;
;; Kent Cooper sum|verts ;;
;;--------------------------------------;;
(setq inc (cond
((getint (strcat "\nEnter number"
(if inc
(strcat " <"
(itoa inc)
">: ")
": ")
)))
(inc))
)
(if
(setq ss (ssget '((0 . "LWPOLYLINE"))))
(repeat (sslength ss)
(setq e (ssname ss 0)
sum '(0 0)
verts (cdr (assoc 90 (setq ent (entget e)))))
(setq ptList
(mapcar 'cdr
(vl-remove-if-not
'(lambda (x) (= (car x) 10))
ent)))
(foreach x ptList (setq sum (mapcar '+ x sum)))
(setq p_ (mapcar '/ sum (list verts verts)))
(entmakex
(list
(cons 0 "TEXT")
(cons 10 p_)
(cons 11 p_)
(cons 8 (cdr (assoc 8 ent)))
'(40 . 0.18)
'(72 . 4)
'(73 . 3)
(cons 1 (itoa inc))
)
)
(entmakex
(list (cons 0 "CIRCLE")
(cons 10 p_)
(assoc 8 ent)
(cons 40 0.28)
)
)
(setq inc (1+ inc))
(ssdel e ss)
)
)
(princ)
)
I make the selection with an area and the numbers come out disordered.
Is there any way to make the selection with an area and that the numbers come out in order?
I do not know how to quickly enumerate a lot of polylines. Selecting each polyline is a bit slow.
@ramirez.m.1989 wrote:
The numbers keep coming out of order.
Selecting by Fence will and should give the correct order.
@ramirez.m.1989 wrote:
Doing several tests I realized that it numbers according to the order in which the polyline was drawn.
Yes, it will do that.
What we need is a mean sorting algorithm. depending on the direction. Left to right , Top to bottom .... but then again, you need to select bygroup, so its basically the same as using Fence selection
EDIT: Now you got me curious, How exactly were the polylines generated?
@ramirez.m.1989 wrote:
In some cases they are more than 1000 polylines so it is not very fast to
select one by one.
Listen ramirez.m.1989, before we started, you were happy with typing in the description per object. I suggested layers so you dont even need to typed in anything. Now, we have a routine to number the polylines via selection. At first using a loop and then modified using Fence, I'm pretty sure beats placing the TEXT on the objects center(ish), typing the string number then creating the circle one after the other.
I'm open for suggestions.
@ramirez.m.1989 wrote:
I'm grateful for your help. With the routines that you have created, I will
save a lot of time.
We are happy to help. 
@ramirez.m.1989 wrote:
I just wanted to know if there was any way to perfect them.
Not sure about "perfect" but maybe a better way. So answer me this.
..That is why i'm asking how were the polylines generated? maybe, just maybe we can deal with the numeric order on or before the objects are created...
...EDIT: Now you got me curious, How exactly were the polylines generated? ..
