ERROR AND MTEXT

[etilley327KA]

I really could use some help. I keep getting an error somewhere in my math functions, but I dont see it. Also, my mtext isnt working either. Im trying to add text with the variables. 

(defun c:XC (/ tmn tdp mtof mtoc mdis slope mdn apron pt1)

            (setq tmn (getreal "\nEnter SLOPE tolerance: "))

            (setq tdp

              (cond

                (XSTRCASE(getreal "\nEnter standard drop or <Enter for 0.67>: "))

                (0.67)

              )

            )

            (setq mtof (getreal "\nEnter TOF: "))

            (setq mtoc (getreal "\nEnter TOC: "))

            (setq mdis (getreal "\nEnter Distance: "))

              (setq slope (rtos (* (/ (- mtof tdp mtoc) mdis) 100) 2 0))

              (setq mdn (- mtof (+ mtoc (* (/ tmn 100) mdis)) 0.375))

              (setq apron (- mtof (+ 0.375 mdn)))

                (if (< slope tmn)

                  (progn

                    (alert "Too High")

                    (command "mtext" (setq pt1 (getpoint "\nSelect Point: ") ) pt1 slope apron mtof mtoc mdis tdp "")

                  )

                    (command "mtext" (setq pt1 (getpoint "\nSelect Point: ") ) pt1 (strcat slope "%") "")

                )

  (princ)

)

[ВeekeeCZ]

Comparing "slope" being a string to "tmn" being a real...

[ВeekeeCZ]

slope apron mtof mtoc mdis tdp ... all have to be STRINGs and (strcat .... ) together into one string.

[ВeekeeCZ]

XSTRCASE is something undocumented that I don't know. What is it? That could be your issue - if that returns a string.

Edit: 

(xstrcase)

An international-friendly version of (strcase).

[etilley327KA]

Someone helped me with that, it looks to be something similar to strcase, but I can't see the difference. I guess ill just switch it to strcase.

[ВeekeeCZ]

---

@etilley327KA wrote:

Someone helped me with that, it looks to be something similar to strcase, but I can't see the difference. I guess ill just switch it to strcase.

---

I would remove it. STRCASE does not make sense to use there.

[etilley327KA]

Slope should be a real, where did I switch it? Also, if I cant use strcat, how do I add text to the variable in my mtext?

[ВeekeeCZ]

---

@etilley327KA wrote:

Slope should be a real, where did I switch it? Also, if I cant use strcat, how do I add text to the variable in my mtext?

---

(setq slope (rtos (* (/ (- mtof tdp mtoc) mdis) 100) 2 0))

2nd... Why can not you? IMHO you can, but first you need to convert all the reals to strings.

[etilley327KA]

OK, so I just need to convert all my reals to strings, got it. On my math function, even when I remove the rtos I still get an error, do you know why?

[ВeekeeCZ]

Did you remove that xstrcase?

(defun c:XC (/ tmn tdp mtof mtoc mdis slope mdn apron pt1)
  (setq tmn (getreal "\nEnter SLOPE tolerance: "))
  (setq tdp (cond ((getreal "\nEnter standard drop or <0.67>: "))
		  (0.67)))
  (setq mtof (getreal "\nEnter TOF: "))
  (setq mtoc (getreal "\nEnter TOC: "))
  (setq mdis (getreal "\nEnter Distance: "))
  (setq slope (* (/ (- mtof tdp mtoc) mdis) 100))
  (setq mdn (- mtof (+ mtoc (* (/ tmn 100) mdis)) 0.375))
  (setq apron (- mtof (+ 0.375 mdn)))
  (if (< slope tmn)
    (progn
      (alert "Too High")
      (command "mtext" (setq pt1 (getpoint "\nSelect Point: ")) pt1 (strcat (rtos slope) ", " (rtos apron) ", " (rtos mtof) ", " (rtos mtoc) ", " (rtos mdis) ", " (rtos tdp) "" ""))
      )
    (command "mtext" (setq pt1 (getpoint "\nSelect Point: ") ) pt1 (strcat slope "%") "" "")
    )
  (princ)
  )

I didn't check the math, just the syntax. 

[Kent1Cooper]

---

@etilley327KA wrote:

.... even when I remove the rtos I still get an error, do you know why?

---

What error?  Show the way the edited code line ended up.

[etilley327KA]

(defun c:XC (/ tmn tdp mtof mtoc mdis slope mdn apron pt1)

            (setq tmn (getreal "\nEnter SLOPE tolerance: "))

            (setq tdp

              (cond

                (STRCASE(getreal "\nEnter standard drop or <Enter for 0.67>: "))

                (0.67)

              )

            )

            (setq mtof (getreal "\nEnter TOF: "))

            (setq mtoc (getreal "\nEnter TOC: "))

            (setq mdis (getreal "\nEnter Distance: "))

              (setq slope (* (/ (- mtof tdp mtoc) mdis) 100))

              (setq mdn (- mtof (+ mtoc (* (/ tmn 100) mdis)) 0.375))

              (setq apron (- mtof (+ 0.375 mdn)))

                (if (< slope tmn)

                  (progn

                    (alert "Too High")

                    (command "mtext" (setq pt1 (getpoint "\nSelect Point: ") ) pt1

                             (strcat (rtos slope 2 0) "%"

                              "\\PApron " (rtos apron 2 2)

                              "\\PTOF " (rtos mtof 2 2)

                              "\\PTOC " (rtos mtoc 2 2)

                              "\\PDist " (rtos mdis 2 2)

                              "\\PDrop " (rtos tdp 2 2)) "")

                  )

                    (command "mtext" (setq pt1 (getpoint "\nSelect Point: ") ) pt1 (strcat (rtos slope 2 0) "%") "")

                )

  (princ)

)

[ВeekeeCZ]

Ok, I guess it's just me... Would you explain to me what purpose serves the STRCASE there?

[Kent1Cooper]

This is why I asked what the error was [saying "I still get an error" is never enough information].  It's apparently not from the removing of the (rtos) part, but from the attempt to change the case of a number, or of nil if you hit Enter to accept the default.

[etilley327KA]

bad argument type: numberp: nil :error#2

[etilley327KA]

Not really sure. I was trying to ask for a number but have a standard input if the user didnt have one.

[ВeekeeCZ · Accepted solution]

---

@etilley327KA wrote:
Not really sure. I was trying to ask for a number but have a standard input if the user didnt have one.

---

Well, it's your code. Who else should know?! If you don't know something, look in HELP.

[etilley327KA]

I removed the stcase, thanks.

[Kent1Cooper]

Even if it were possible to make a number uppercase, you would be missing a set of parentheses:

              (cond

                ((STRCASE(getreal "\nEnter standard drop or <Enter for 0.67>: ")))

                (0.67)

              )

[etilley327KA]

Yeah, it seems that variable was causing the problem. Thanks