HOW TO FREEZE ALL LAYER EXCEPT PICKED IN VPORT?

[PRULS5370]

anyone have the lisp for it? can i see it? please

[3wood]

You can try LAYER.vlx.

VPfreeze all layers first in a viewport, then use command LPO to pick up the layer you need to show in the viewport.

[PRULS5370]

thank u 🙂

[Kent1Cooper · Accepted solution]

If you mean a single Layer of a picked object, this works in limited testing:

(defun C:VPFAES (/ esel); = ViewPort Freeze All layers Except that of Selected object
  (if (setq esel (entsel "\nSelect object on only Layer to be thawed in current Viewport: "))
    (command "_.vplayer"
      "_freeze" "*" "_current"
      "_thaw" (cdr (assoc 8 (entget (car esel)))) "_current"
      ""
    ); command
  ); if
  (princ)
); defun

If you want to select multiple objects to designate Layers to remain thawed, that can also be done:

(defun C:VPFAES (/ esel laystr); = ViewPort Freeze All layers Except those of Selected objects
  (while (setq esel (entsel "\nSelect object(s) on Layer(s) to be thawed in current Viewport: "))
    (setq laystr (strcat (cond (laystr) ("")) (cdr (assoc 8 (entget (car esel)))) ","))
  ); while
  (if laystr
    (command "_.vplayer" "_freeze" "*" "_current" "_thaw" laystr "_current" "")
  ); if
  (princ)
); defun

[PRULS5370]

THANK U 🙂

[TomBeauford]

Why not just use https://help.autodesk.com/view/ACD/2022/ENU/?guid=GUID-E24B9866-9538-43BF-A3DF-AA7E2341C624

LAYISO (Command)

Hides or locks all layers except those of the selected objects.

[Kent1Cooper]

---

@TomBeauford wrote:

Why not just use LAYISO (Command)

Hides or locks all layers except those of the selected objects.

---

... if the Settings are correct for that, but the default Settings seem to be.  I was not aware that LAYISO has a per-Viewport-VPFreeze option now [I think it has not always had that], rather than just turning Off other Layers [which is still an optional Setting].