How to prevent if a system variable does not exist, Activex

[carlos_m_gil_p]

Hello boys how are you.
With the changes of versions of autocad, they are eliminating system variables.
How do I avoid the error, if a variable does not exist, with activex functions.

I tried as follows, but it didn't work.

(vl-catch-all-error-p 
  (setq v (vlax-variant-value (vla-GetVariable (vla-get-activedocument (vlax-get-acad-object)) "casa"))))

 Thanks.

[_gile · Accepted solution]

Hi,

Try this way:

(vl-catch-all-error-p
  (vl-catch-all-apply
    '(lambda ()
       (setq v (vlax-variant-value
		 (vla-GetVariable (vla-get-activedocument (vlax-get-acad-object)) "casa")
	       )
       )
     )
  )
)

Why not simply use the getvar function?

(vl-catch-all-error-p
  (vl-catch-all-apply
    '(lambda () (setq v (getvar "casa")))
  )
)

[carlos_m_gil_p]

Hi @_gile , thank you for your answer.
I always apply it with getvar.
The point is that I wanted to learn how to do it with vl ...
Thank you.
Greetings.

[john.uhden]

Often times the vl way is the long way.

Another thing I was reminded of last week...

The vla-item method errors out if the named item doesn't exist.  You would think it would return nil, but it doesn't.  So if you are looking for the existence of a table entry, use the old tblsearch function instead.

[Sea-Haven]

Why not

(if (setq v (getvar 'casa))
(progn do something now

[carlos_m_gil_p]

Hi @john.uhden , how are you?

I understand that the vl are more powerful.

Yes, it is a longer way, but I think it can be solved by creating a general function for each case.

I am starting to use VSCode and with one click I can insert these functions.
I improve my code and my workflow.

All this based on my opinion and in the same way learn more about the vl functions.

Thanks for the information about the vla-item method, I will keep it in mind for future use.

Greetings.

Hi @Sea-Haven 

I am not saying that it is wrong or that I do not use them that way, as I mentioned above, it is a matter of learning more about these functions.

Thanks.

[_gile]

---

@john.uhden  a écrit :

The vla-item method errors out if the named item doesn't exist.  You would think it would return nil, but it doesn't.  So if you are looking for the existence of a table entry, use the old tblsearch function instead.

---

;; gc:GetItem (gile)
;; Returns the vla-object of item if it exists in the collection (or nil)
;;
;; Arguments
;; col : collection (vla-object)
;; name : object name (string) or index (integer)

(defun gc:GetItem (col name / obj)
  (vl-catch-all-apply
    (function (lambda () (setq obj (vla-Item col name))))
  )
  obj
)

[Sea-Haven]

Have a look at attached

[carlos_m_gil_p]

Hello @Sea-Haven , thank you very much for your information and help.
Greetings.