length of a scroll arc using AutoLisp

[mike2334]

I have drawn the top of a impeller scroll for a cyclone using AutoLisp.  Now using AutoLisp I have to find the length of this scroll so I can make the side.   How can I get this length, I have use pedit to make it all one line but with entget I can't find the length?  Is there a way to use list in Autolisp and pull out the length?

Thanks Mike

[Anonymous]

post this in the Lisp Forum for better help. You should do a search first there in case there is something already written.

[dlanorh]

If you are using a full windows version of AutoCAD, try this

(vl-load-com)
;My Scroll Length
(defun c:msl ( / ent elst typ len)

  (setq elst (entget (setq ent (car (entsel "\nSelect Line Entity : "))))
        typ (cdr (assoc 0 elst))
  );end_setq

  (cond ( (or (wcmatch typ "*POLYLINE")
              (vl-position typ (list "ARC" "CIRCLE" "ELLIPSE" "LINE" "SPLINE"))
          )
          (setq len (vlax-curve-getdistatparam ent (vlax-curve-getendparam ent)))
          (alert (strcat "Length : " (rtos len (getvar 'lunits) (getvar 'luprec))))
        )
        (t (alert "NOT a Line Entity or Infinite Length Entity"))
  );end_cond

  (princ)
);end_defun