Layer rename assistance
Would you want to give it the change each time, or are you looking for something like a command to add specifically "NEWW-" always after the second character of the name of the Layer of a selected object? [You could have separate commands to different infixes.]
Also, suppose you select an object on a Layer that already has that added? Should there be "protection" against renaming Layer "A-NEWW-ELEC-POWR" to become "A-NEWW-NEWW-ELEC-POWR"?
In simplest terms, this will do the former:
(command "_.rename" "_layer" (setq oldname (cdr (assoc 8 (entget (car (entsel)))))) (lisped oldname))
It brings up a text editor with the current Layer name already filled in, and you can add whatever you want wherever you want, take part away, replace the whole thing, or edit it in any other way you like, and when you hit Enter, the Layer name will be changed.
And this will do the latter:
(command "_.rename" "_layer"
(setq oldname (cdr (assoc 8 (entget (car (entsel))))))
(strcat (substr oldname 1 2) "NEWW-" (substr oldname 3))
)
@DC-MWA wrote:
.... i will most likely add kword options to add NEWW, EXST, FUTR, DEMO options
And yes, the "protection" seems like a great idea.
A quickie, minimally tested:
(defun C:LNIF ; = Layer Name InFix
(/ infix esel layold)
(initget "Neww Exst Futr Demo")
(setq infix (getkword "\nLayer name infix [Neww/Exst/Futr/Demo]: "))
(while (setq esel (entsel "\nObject on Layer to have Infix added: "))
(setq layold (cdr (assoc 8 (entget (car esel)))))
(if (/= (strcase (substr layold 3 4)) (strcase infix))
(command "_.rename" "_layer" layold
(strcat (substr layold 1 2) (strcase infix) "-" (substr layold 3))
); command
); if
); while
(princ)
); defun
It could be enhanced to remember which infix you last chose and offer it as default on subsequent use, report on Layers it didn't rename because they already had the infix, check for any of those infixes in the current name rather than just the selected one, as well as all the usual stuff [*error* handler, Undo begin/end wrapping, etc.].
I put the options with only initial capitals because if you show them in all capitals, you would need to type all four letters of the one you want [though there would be the option to pick it in the prompt], whereas here you can type only the first letter. It gets all-capitalized in application.
@DC-MWA wrote:
Heck yea!!!
Sounds like it worked.... I edited the Message a few times, probably overlapping your reply, including fixing one thing in the code [about the already-infixed check], so make sure you use the latest.
@DC-MWA wrote:
I dont seem to have the infix check??
It's this:
(if (/= (strcase (substr layold 3 4)) (strcase infix))If the 3rd through 7th characters of the current Layer name are different from the chosen infix [not case-sensitive], it will rename the Layer by adding that. If they're the same, it won't, so you don't double up on that infix. But as currently written, if [for example] they are "EXST" and you chose "DEMO", it will add "DEMO-" into the Layer name, for a different kind of doubling up -- that's why I mentioned that it could be made to check for any of those infixes already present, not just the chosen one. I suppose it could be made to check for those, and if present, replace that part with your chosen one, instead of bypassing the Layer of that chosen object.
Your choices add more as required.
(if (not AH:Butts)(load "Multi Radio buttons.lsp"))
(if (= but nil)(setq but 1))
(setq ans(ah:butts but "V" '("Choose a new string" "NEWW" "EXST" "FUTR" "DEMO"))) ; ans holds the button picked
