Extract a value from a Dynamic block using simple Autolisp code rather than Visual Lisp
@peter_thomson wrote:
Wondering if it is possible to extract a value from a dynamic block using just simple Autolisp functions.
Look here
HTH
@peter_thomson wrote:
Thank you, however, there is still some VL code in there.
You mean these two?
(mapcar 'cdr (vl-remove-if-not '(lambda (x) (= 303 (car x))) elst))(vl-remove-if-not
'(lambda (x) (= (car x) 360))
(entget enhancedBlock)
)
@peter_thomson wrote:
I will try and replace the VL-remove and the VL-remove-if-not code with simple autolisp. I guess it will be less efficient, but the benefit of being able to run the code in Core Console for plotting will be enormous.
I'm pretty sure you can @peter_thomson , go for it then.
Glad it helps
BTW: What about taking the .Net approach?
@peter_thomson wrote:
Not even sure that I am clever enough to re-write that other code but will have a go anyway.
Let me know if you hit a snag, we'll be here.
@peter_thomson wrote:
Thank you, however, there is still some VL code in there.
I will try and replace the VL-remove and the VL-remove-if-not code with simple autolisp. I guess it will be less efficient, but the benefit of being able to run the code in Core Console for plotting will be enormous.
Mant thanks,
Peter
Are you sure the vl-* functions are not supported by the Core Console? vl functions, unlike vla, vlax or vlr functions, are simple AutoLISP functions.
Anyway, you can use the following function:
(defun gc:massoc (code alst)
(if (setq alst (member (assoc code alst) alst))
(cons (cdar alst) (gc:massoc code (cdr alst)))
)
)
and replace:
(mapcar 'cdr (vl-remove-if-not '(lambda (x) (= 303 (car x))) elst))with
(gc:massoc 303 elst)
Assuming you want to get all the dynamic property values of a block reference, you can try the following:
(defun GetDynamicPropertyValues (blockReference / blockRecord xDictionary enhancedBlock elst param name lst)
(if (and
(setq blockRecord (getDynBlockRecord blockReference))
(setq xDictionary
(cdr
(assoc 360
(member '(102 . "{ACAD_XDICTIONARY") blockRecord)
)
)
)
(setq enhancedBlock
(cdr
(assoc 360
(member '(3 . "ACAD_ENHANCEDBLOCK") (entget xDictionary))
)
)
)
)
(foreach prop (gc:massoc 360 (entget enhancedBlock))
(setq elst (entget prop)
param (cdr (assoc 0 elst))
name (cond
((= param "BLOCKPOINTPARAMETER")
(cdr (assoc 303 elst))
)
((= param "BLOCKLINEARPARAMETER")
(cdr (assoc 305 elst))
)
((= param "BLOCKPOLARPARAMETER")
(cdr (assoc 305 elst))
)
((= param "BLOCKXYPARAMETER")
(cdr (assoc 305 elst))
)
((= param "BLOCKROTATIONPARAMETER")
(cdr (assoc 305 elst))
)
((= param "BLOCKFLIPPARAMETER")
(cdr (assoc 305 elst))
)
((= param "BLOCKVISIBILITYPARAMETER")
(cdr (assoc 301 elst))
)
((= param "BLOCKLOOKUPPARAMETER")
(cdr (assoc 303 elst))
)
((= param "BLOCKALIGNMENTPARAMETER")
(cdr (assoc 300 elst))
)
)
)
(if name
(setq lst (cons (cons name
(getpropertyvalue blockReference (strcat "AcDbDynBlockProperty" name))
)
lst
)
)
)
)
)
(reverse lst)
)
(defun getDynBlockRecord (blockRef / elst xDictionary blockRep repData blockRecord block)
(if (= (cdr (assoc 0 (setq elst (entget blockRef)))) "INSERT")
(if (and (setq xDictionary (cdr (assoc 360 (member '(102 . "{ACAD_XDICTIONARY") elst))))
(setq blockRep (cdr (assoc 360 (member '(3 . "AcDbBlockRepresentation") (entget xDictionary)))))
)
(setq repData (cdr (assoc 360 (member '(3 . "AcDbRepData") (entget blockRep))))
blockRecord (entget (cdr (assoc 340 (entget repData))))
)
(setq block (entget (tblobjname "block" (cdr (assoc 2 elst))))
blockRecord (entget (cdr (assoc 330 block)))
)
)
)
)
(defun gc:massoc (code alst)
(if (setq alst (member (assoc code alst) alst))
(cons (cdar alst) (gc:massoc code (cdr alst)))
)
)To get the value of a dynamic property you know the property name, simply use the getpropertyvalue function:
(getpropertyvalue blockReferenceEname (strcat "AcDbDynBlockProperty" name))