Insert a block at the intersection of two lines which come from 4 points

[Bin2009]

I have a lot of work for insert a block at the intersection of two lines which come from 4 points. The points coordinates are from a excel table as below first image.

Is any lisp can help with the 3 steps to get final result as below second image:

1. Draw four lines for the boundary,

2. Draw 2 diagonal lines,

3. Insert a block in the intersection of the 2 diagonal lines.

How can I find it easily? Can I do it with a single command?  

Thank very much in advance!

[Kent1Cooper]

Look into the (inters) AutoLisp function.  That intersection point can be found with:

(inters point1 poin3 poin2 point4)

The diagonal Lines are not needed to find it, if that was the only reason for having them.

[Bin2009]

Hello Kent,

Thank very much for the inters Autolisp function, I actually not good at write Aitolisp, need figure out how to do it,

Best regards

Bin

[Sea-Haven]

The inters is a good function to use here, you can also get the midpoint of two points, as your providing 4 points.

(setq mp (mapcar '* (mapcar '+ pt1 pt3) '(0.5 0.5)))

Just a side question how are you getting the information from Excel ? There are ways to read an Excel, use a csv or read it directly from CAD.

[Bin2009]

Thanks Sea-Haven for the reply.

My idea lisp is can read the 4 points from excel, then draw the 4 outline and 2 diagonal line, and put the block at the intersection points.

In the excel have about 20 sets of 4-points for each kind of block, and I have 8 different blocks, that means I need repeat the same steps over 100 times, that's why I need a lisp.

Thanks

Bin

[Kent1Cooper]

---

@Bin2009 wrote:

.... lisp is can read the 4 points from excel, then draw the 4 outline and 2 diagonal line, and put the block at the intersection points.....

---

In your image, I assume the last entry in each line is the Block name.  Are the first three numbers X, Y & Z coordinates for a Block, or perhaps is the first [having no decimals like the others] some kind of reference, and the second and third numbers X & Y coordinates?  If the latter, is the reference to be bypassed, or is it needed somehow for Block insertion?  Are lines like that the only contents of the file?  Is it a .CSV file type [easy for AutoLisp to read]?

[Sea-Haven]

Post a Excel and a matching dwg, if its every 4 rows then reading Excel should be easy. Need your dwg for the blocks.

Looking at image looks like 1st row would be header information.

[Bin2009]

Thank you for response, please see attached cad file and excel.

[Bin2009]

Hello Kent, 

Thank you very much for your response. Yes the first 3 column are X,Y,Z, they all have decimal, only because the cell width is too short so the decimal didn't show up. the excel is csv file, I already attached it in the below response to Sea-Haven, the last column is the set number for the block, point 1-4 is for cabinet1, point 5-8 is for cabinet 2...., I also attached the final cad file our boss want to see. Thank you so much!

[Kent1Cooper]

That seems clear enough, except for one thing:  the yellow Text whose value is "0.000" at all locations.  Is that a constant [and if so, maybe expendable]?  Is it the Z coordinate [that would agree with the .csv file]?  Does the labeling not include anything about X & Y?  If not, why Z [if that's what it is]?

[Kent1Cooper · Accepted solution]

---

@Kent1Cooper wrote:

.... except for one thing:  the yellow Text whose value is "0.000" at all locations.  Is that a constant...?  ....

---

Well, assuming it is a constant, the attached TEST.lsp seems to do it, though the Block at the same scale factor as your sample shows up smaller.  The content of the one Text object can be corrected if it's not always supposed to be that.  [If it's the Z coordinate, then the code would need to deal with the DIMZIN System Variable to ensure the 3 trailing decimal zeroes show up.]

See the <-- EDIT line to put in your real file path and name.  It could be made to ask you to get the file, rather than have that built in.

[I do wonder about the color override on the Lines.  Could you just assign the right color to the Layer they're on, and leave them as BYLAYER in color?  Whether the Layer3 Text objects should be BYLAYER in color and on different Layers is perhaps an iffier question -- I can see having them on the same Layer, but why the different colors?]

[komondormrex · Accepted solution]

@Bin2009 

and yet another one

(defun c:cabinets (/ text_height h_factor line_spacing_factor cabinet_point csv_id string cabinet_point cabinet_name cabinet_list cabinet_points line_drawn ins_point insert )
  (defun get_point (sub_cabinet) (list (cadr sub_cabinet) (caddr sub_cabinet)))
  (defun put_text (sub_cabinet text_height h_factor line_spacing_factor / text zero_point)
    (mapcar '(lambda (text_string text_point layer color) (setq text (vla-addtext (vla-get-block (vla-get-activelayout (vla-get-activedocument (vlax-get-acad-object))))
								       text_string (vlax-3d-point text_point) text_height
								       )
								)
	       						(vla-put-alignment text 9)
	       						(vla-put-textalignmentpoint text (vlax-3d-point text_point)) 
	       						(entmod (append (entget (vlax-vla-object->ename text)) (list (cons 8 layer) (cons 62 color))))
	       )
	    	(list "0.000" (itoa (car sub_cabinet)) (vl-symbol-name (last sub_cabinet)))
	    	(list (setq zero_point (list (+ (* text_height h_factor) (cadr sub_cabinet)) (caddr sub_cabinet)))
		      (list (car zero_point) (+ (cadr zero_point) (* text_height line_spacing_factor)))
		      (list (car zero_point) (- (cadr zero_point) (* text_height line_spacing_factor)))
		)
	    	(list "Layer3" "Layer3" "Layer3")
	    	(list 2 1 3)
	)
  )
  (setq text_height 0.025
	h_factor 1.25
	line_spacing_factor 1.5
	csv_id (open "YOUR_DRIVE:\\YOUR_DIRECTORY\\Point_BlockSample.csv" "r")
  )
  (while (setq string (read-line csv_id))
    (setq cabinet_point (read (strcat "(" (vl-string-translate "," " " string) ")")))
    (cond
      ((or (null cabinet_name) (= cabinet_name (last cabinet_point))) (setq cabinet_points (append cabinet_points (list cabinet_point))))
      (t (setq cabinet_list (append cabinet_list (list cabinet_points)) cabinet_points (list cabinet_point)))
    )
    (setq cabinet_name (last cabinet_point)) 
  )
  (setq cabinet_list (append cabinet_list (list cabinet_points)))
  (close csv_id)
  (foreach cabinet cabinet_list
    (mapcar '(lambda (line) (setq line_drawn (vla-addline (vla-get-block (vla-get-activelayout (vla-get-activedocument (vlax-get-acad-object))))
					 	(vlax-3d-point (car line)) (vlax-3d-point (cadr line))
					 	)
				  )
	       			(entmod (append (entget (vlax-vla-object->ename line_drawn)) '((8 . "Layer2") (62 . 1))))
	     )
	     (mapcar 'list (setq cabinet_points (mapcar 'get_point cabinet))
		     	   (append (cdr cabinet_points) (list (car cabinet_points)))
		)
	)
    (mapcar '(lambda (line) (setq line_drawn (vla-addline (vla-get-block (vla-get-activelayout (vla-get-activedocument (vlax-get-acad-object))))
					 	(vlax-3d-point (car line)) (vlax-3d-point (cadr line))
					       )
				  )
	       			(entmod (append (entget (vlax-vla-object->ename line_drawn)) '((8 . "Layer2") (62 . 1))))
	       )
	    (list (list (get_point (car cabinet)) (get_point (caddr cabinet))) (list (get_point (cadr cabinet)) (get_point (cadddr cabinet))))
	)
    (setvar 'cmdecho 0)
    (setq ins_point (inters (get_point (car cabinet)) (get_point (caddr cabinet)) (get_point (cadr cabinet)) (get_point (cadddr cabinet)))
    	  insert (vla-insertblock (vla-get-block (vla-get-activelayout (vla-get-activedocument (vlax-get-acad-object))))
		   (vlax-3d-point ins_point) "Cabinet" 1 1 1 0
		   )
	)
    (entmod (append (entget (vlax-vla-object->ename insert)) '((8 . "Layer1") (62 . 256))))
    (command "_objectscale" (vlax-vla-object->ename insert) "" "_add" "" "1:500" "")
    (command "_aiobjectscaleremove" (vlax-vla-object->ename insert) "")
    (setvar 'cmdecho 1)
    (mapcar '(lambda (sub_cabinet) (put_text sub_cabinet text_height h_factor line_spacing_factor)) cabinet) 
  )
  (princ)
)

[Sea-Haven · Accepted solution]

Give this a try, just open your Excel 1st, I tested on your csv file as Excel. This is version one just to make it work. I did make one change I made a block for the cabinet details. See dwg. I will make it closer to what you provided. There is some checks to work out block CABLABEL always goes outside of shape.

Please let me know if happy with progress and will do some more tidy ups.

; ; https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/insert-a-block-at-the-intersection-of-two-lines-which-come-from/td-p/13291071

; Read data from excel and make a pline and add blocks.
; BY AlanH FEB 2025

(defun c:mkcabs ( / cname colsmax label lst lst2 mp num oldsnap row rowsmax val x y)
(alert "Make sure you have correct Excel open\npress ESC if not ready and run again")

;;	Thanks to fixo			;;
(defun getcell2 (row column / )
  (setq cells (vlax-get-property  (vlax-get-property myxl "ActiveSheet") "Cells"))
  (setq cell (vlax-get (vlax-variant-value  (vlax-get-property cells "Item" row column)) 'value))
)

(defun LWPoly (plst cls)
  (entmakex (append (list (cons 0 "LWPOLYLINE")
  (cons 100 "AcDbEntity")
  (cons 100 "AcDbPolyline")
  (cons 90 (length plst))
  (cons 70 cls))
  (mapcar (function (lambda (p) (cons 10 p))) plst)))
)

(setq myxl1 (vlax-get-object "Excel.Application"))
(if (= myxl1 nil)
    (setq myxl (vlax-get-or-create-object "excel.Application"))
	(setq myxl myxl1)
)
(vla-put-visible myXL :vlax-true)
(vlax-put-property myxl 'ScreenUpdating :vlax-true)
(vlax-put-property myXL 'DisplayAlerts :vlax-true)

(setq colsmax (vlax-get (vlax-get (vlax-get-property (vlax-get-property  myxl "ActiveSheet") 'UsedRange) 'columns) 'count))
(setq rowsmax (vlax-get (vlax-get (vlax-get-property (vlax-get-property  myxl "ActiveSheet") 'UsedRange) 'rows) 'count))

(setq oldsnap (getvar 'osmode))
(setvar 'osmode 0)

(setq row 1)

(repeat (/ rowsmax 4)
  (setq lst ' () lst2 '())
  (repeat 4
    (setq num (rtos (getcell2 row 1) 2 0))
    (setq X (getcell2 row 2))
    (setq y (getcell2 row 3))
    (setq label (getcell2 row 4))
    (setq cname (getcell2 row 5))
    (setq lst (cons (list num label cname) lst))
    (setq lst2 (cons (list x y) lst2))
    (setq row (1+ row))
  )
  (lwpoly lst2 1)
  (command "LINE" (nth 0 lst2) (nth 2 lst2) "")
  (command "LINE" (nth 1 lst2) (nth 3 lst2) "")
  (setq mp (inters (nth 0 lst2) (nth 2 lst2)(nth 1 lst2) (nth 3 lst2)))
  (command "-insert" "Cabinet" "s" 1.0 mp 0.0)
  (setq k 0)
  (foreach pt lst2
   (setq val (nth k lst))
   (command "-insert" "CABLABEL" pt 1 1 0.0 (car val) (cadr val) (caddr val))
   (setq k (1+ k))
  )
)

(setvar 'osmode oldsnap)

(if (not (vlax-object-released-p myXL))(progn(vlax-release-object myXL)(setq myXL nil)))

(princ)
)
(c:mkcabs)

[Bin2009]

Thank so much  Kent,

Your lisp give me exactly what I need, that's great!!

About the color, I can explain here: the final final drawing we keep in file will only the blocks. However, when our check review our drawing, she want to see the point information, (those text in different color) and those construction lines (four lines around and two diagonal lines) to make sure no any mistake, so red, yellow, green color will be standout and easy for checker to see it, because my real working drawing is basemap drawing which contains over hundred layers and huge number of objects, and all layer color is 8. After our checker reviewed the drawing, she will delete all the text and turn off the red color construction lines.

I think if use your lisp, every point, lines, blocks will be on the accurate location without mistake form manually input, I will talk with my check see if she think still need check using the text and construction lines.

Thanks a lot again for your help! I really want to learn how to make the lisp by myself.

Bin

[Bin2009]

Hello komondormrex,

Thank so much  for your lisp, it also work perfect!

Highly appreciate for your help!

Bin

[Bin2009]

Hello Sea-Haven,

Thank so much for your lisp, it also works perfect for me!

Highly appreciate for all your help!

Bin