Help with FILEOPEN Command in AutoLISP
Autolisp is not really the right tool for your needs.
It is a single document application. Activating another document stops and autolsip program until the host document is activated again.
Using a script to cycle through the documents you need to run the (c:SVAM-Todos) and in the end return to the host document, It will probably be the best solution.
This post might give you some ideas
Hope this helps,
Henrique
@scottividal wrote:
Thank you for the suggestion, I've been researching scripts (with a bit of help from ChatGPT). And I understand a bit more, but I still can't solve my problem.
I understand that I should create a script that opens all the files in the folder and runs my Lisp routine on them. However, it's not clear to me if there's a way to automate the script to know the path of the folder. Also, I don't understand if I can include something like this code in the script.
; Script
(setq files (vl-directory-files "." "*.dwg" 1))
(foreach file files
(if (/= file "EjecutarVigas.scr")
(progn
(command "_OPEN" (strcat (getvar "dwgprefix") file))
(command "_beams")
(command "_SAVE" "_YES")
(command "_CLOSE" "_YES") ) ) )
@scottividal change "X:/Your/File/Path/FileName.lsp" to the correct file path and name an try it.
;; Old Version of 'BrowseForFolder' by: Tony Tanzillo
(defun BrowseForFolder (Message / sh folder parentfolder folderobject result)
(vl-load-com)
(setq sh (vla-getInterfaceObject (vlax-get-acad-object) "Shell.Application"))
(setq folder (vlax-invoke-method sh 'BrowseForFolder 0 Message 0))
(vlax-release-object sh)
(if folder
(progn
(setq parentfolder (vlax-get-property folder 'ParentFolder))
(setq FolderObject (vlax-invoke-method ParentFolder 'ParseName (vlax-get-property Folder 'Title)))
(setq result (vlax-get-property FolderObject 'Path))
(mapcar 'vlax-release-object
(list folder parentfolder folderobject)
)
(if (/= (substr result (strlen result)) "\\")
(setq result (strcat result "\\"))
result
)
)
)
)
(defun c:demo (/ DirPath DwgFile DwgList Ofile Scrfile)
(if (setq DirPath (BrowseForFolder "Select directory to process all drawings."))
(progn
(setq Scrfile (vl-filename-mktemp "test.scr"))
(setq Ofile (open Scrfile "w"))
(setq DwgList (vl-directory-files DirPath "*.dwg" 1))
(foreach Dwg DwgList
(setq DwgFile (strcat DirPath Dwg))
(write-line (strcat "_.open\r" (chr 34) DwgFile (chr 34) "\r") Ofile)
(write-line (strcat "(load " (chr 34) "X:/Your/File/Path/FileName.lsp" (chr 34) ")\r") Ofile)
(write-line "(c:SVAM-Todos)\r" Ofile)
(write-line "_.qsave\r" Ofile)
(write-line "_.close\r" Ofile)
)
(close Ofile)
(command "_.script" Scrfile)
)
)
(princ)
)
Hope this helps,
Henrique
@scottividal try this one
(defun c:demo (/ DirPath DwgFile DwgList Ofile Scrfile)
(if (setq DirPath (BrowseForFolder "Select directory to process all drawings."))
(progn (setq Scrfile (vl-filename-mktemp "test.scr"))
(setq Ofile (open Scrfile "w"))
(setq DwgList (vl-directory-files DirPath "*.dwg" 1))
;; Iterate over each drawing file
(foreach Dwg DwgList
(setq DwgFile (strcat DirPath Dwg))
;; Write AutoCAD commands to the script file
(write-line (strcat "_.open\r" (chr 34) DwgFile (chr 34) "\r") Ofile)
(write-line "(c:SVAM-Todos)\r" Ofile)
(write-line "_.deley\r500\r" Ofile) ; Add a delay of 500 milliseconds\r"
)
;; Close the script file and execute it
(close Ofile)
(princ (strcat "Processing: " DwgFile "\n"))
;; Execute the script
(command "_.script" Scrfile)
;|(if (= 0 (command "_.script" Scrfile))
(princ "Script executed successfully.\n")
(princ "Error executing the script.\n")
)|;
;; Close the script file after processing all drawings
;;;(close Ofile)
)
)
(princ)
)
(= 0 (command "_.script" Scrfile) a command call will always return nil, this test will always be false...
The script file will stop because (vl-cmdf 500) will send to the command line only 500 and the result will be *Cancel* and stop the script...
To add a deley we need to use the command deley.
Hope this helps,
Henrique
