Editing multiple single-line text entities.... again!
Just a guess, I don't have AC2017 in this old laptop...
Try to change
DDATTE
to
ATTEDIT
Hope this helps,
Henrique
@Anonymous wrote:
....
I had this same list file not work after updating to 2015 and now after updating to 2017, it is not working again.
....
(defun C:ME (/ A B C D E F G H J K L M )
(graphscr)
(setvar "BLIPMODE" 0)
(SETVAR "CMDECHO" 0)
(SETVAR "HIGHLIGHT" 1)
(PROMPT "\nMULTI-EDIT IS LOADED ... ")
(SETQ A (SSGET '((0 . "TEXT,INSERT"))) B (SSLENGTH A) C 0)
(WHILE (< C B)
(SETQ D (SSNAME A C)
E (ENTGET D)
)
(SETQ F (CAR E))
(SETQ G (CDR E))
(SETQ H (CAR G))
(SETQ J (CDR H))
(SETQ K "TEXT")
(SETQ L "INSERT")
(SETQ M "DIMENSION")
(IF (= J K) (COMMAND ".TEXTEDIT" D)(COMMAND ".DDATTE" D ))
(TERPRI)
(SETQ C (1+ C))
)
(PRINC)
); END ME.LSP
I cannot seem to figure out what is causing the problem. Any help would be greatly appreciated!
You don't say what "not working" means. Does it fail to load? Does it load but not run? Does it run but give different results than you expect? What does it not do that you expect it to? What does it do that you don't expect? Any error messages? Etc., etc.
If I may say so, that's a very peculiar way to get an entity type. I don't have 2017 here, but it could be that it lists entity data in a slightly different way. That code requires the entity-type entry to be exactly the second one in the entity data list, but maybe it's not in 2017. If that's the cause of the problem, you can get the entity type directly, whatever position its entry is in the list, and shorten the code considerably by doing so [there are also several unused variables], something like [untested]:
(defun C:ME (/ A B C D J)
(graphscr)
(setvar "BLIPMODE" 0)
(SETVAR "CMDECHO" 0)
(SETVAR "HIGHLIGHT" 1)
(PROMPT "\nMULTI-EDIT IS LOADED ... ")
(SETQ A (SSGET '((0 . "TEXT,INSERT"))) B (SSLENGTH A) C 0)
(WHILE (< C B)
(SETQ
D (SSNAME A C)
J (CDR (assoc 0 (entget D)))
)
(IF (= J "TEXT") (COMMAND ".TEXTEDIT" D) (COMMAND ".DDATTE" D ))
(TERPRI)
(SETQ C (1+ C))
)
(PRINC)
); END ME.LSP
or even without the J variable:
....
(WHILE (< C B)
(SETQ D (SSNAME A C))
(IF (= (CDR (assoc 0 (entget D))) "TEXT") (COMMAND ".TEXTEDIT" D) (COMMAND ".DDATTE" D ))
....
Kent Cooper, AIA 
@Anonymous wrote:
....
(IF (= J K) (COMMAND ".TEXTEDIT" D)(COMMAND ".DDATTE" D ))
(TERPRI)
(SETQ C (1+ C))
)
(PRINC)
); END ME.LSP....
I would think if this were the issue, it would have not worked in any version, but here goes....
That looks like it doesn't allow for any User input to actually do the editing, but calls up one of the commands, and while that's presumably waiting for editing input, goes on to look at the next object. Without setting up the situation and trying it, you may need something like a check on whether the command is still active and pause to wait for User input until it's done, before moving on, such as:
....
(IF (= J K) (COMMAND ".TEXTEDIT" D)(COMMAND ".DDATTE" D ))
(while (> (getvar 'cmdactive) 0) (command pause)))
(setq C (1+ C))
....
which works in certain kinds of commands, but I'm not sure how that relates to in-view text editing as that works in recent versions. Or if the in-view editing box is considered a "dialog box" condition, you may need to force it to bring that up, since the default in (command) functions is to operate without the dialog box unless you do call for it:
....
(initdia)
(if (= J ....
Kent Cooper, AIA
@Anonymous wrote:
....
*Invalid selection*
Expects a point or Last/Undo....
As for that, does it work right if every object selected is Text and none are Attributes? In the case of Attributes, the "object" it gets when it steps through the selection set will be the Block, which you may have selected somewhere other than on an Attribute, or as part of a Window selection. It may need a location in order to find which Attribute to edit, since Blocks can have more than one [and it may need that even in the case of a Block that has only one]. But if you pick only Text, that presumably would not be an issue, since the entity name alone should be enough for it to know what to work with.
Kent Cooper, AIA
Accepted solution
@Anonymous wrote:
TEXTEDITMODE ....
Is that a new variable?
Must be -- it's not recognized here in AutoCAD 2016.
Kent Cooper, AIA
@Anonymous wrote:
TEXTEDITMODE was the problem.... or so I believe.
...
Is that a new variable?
Yes, it is...
2017 New Commands and System Variables
Hope this helps,
Henrique
Accepted solution
@Anonymous wrote:
.... can someone please help me with how to add to the lsp to set that variable to 1 before running it and then setting it back to 0 after the user is done?
....
Is the line in red all I need to do? Is this set up to already set variables back to what they were before running the lisp?
The usual way would be something like this:
(defun C:ME (/ tem A B C D E F G H J K L M )
(graphscr)
(setq tem (getvar 'texteditmode))
(setvar "TEXTEDITMODE" 1)
(setvar "BLIPMODE" 0)
.... ....
(SETQ C (1+ C))
)
(setvar 'texteditmode tem)
(PRINC)
); END ME.LSP
Call the variable anything you like. A good error handler can also ensure that it will be reset even if there is some error.
BUT it occurs to me -- will the routine be used on some 2017 stations and some with earlier versions? That would be a problem if you do only the above, because there will be an error trying to reset it in older versions. You could do something that checks the AutoCAD version first, but since, in a version that does not have that System Variable, "getting" it will just return nil, you could simply make it depend on that:
(defun C:ME (/ tem A B C D E F G H J K L M )
(graphscr)
(if (setq tem (getvar 'texteditmode))
(setvar "TEXTEDITMODE" 1))
(setvar "BLIPMODE" 0)
.... ....
(SETQ C (1+ C))
)
(if tem (setvar 'texteditmode tem))
(PRINC)
); END ME.LSP
Kent Cooper, AIA