Get Coordinates of Text Entity
Accepted solution
Here's the way I would go about it. I have a "pet peeve" about (ssget) always using the "Select objects: " prompt, always in the plural, so when I want to select a single object, I prefer to spell out my own prompt, which (entsel) lets me do. And I prefer to do the same with (getpoint), rather than use pauses after Osnap mode calls, because the pauses leave the User with a prompt that's just "of ".
Also, if you check whether the 11-code value in entity data is (0 0 0) to decide whether the Text is left-justified or not, there's the risk [however slight] that you'll pick a piece of Text that's not left-justified but that happens to have its origin at (0 0 0), in which case it will use the wrong base point for the Move displacement. This also will work in versions of AutoCAD old enough to not have the m2p Osnap mode.
(defun C:TM2P (/ txt tdata p1 p2); = Text to Midway between 2 Points
(if
(and
(setq txt (car (entsel "\nSelect Text to move to Midway between 2 Points: ")))
(= (cdr (assoc 0 (setq tdata (entget txt)))) "TEXT")
(setq p1 (getpoint "\nFirst of 2 Points: "))
(setq p2 (getpoint "\nSecond of 2 Points: "))
); and
(command "_.move" txt ""
"_none" (cdr (assoc (if (= (cdr (assoc 72 tdata)) (cdr (assoc 73 tdata)) 0) 10 11) tdata))
"_none" (mapcar '/ (mapcar '+ p1 p2) '(2 2 2))
); command
(prompt "\nNo Text selected, or 2 Points not picked.")
); if
(princ)
); defun
That longest line is testing whether the Text is left-justified by looking at whether both 72- and 73-code entity data values are 0, in which case it takes the 10-code value for its insertion point, or not [any other justification], in which case it takes the 11-code value. The following line is the equivalent of m2p Osnap.
Kent Cooper, AIA 
@ВeekeeCZ wrote:
....It depends on the workflow. I prefer noun/verb type of selection so much that when I get a lisp with entsel selection, rewriting to ssget is always first thing I do (if it's possible because of the pick-point). In this case I actually never see the prompt... ....
The one potential difficulty with that, as done in the test2 command, is that if there happens to be a pre-selection containing more than one Text object, it Moves all of them, using as the Move displacement base point the insertion point of one of them, but whichever happens to be first in the set, so you have no control over which one. I worked up something I thought would account for that [adapted from another routine], but it's not working quite right yet -- maybe later.
Kent Cooper, AIA
@Kent1Cooper wrote:
... if there happens to be a pre-selection containing more than one Text object, it Moves all of them.... I worked up something I thought would account for that [adapted from another routine], but it's not working quite right yet -- maybe later.
I got it working -- see attached TextToMidOf2.lsp with its TM2P command.
Kent Cooper, AIA